basis/specialized-arrays/specialized-arrays.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.data alien.parser
   4 assocs byte-arrays classes compiler.units functors kernel lexer
   5 libc math math.vectors math.vectors.private namespaces
   6 parser prettyprint.custom sequences sequences.private strings
   7 summary vocabs vocabs.loader vocabs.parser vocabs.generated
   8 words fry combinators make ;
   9 IN: specialized-arrays
  10
  11 MIXIN: specialized-array
  12
  13 INSTANCE: specialized-array sequence
  14
  15 GENERIC: direct-array-syntax ( obj -- word )
  16
  17 ERROR: bad-byte-array-length byte-array type ;
  18
  19 M: bad-byte-array-length summary
  20     drop "Byte array length doesn't divide type width" ;
  21
  22 : (underlying) ( n c-type -- array )
  23     heap-size * (byte-array) ; inline
  24
  25 : <underlying> ( n type -- array )
  26     heap-size * <byte-array> ; inline
  27
  28 <PRIVATE
  29
  30 FUNCTOR: define-array ( T -- )
  31
  32 A            DEFINES-CLASS ${T}-array
  33 S            DEFINES-CLASS ${T}-sequence
  34 <A>          DEFINES <${A}>
  35 (A)          DEFINES (${A})
  36 <direct-A>   DEFINES <direct-${A}>
  37 malloc-A     DEFINES malloc-${A}
  38 >A           DEFINES >${A}
  39 byte-array>A DEFINES byte-array>${A}
  40
  41 A{           DEFINES ${A}{
  42 A@           DEFINES ${A}@
  43
  44 NTH          [ T dup c-type-getter-boxer array-accessor ]
  45 SET-NTH      [ T dup c-setter array-accessor ]
  46
  47 WHERE
  48
  49 MIXIN: S
  50
  51 TUPLE: A
  52 { underlying c-ptr read-only }
  53 { length array-capacity read-only } ;
  54
  55 : <direct-A> ( alien len -- specialized-array ) A boa ; inline
  56
  57 : <A> ( n -- specialized-array )
  58     [ \ T <underlying> ] keep <direct-A> ; inline
  59
  60 : (A) ( n -- specialized-array )
  61     [ \ T (underlying) ] keep <direct-A> ; inline
  62
  63 : malloc-A ( len -- specialized-array )
  64     [ \ T heap-size calloc ] keep <direct-A> ; inline
  65
  66 : byte-array>A ( byte-array -- specialized-array )
  67     >c-ptr dup length \ T heap-size /mod 0 =
  68     [ drop \ T bad-byte-array-length ] unless
  69     <direct-A> ; inline
  70
  71 M: A clone [ underlying>> clone ] [ length>> ] bi <direct-A> ; inline
  72
  73 M: A length length>> ; inline
  74
  75 M: A nth-unsafe underlying>> NTH call ; inline
  76
  77 M: A set-nth-unsafe underlying>> SET-NTH call ; inline
  78
  79 : >A ( seq -- specialized-array ) A new clone-like ;
  80
  81 M: A like drop dup A instance? [ >A ] unless ; inline
  82
  83 M: A new-sequence drop (A) ; inline
  84
  85 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  86
  87 M: A resize
  88     [
  89         [ \ T heap-size * ] [ underlying>> ] bi*
  90         resize-byte-array
  91     ] [ drop ] 2bi
  92     <direct-A> ; inline
  93
  94 M: A byte-length length \ T heap-size * ; inline
  95
  96 M: A direct-array-syntax drop \ A@ ;
  97
  98 M: A pprint-delims drop \ A{ \ } ;
  99
 100 M: A >pprint-sequence ;
 101
 102 SYNTAX: A{ \ } [ >A ] parse-literal ;
 103 SYNTAX: A@ scan-object scan-object <direct-A> suffix! ;
 104
 105 INSTANCE: A specialized-array
 106
 107 ;FUNCTOR
 108
 109 GENERIC: (underlying-type) ( c-type -- c-type' )
 110
 111 M: string (underlying-type) c-types get at ;
 112 M: word (underlying-type) "c-type" word-prop ;
 113
 114 : underlying-type ( c-type -- c-type' )
 115     dup (underlying-type) {
 116         { [ dup not ] [ drop no-c-type ] }
 117         { [ dup c-type-name? ] [ nip underlying-type ] }
 118         [ drop ]
 119     } cond ;
 120
 121 : specialized-array-vocab ( c-type -- vocab )
 122     [
 123         "specialized-arrays.instances." %
 124         [ vocabulary>> % "." % ]
 125         [ name>> % ]
 126         bi
 127     ] "" make ;
 128
 129 PRIVATE>
 130
 131 : define-array-vocab ( type -- vocab )
 132     underlying-type
 133     [ specialized-array-vocab ] [ '[ _ define-array ] ] bi
 134     generate-vocab ;
 135
 136 M: c-type-name require-c-array define-array-vocab drop ;
 137
 138 ERROR: specialized-array-vocab-not-loaded c-type ;
 139
 140 M: c-type-name c-array-constructor
 141     underlying-type
 142     dup [ name>> "<" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 143     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 144
 145 M: c-type-name c-(array)-constructor
 146     underlying-type
 147     dup [ name>> "(" "-array)" surround ] [ specialized-array-vocab ] bi lookup
 148     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 149
 150 M: c-type-name c-direct-array-constructor
 151     underlying-type
 152     dup [ name>> "<direct-" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 153     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 154
 155 SYNTAX: SPECIALIZED-ARRAYS:
 156     ";" parse-tokens [ parse-c-type define-array-vocab use-vocab ] each ;
 157
 158 SYNTAX: SPECIALIZED-ARRAY:
 159     scan-c-type define-array-vocab use-vocab ;
 160
 161 "prettyprint" vocab [
 162     "specialized-arrays.prettyprint" require
 163 ] when
 164
 165 "mirrors" vocab [
 166     "specialized-arrays.mirrors" require
 167 ] when