basis/specialized-arrays/specialized-arrays.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.data alien.parser
   4 assocs byte-arrays classes compiler.units functors kernel lexer
   5 libc math math.vectors math.vectors.private namespaces
   6 parser prettyprint.custom sequences sequences.private strings
   7 summary vocabs vocabs.loader vocabs.parser vocabs.generated
   8 words fry combinators make ;
   9 IN: specialized-arrays
  10
  11 MIXIN: specialized-array
  12
  13 INSTANCE: specialized-array sequence
  14
  15 GENERIC: direct-array-syntax ( obj -- word )
  16
  17 ERROR: bad-byte-array-length byte-array type ;
  18
  19 M: bad-byte-array-length summary
  20     drop "Byte array length doesn't divide type width" ;
  21
  22 ERROR: not-a-byte-array alien ;
  23
  24 M: not-a-byte-array summary
  25     drop "Not a byte array" ;
  26
  27 : (underlying) ( n c-type -- array )
  28     heap-size * (byte-array) ; inline
  29
  30 : <underlying> ( n type -- array )
  31     heap-size * <byte-array> ; inline
  32
  33 <PRIVATE
  34
  35 FUNCTOR: define-array ( T -- )
  36
  37 A          DEFINES-CLASS ${T}-array
  38 <A>        DEFINES <${A}>
  39 (A)        DEFINES (${A})
  40 <direct-A> DEFINES <direct-${A}>
  41 malloc-A   DEFINES malloc-${A}
  42 >A         DEFINES >${A}
  43 A-cast     DEFINES ${A}-cast
  44 A{         DEFINES ${A}{
  45 A@         DEFINES ${A}@
  46
  47 WHERE
  48
  49 TUPLE: A
  50 { underlying c-ptr read-only }
  51 { length array-capacity read-only } ; final
  52
  53 : <direct-A> ( alien len -- specialized-array ) A boa ; inline
  54
  55 : <A> ( n -- specialized-array )
  56     [ \ T <underlying> ] keep <direct-A> ; inline
  57
  58 : (A) ( n -- specialized-array )
  59     [ \ T (underlying) ] keep <direct-A> ; inline
  60
  61 : malloc-A ( len -- specialized-array )
  62     [ \ T heap-size calloc ] keep <direct-A> ; inline
  63
  64 : A-cast ( byte-array -- specialized-array )
  65     binary-object \ T heap-size /mod 0 =
  66     [ <direct-A> ] [ drop \ T bad-byte-array-length ] if ; inline
  67
  68 M: A clone [ underlying>> clone ] [ length>> ] bi <direct-A> ; inline
  69
  70 M: A length length>> ; inline
  71
  72 M: A nth-unsafe underlying>> \ T alien-element ; inline
  73
  74 M: A set-nth-unsafe underlying>> \ T set-alien-element ; inline
  75
  76 : >A ( seq -- specialized-array ) A new clone-like ;
  77
  78 M: A like drop dup A instance? [ >A ] unless ; inline
  79
  80 M: A new-sequence drop (A) ; inline
  81
  82 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  83
  84 M: A resize
  85     [
  86         [ \ T heap-size * ] [ underlying>> ] bi*
  87         resize-byte-array
  88     ] [ drop ] 2bi
  89     <direct-A> ; inline
  90
  91 M: A element-size drop \ T heap-size ; inline
  92
  93 M: A direct-array-syntax drop \ A@ ;
  94
  95 M: A pprint-delims drop \ A{ \ } ;
  96
  97 M: A >pprint-sequence ;
  98
  99 SYNTAX: A{ \ } [ >A ] parse-literal ;
 100 SYNTAX: A@ scan-object scan-object <direct-A> suffix! ;
 101
 102 INSTANCE: A specialized-array
 103
 104 M: A vs+ [ + \ T c-type-clamp ] 2map ; inline
 105 M: A vs- [ - \ T c-type-clamp ] 2map ; inline
 106 M: A vs* [ * \ T c-type-clamp ] 2map ; inline
 107
 108 M: A v*high [ * \ T heap-size neg shift ] 2map ; inline
 109
 110 ;FUNCTOR
 111
 112 GENERIC: underlying-type ( c-type -- c-type' )
 113
 114 M: c-type-word underlying-type
 115     dup "c-type" word-prop {
 116         { [ dup not ] [ drop no-c-type ] }
 117         { [ dup pointer? ] [ 2drop void* ] }
 118         { [ dup c-type-word? ] [ nip underlying-type ] }
 119         [ drop ]
 120     } cond ;
 121
 122 M: pointer underlying-type
 123     drop void* ;
 124
 125 : specialized-array-vocab ( c-type -- vocab )
 126     [
 127         "specialized-arrays.instances." %
 128         [ vocabulary>> % "." % ]
 129         [ name>> % ]
 130         bi
 131     ] "" make ;
 132
 133 PRIVATE>
 134
 135 : define-array-vocab ( type -- vocab )
 136     underlying-type
 137     [ specialized-array-vocab ] [ '[ _ define-array ] ] bi
 138     generate-vocab ;
 139
 140 ERROR: specialized-array-vocab-not-loaded c-type ;
 141
 142 M: c-type-word c-array-constructor
 143     underlying-type
 144     dup [ name>> "<" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 145     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 146
 147 M: pointer c-array-constructor drop void* c-array-constructor ;
 148
 149 M: c-type-word c-(array)-constructor
 150     underlying-type
 151     dup [ name>> "(" "-array)" surround ] [ specialized-array-vocab ] bi lookup
 152     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 153
 154 M: pointer c-(array)-constructor drop void* c-(array)-constructor ;
 155
 156 M: c-type-word c-direct-array-constructor
 157     underlying-type
 158     dup [ name>> "<direct-" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 159     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 160
 161 M: pointer c-direct-array-constructor drop void* c-direct-array-constructor ;
 162
 163 SYNTAX: SPECIALIZED-ARRAYS:
 164     ";" [ parse-c-type define-array-vocab use-vocab ] each-token ;
 165
 166 SYNTAX: SPECIALIZED-ARRAY:
 167     scan-c-type define-array-vocab use-vocab ;
 168
 169 { "specialized-arrays" "prettyprint" } "specialized-arrays.prettyprint" require-when
 170
 171 { "specialized-arrays" "mirrors" } "specialized-arrays.mirrors" require-when