basis/specialized-arrays/specialized-arrays.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.data alien.parser
   4 assocs byte-arrays classes compiler.units functors kernel lexer
   5 libc math math.vectors math.vectors.private namespaces
   6 parser prettyprint.custom sequences sequences.private strings
   7 summary vocabs vocabs.loader vocabs.parser vocabs.generated
   8 words fry combinators make ;
   9 IN: specialized-arrays
  10
  11 MIXIN: specialized-array
  12
  13 INSTANCE: specialized-array sequence
  14
  15 : (underlying) ( n c-type -- array )
  16     heap-size * (byte-array) ; inline
  17
  18 : <underlying> ( n type -- array )
  19     heap-size * <byte-array> ; inline
  20
  21 GENERIC: underlying-type ( c-type -- c-type' )
  22
  23 M: c-type-word underlying-type
  24     dup "c-type" word-prop {
  25         { [ dup not ] [ drop no-c-type ] }
  26         { [ dup pointer? ] [ 2drop void* ] }
  27         { [ dup c-type-word? ] [ nip underlying-type ] }
  28         [ drop ]
  29     } cond ;
  30
  31 M: pointer underlying-type
  32     drop void* ;
  33
  34 <PRIVATE
  35
  36 GENERIC: nth-c-ptr ( n seq -- displaced-alien )
  37 GENERIC: direct-like ( alien len exemplar -- seq )
  38
  39 FUNCTOR: define-array ( T -- )
  40
  41 A          DEFINES-CLASS ${T}-array
  42 <A>        DEFINES <${A}>
  43 (A)        DEFINES (${A})
  44 <direct-A> DEFINES <direct-${A}>
  45 malloc-A   DEFINES malloc-${A}
  46 A-cast     DEFINES ${A}-cast
  47 A{         DEFINES ${A}{
  48 A@         DEFINES ${A}@
  49
  50 WHERE
  51
  52 TUPLE: A
  53 { underlying c-ptr read-only }
  54 { length array-capacity read-only } ; final
  55
  56 : <direct-A> ( alien len -- specialized-array ) A boa ; inline
  57
  58 M: A direct-like drop <direct-A> ; inline
  59
  60 : <A> ( n -- specialized-array )
  61     [ \ T <underlying> ] keep <direct-A> ; inline
  62
  63 : (A) ( n -- specialized-array )
  64     [ \ T (underlying) ] keep <direct-A> ; inline
  65
  66 M: A clone [ underlying>> clone ] [ length>> ] bi <direct-A> ; inline
  67
  68 M: A length length>> ; inline
  69
  70 M: A nth-unsafe underlying>> \ T alien-element ; inline
  71
  72 M: A nth-c-ptr underlying>> \ T array-accessor drop swap <displaced-alien> ; inline
  73
  74 M: A set-nth-unsafe underlying>> \ T set-alien-element ; inline
  75
  76 M: A like drop dup A instance? [ \ T >c-array ] unless ; inline
  77
  78 M: A new-sequence drop (A) ; inline
  79
  80 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  81
  82 M: A resize
  83     [
  84         [ \ T heap-size * ] [ underlying>> ] bi*
  85         resize-byte-array
  86     ] [ drop ] 2bi
  87     <direct-A> ; inline
  88
  89 M: A element-size drop \ T heap-size ; inline
  90
  91 M: A underlying-type drop \ T ;
  92
  93 M: A pprint-delims drop \ A{ \ } ;
  94
  95 M: A >pprint-sequence ;
  96
  97 SYNTAX: A{ \ } [ \ T >c-array ] parse-literal ;
  98
  99 INSTANCE: A specialized-array
 100
 101 M: A vs+ [ + \ T c-type-clamp ] 2map ; inline
 102 M: A vs- [ - \ T c-type-clamp ] 2map ; inline
 103 M: A vs* [ * \ T c-type-clamp ] 2map ; inline
 104
 105 M: A v*high [ * \ T heap-size neg shift ] 2map ; inline
 106
 107 ;FUNCTOR
 108
 109 : specialized-array-vocab ( c-type -- vocab )
 110     [
 111         "specialized-arrays.instances." %
 112         [ vocabulary>> % "." % ]
 113         [ name>> % ]
 114         bi
 115     ] "" make ;
 116
 117 : direct-slice-unsafe ( from to seq -- seq' )
 118     [ nip nth-c-ptr ]
 119     [ drop swap - ]
 120     [ 2nip ] 3tri direct-like ; inline
 121
 122 PRIVATE>
 123
 124 : direct-slice ( from to seq -- seq' )
 125     check-slice direct-slice-unsafe ; inline
 126
 127 : direct-head ( seq n -- seq' ) (head) direct-slice ; inline
 128 : direct-tail ( seq n -- seq' ) (tail) direct-slice ; inline
 129 : direct-head* ( seq n -- seq' ) from-end direct-head ; inline
 130 : direct-tail* ( seq n -- seq' ) from-end direct-tail ; inline
 131
 132 : define-array-vocab ( type -- vocab )
 133     underlying-type
 134     [ specialized-array-vocab ] [ '[ _ define-array ] ] bi
 135     generate-vocab ;
 136
 137 ERROR: specialized-array-vocab-not-loaded c-type ;
 138
 139 M: c-type-word c-array-constructor
 140     underlying-type
 141     dup [ name>> "<" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 142     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 143
 144 M: pointer c-array-constructor drop void* c-array-constructor ;
 145
 146 M: c-type-word c-(array)-constructor
 147     underlying-type
 148     dup [ name>> "(" "-array)" surround ] [ specialized-array-vocab ] bi lookup
 149     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 150
 151 M: pointer c-(array)-constructor drop void* c-(array)-constructor ;
 152
 153 M: c-type-word c-direct-array-constructor
 154     underlying-type
 155     dup [ name>> "<direct-" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 156     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 157
 158 M: pointer c-direct-array-constructor drop void* c-direct-array-constructor ;
 159
 160 M: c-type-word c-array-type
 161     underlying-type
 162     dup [ name>> "-array" append ] [ specialized-array-vocab ] bi lookup
 163     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 164
 165 M: pointer c-array-type drop void* c-array-type ;
 166
 167 M: c-type-word c-array-type?
 168     underlying-type
 169     dup [ name>> "-array?" append ] [ specialized-array-vocab ] bi lookup
 170     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 171
 172 M: pointer c-array-type? drop void* c-array-type? ;
 173
 174 SYNTAX: SPECIALIZED-ARRAYS:
 175     ";" [ parse-c-type define-array-vocab use-vocab ] each-token ;
 176
 177 SYNTAX: SPECIALIZED-ARRAY:
 178     scan-c-type define-array-vocab use-vocab ;
 179
 180 { "specialized-arrays" "prettyprint" } "specialized-arrays.prettyprint" require-when
 181
 182 { "specialized-arrays" "mirrors" } "specialized-arrays.mirrors" require-when