basis/specialized-arrays/specialized-arrays.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.data alien.parser
   4 assocs byte-arrays classes compiler.units functors kernel lexer
   5 libc math math.vectors math.vectors.private namespaces
   6 parser prettyprint.custom sequences sequences.private strings
   7 summary vocabs vocabs.loader vocabs.parser vocabs.generated
   8 words fry combinators make ;
   9 IN: specialized-arrays
  10
  11 MIXIN: specialized-array
  12
  13 INSTANCE: specialized-array sequence
  14
  15 GENERIC: direct-array-syntax ( obj -- word )
  16
  17 ERROR: bad-byte-array-length byte-array type ;
  18
  19 M: bad-byte-array-length summary
  20     drop "Byte array length doesn't divide type width" ;
  21
  22 ERROR: not-a-byte-array alien ;
  23
  24 M: not-a-byte-array summary
  25     drop "Not a byte array" ;
  26
  27 : (underlying) ( n c-type -- array )
  28     heap-size * (byte-array) ; inline
  29
  30 : <underlying> ( n type -- array )
  31     heap-size * <byte-array> ; inline
  32
  33 <PRIVATE
  34
  35 GENERIC: nth-c-ptr ( n seq -- displaced-alien )
  36 GENERIC: direct-like ( alien len exemplar -- seq )
  37
  38 FUNCTOR: define-array ( T -- )
  39
  40 A          DEFINES-CLASS ${T}-array
  41 <A>        DEFINES <${A}>
  42 (A)        DEFINES (${A})
  43 <direct-A> DEFINES <direct-${A}>
  44 malloc-A   DEFINES malloc-${A}
  45 >A         DEFINES >${A}
  46 A-cast     DEFINES ${A}-cast
  47 A{         DEFINES ${A}{
  48 A@         DEFINES ${A}@
  49
  50 WHERE
  51
  52 TUPLE: A
  53 { underlying c-ptr read-only }
  54 { length array-capacity read-only } ; final
  55
  56 : <direct-A> ( alien len -- specialized-array ) A boa ; inline
  57
  58 M: A direct-like drop <direct-A> ; inline
  59
  60 : <A> ( n -- specialized-array )
  61     [ \ T <underlying> ] keep <direct-A> ; inline
  62
  63 : (A) ( n -- specialized-array )
  64     [ \ T (underlying) ] keep <direct-A> ; inline
  65
  66 : malloc-A ( len -- specialized-array )
  67     [ \ T heap-size calloc ] keep <direct-A> ; inline
  68
  69 : A-cast ( byte-array -- specialized-array )
  70     binary-object \ T heap-size /mod 0 =
  71     [ <direct-A> ] [ drop \ T bad-byte-array-length ] if ; inline
  72
  73 M: A clone [ underlying>> clone ] [ length>> ] bi <direct-A> ; inline
  74
  75 M: A length length>> ; inline
  76
  77 M: A nth-unsafe underlying>> \ T alien-element ; inline
  78
  79 M: A nth-c-ptr underlying>> \ T array-accessor drop swap <displaced-alien> ; inline
  80
  81 M: A set-nth-unsafe underlying>> \ T set-alien-element ; inline
  82
  83 : >A ( seq -- specialized-array ) A new clone-like ;
  84
  85 M: A like drop dup A instance? [ >A ] unless ; inline
  86
  87 M: A new-sequence drop (A) ; inline
  88
  89 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  90
  91 M: A resize
  92     [
  93         [ \ T heap-size * ] [ underlying>> ] bi*
  94         resize-byte-array
  95     ] [ drop ] 2bi
  96     <direct-A> ; inline
  97
  98 M: A element-size drop \ T heap-size ; inline
  99
 100 M: A direct-array-syntax drop \ A@ ;
 101
 102 M: A pprint-delims drop \ A{ \ } ;
 103
 104 M: A >pprint-sequence ;
 105
 106 SYNTAX: A{ \ } [ >A ] parse-literal ;
 107 SYNTAX: A@ scan-object scan-object <direct-A> suffix! ;
 108
 109 INSTANCE: A specialized-array
 110
 111 M: A vs+ [ + \ T c-type-clamp ] 2map ; inline
 112 M: A vs- [ - \ T c-type-clamp ] 2map ; inline
 113 M: A vs* [ * \ T c-type-clamp ] 2map ; inline
 114
 115 M: A v*high [ * \ T heap-size neg shift ] 2map ; inline
 116
 117 ;FUNCTOR
 118
 119 GENERIC: underlying-type ( c-type -- c-type' )
 120
 121 M: c-type-word underlying-type
 122     dup "c-type" word-prop {
 123         { [ dup not ] [ drop no-c-type ] }
 124         { [ dup pointer? ] [ 2drop void* ] }
 125         { [ dup c-type-word? ] [ nip underlying-type ] }
 126         [ drop ]
 127     } cond ;
 128
 129 M: pointer underlying-type
 130     drop void* ;
 131
 132 : specialized-array-vocab ( c-type -- vocab )
 133     [
 134         "specialized-arrays.instances." %
 135         [ vocabulary>> % "." % ]
 136         [ name>> % ]
 137         bi
 138     ] "" make ;
 139
 140 : direct-slice-unsafe ( from to seq -- seq' )
 141     [ nip nth-c-ptr ]
 142     [ drop swap - ]
 143     [ 2nip ] 3tri direct-like ; inline
 144
 145 PRIVATE>
 146
 147 : direct-slice ( from to seq -- seq' )
 148     check-slice direct-slice-unsafe ; inline
 149
 150 : direct-head ( seq n -- seq' ) (head) direct-slice ; inline
 151 : direct-tail ( seq n -- seq' ) (tail) direct-slice ; inline
 152 : direct-head* ( seq n -- seq' ) from-end direct-head ; inline
 153 : direct-tail* ( seq n -- seq' ) from-end direct-tail ; inline
 154
 155 : define-array-vocab ( type -- vocab )
 156     underlying-type
 157     [ specialized-array-vocab ] [ '[ _ define-array ] ] bi
 158     generate-vocab ;
 159
 160 ERROR: specialized-array-vocab-not-loaded c-type ;
 161
 162 M: c-type-word c-array-constructor
 163     underlying-type
 164     dup [ name>> "<" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 165     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 166
 167 M: pointer c-array-constructor drop void* c-array-constructor ;
 168
 169 M: c-type-word c-(array)-constructor
 170     underlying-type
 171     dup [ name>> "(" "-array)" surround ] [ specialized-array-vocab ] bi lookup
 172     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 173
 174 M: pointer c-(array)-constructor drop void* c-(array)-constructor ;
 175
 176 M: c-type-word c-direct-array-constructor
 177     underlying-type
 178     dup [ name>> "<direct-" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 179     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 180
 181 M: pointer c-direct-array-constructor drop void* c-direct-array-constructor ;
 182
 183 SYNTAX: SPECIALIZED-ARRAYS:
 184     ";" [ parse-c-type define-array-vocab use-vocab ] each-token ;
 185
 186 SYNTAX: SPECIALIZED-ARRAY:
 187     scan-c-type define-array-vocab use-vocab ;
 188
 189 { "specialized-arrays" "prettyprint" } "specialized-arrays.prettyprint" require-when
 190
 191 { "specialized-arrays" "mirrors" } "specialized-arrays.mirrors" require-when