basis/specialized-arrays/specialized-arrays.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.data alien.parser
   4 byte-arrays classes combinators fry functors kernel lexer locals
   5 make math math.vectors parser prettyprint.custom sequences
   6 sequences.private vocabs.generated vocabs.loader vocabs.parser
   7 words ;
   8 IN: specialized-arrays
   9
  10 MIXIN: specialized-array
  11
  12 INSTANCE: specialized-array sequence
  13
  14 : (underlying) ( n c-type -- array )
  15     heap-size * (byte-array) ; inline
  16
  17 : <underlying> ( n type -- array )
  18     heap-size * <byte-array> ; inline
  19
  20 GENERIC: underlying-type ( c-type -- c-type' )
  21
  22 M: c-type-word underlying-type
  23     dup "c-type" word-prop {
  24         { [ dup not ] [ drop no-c-type ] }
  25         { [ dup pointer? ] [ 2drop void* ] }
  26         { [ dup c-type-word? ] [ nip underlying-type ] }
  27         [ drop ]
  28     } cond ;
  29
  30 M: pointer underlying-type
  31     drop void* ;
  32
  33 <PRIVATE
  34
  35 GENERIC: nth-c-ptr ( n seq -- displaced-alien )
  36 GENERIC: direct-like ( alien len exemplar -- seq )
  37
  38 M: byte-array nth-c-ptr <displaced-alien> ; inline
  39 M: byte-array direct-like drop uchar <c-direct-array> ; inline
  40
  41 FUNCTOR: define-array ( T -- )
  42
  43 A          DEFINES-CLASS ${T}-array
  44 <A>        DEFINES <${A}>
  45 (A)        DEFINES (${A})
  46 <direct-A> DEFINES <direct-${A}>
  47 A{         DEFINES ${A}{
  48
  49 WHERE
  50
  51 TUPLE: A
  52 { underlying c-ptr read-only }
  53 { length array-capacity read-only } ; final
  54
  55 : <direct-A> ( alien len -- specialized-array ) A boa ; inline
  56
  57 M: A direct-like drop <direct-A> ; inline
  58
  59 : <A> ( n -- specialized-array )
  60     [ \ T <underlying> ] keep <direct-A> ; inline
  61
  62 : (A) ( n -- specialized-array )
  63     [ \ T (underlying) ] keep <direct-A> ; inline
  64
  65 M: A clone [ underlying>> clone ] [ length>> ] bi <direct-A> ; inline
  66
  67 M: A length length>> ; inline
  68
  69 M: A nth-unsafe underlying>> \ T alien-element ; inline
  70
  71 M: A nth-c-ptr underlying>> \ T array-accessor drop swap <displaced-alien> ; inline
  72
  73 M: A set-nth-unsafe underlying>> \ T set-alien-element ; inline
  74
  75 M: A like drop dup A instance? [ \ T >c-array ] unless ; inline
  76
  77 M: A new-sequence drop (A) ; inline
  78
  79 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  80
  81 M: A resize
  82     [
  83         [ \ T heap-size * ] [ underlying>> ] bi*
  84         resize-byte-array
  85     ] [ drop ] 2bi
  86     <direct-A> ; inline
  87
  88 M: A element-size drop \ T heap-size ; inline
  89
  90 M: A underlying-type drop \ T ;
  91
  92 M: A pprint-delims drop \ A{ \ } ;
  93
  94 M: A >pprint-sequence ;
  95
  96 SYNTAX: A{ \ } [ \ T >c-array ] parse-literal ;
  97
  98 INSTANCE: A specialized-array
  99
 100 M: A vs+ [ + \ T c-type-clamp ] 2map ; inline
 101 M: A vs- [ - \ T c-type-clamp ] 2map ; inline
 102 M: A vs* [ * \ T c-type-clamp ] 2map ; inline
 103
 104 M: A v*high [ * \ T heap-size neg shift ] 2map ; inline
 105
 106 ;FUNCTOR
 107
 108 : specialized-array-vocab ( c-type -- vocab )
 109     [
 110         "specialized-arrays.instances." %
 111         [ vocabulary>> % "." % ]
 112         [ name>> % ]
 113         bi
 114     ] "" make ;
 115
 116 :: direct-slice-unsafe ( from to seq -- seq' )
 117     from seq nth-c-ptr to from - seq direct-like ; inline
 118
 119 PRIVATE>
 120
 121 : direct-slice ( from to seq -- seq' )
 122     check-slice direct-slice-unsafe ; inline
 123
 124 : direct-head ( seq n -- seq' ) (head) direct-slice ; inline
 125 : direct-tail ( seq n -- seq' ) (tail) direct-slice ; inline
 126 : direct-head* ( seq n -- seq' ) from-end direct-head ; inline
 127 : direct-tail* ( seq n -- seq' ) from-end direct-tail ; inline
 128
 129 : define-array-vocab ( type -- vocab )
 130     underlying-type
 131     [ specialized-array-vocab ] [ '[ _ define-array ] ] bi
 132     generate-vocab ;
 133
 134 ERROR: specialized-array-vocab-not-loaded c-type ;
 135
 136 M: c-type-word c-array-constructor
 137     underlying-type
 138     dup [ name>> "<" "-array>" surround ] [ specialized-array-vocab ] bi lookup-word
 139     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 140
 141 M: pointer c-array-constructor drop void* c-array-constructor ;
 142
 143 M: c-type-word c-(array)-constructor
 144     underlying-type
 145     dup [ name>> "(" "-array)" surround ] [ specialized-array-vocab ] bi lookup-word
 146     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 147
 148 M: pointer c-(array)-constructor drop void* c-(array)-constructor ;
 149
 150 M: c-type-word c-direct-array-constructor
 151     underlying-type
 152     dup [ name>> "<direct-" "-array>" surround ] [ specialized-array-vocab ] bi lookup-word
 153     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 154
 155 M: pointer c-direct-array-constructor drop void* c-direct-array-constructor ;
 156
 157 M: c-type-word c-array-type
 158     underlying-type
 159     dup [ name>> "-array" append ] [ specialized-array-vocab ] bi lookup-word
 160     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 161
 162 M: pointer c-array-type drop void* c-array-type ;
 163
 164 M: c-type-word c-array-type?
 165     underlying-type
 166     dup [ name>> "-array?" append ] [ specialized-array-vocab ] bi lookup-word
 167     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 168
 169 M: pointer c-array-type? drop void* c-array-type? ;
 170
 171 SYNTAX: SPECIALIZED-ARRAYS:
 172     ";" [ parse-c-type define-array-vocab use-vocab ] each-token ;
 173
 174 SYNTAX: SPECIALIZED-ARRAY:
 175     scan-c-type define-array-vocab use-vocab ;
 176
 177 { "specialized-arrays" "prettyprint" } "specialized-arrays.prettyprint" require-when
 178
 179 { "specialized-arrays" "mirrors" } "specialized-arrays.mirrors" require-when
 180
 181 uchar define-array-vocab drop