basis/specialized-arrays/specialized-arrays.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.data alien.parser
   4 assocs byte-arrays classes compiler.units functors kernel lexer
   5 libc math math.vectors math.vectors.specialization namespaces
   6 parser prettyprint.custom sequences sequences.private strings
   7 summary vocabs vocabs.loader vocabs.parser vocabs.generated
   8 words fry combinators present ;
   9 IN: specialized-arrays
  10
  11 MIXIN: specialized-array
  12
  13 INSTANCE: specialized-array sequence
  14
  15 GENERIC: direct-array-syntax ( obj -- word )
  16
  17 ERROR: bad-byte-array-length byte-array type ;
  18
  19 M: bad-byte-array-length summary
  20     drop "Byte array length doesn't divide type width" ;
  21
  22 : (underlying) ( n c-type -- array )
  23     heap-size * (byte-array) ; inline
  24
  25 : <underlying> ( n type -- array )
  26     heap-size * <byte-array> ; inline
  27
  28 <PRIVATE
  29
  30 FUNCTOR: define-array ( T -- )
  31
  32 A            DEFINES-CLASS ${T}-array
  33 S            DEFINES-CLASS ${T}-sequence
  34 <A>          DEFINES <${A}>
  35 (A)          DEFINES (${A})
  36 <direct-A>   DEFINES <direct-${A}>
  37 malloc-A     DEFINES malloc-${A}
  38 >A           DEFINES >${A}
  39 byte-array>A DEFINES byte-array>${A}
  40
  41 A{           DEFINES ${A}{
  42 A@           DEFINES ${A}@
  43
  44 NTH          [ T dup c-type-getter-boxer array-accessor ]
  45 SET-NTH      [ T dup c-setter array-accessor ]
  46
  47 WHERE
  48
  49 MIXIN: S
  50
  51 TUPLE: A
  52 { underlying c-ptr read-only }
  53 { length array-capacity read-only } ;
  54
  55 : <direct-A> ( alien len -- specialized-array ) A boa ; inline
  56
  57 : <A> ( n -- specialized-array ) [ \ T <underlying> ] keep <direct-A> ; inline
  58
  59 : (A) ( n -- specialized-array ) [ \ T (underlying) ] keep <direct-A> ; inline
  60
  61 : malloc-A ( len -- specialized-array ) [ \ T heap-size calloc ] keep <direct-A> ; inline
  62
  63 : byte-array>A ( byte-array -- specialized-array )
  64     dup length \ T heap-size /mod 0 = [ drop \ T bad-byte-array-length ] unless
  65     <direct-A> ; inline
  66
  67 M: A clone [ underlying>> clone ] [ length>> ] bi <direct-A> ; inline
  68
  69 M: A length length>> ; inline
  70
  71 M: A nth-unsafe underlying>> NTH call ; inline
  72
  73 M: A set-nth-unsafe underlying>> SET-NTH call ; inline
  74
  75 : >A ( seq -- specialized-array ) A new clone-like ;
  76
  77 M: A like drop dup A instance? [ >A ] unless ; inline
  78
  79 M: A new-sequence drop (A) ; inline
  80
  81 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  82
  83 M: A resize
  84     [
  85         [ \ T heap-size * ] [ underlying>> ] bi*
  86         resize-byte-array
  87     ] [ drop ] 2bi
  88     <direct-A> ; inline
  89
  90 M: A byte-length length \ T heap-size * ; inline
  91
  92 M: A element-type drop \ T ; inline
  93
  94 M: A direct-array-syntax drop \ A@ ;
  95
  96 M: A pprint-delims drop \ A{ \ } ;
  97
  98 M: A >pprint-sequence ;
  99
 100 SYNTAX: A{ \ } [ >A ] parse-literal ;
 101 SYNTAX: A@ scan-object scan-object <direct-A> parsed ;
 102
 103 INSTANCE: A specialized-array
 104
 105 A T c-type-boxed-class f specialize-vector-words
 106
 107 ;FUNCTOR
 108
 109 GENERIC: (underlying-type) ( c-type -- c-type' )
 110
 111 M: string (underlying-type) c-types get at ;
 112 M: word (underlying-type) "c-type" word-prop ;
 113
 114 : underlying-type ( c-type -- c-type' )
 115     dup (underlying-type) {
 116         { [ dup not ] [ drop no-c-type ] }
 117         { [ dup c-type-name? ] [ nip underlying-type ] }
 118         [ drop ]
 119     } cond ;
 120
 121 : underlying-type-name ( c-type -- name )
 122     underlying-type present ;
 123
 124 : specialized-array-vocab ( c-type -- vocab )
 125     present "specialized-arrays.instances." prepend ;
 126
 127 PRIVATE>
 128
 129 : define-array-vocab ( type -- vocab )
 130     underlying-type
 131     [ specialized-array-vocab ] [ '[ _ define-array ] ] bi
 132     generate-vocab ;
 133
 134 M: c-type-name require-c-array define-array-vocab drop ;
 135
 136 ERROR: specialized-array-vocab-not-loaded c-type ;
 137
 138 M: c-type-name c-array-constructor
 139     underlying-type-name
 140     dup [ "<" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 141     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 142
 143 M: c-type-name c-(array)-constructor
 144     underlying-type-name
 145     dup [ "(" "-array)" surround ] [ specialized-array-vocab ] bi lookup
 146     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 147
 148 M: c-type-name c-direct-array-constructor
 149     underlying-type-name
 150     dup [ "<direct-" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 151     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 152
 153 SYNTAX: SPECIALIZED-ARRAY:
 154     scan-c-type define-array-vocab use-vocab ;
 155
 156 "prettyprint" vocab [
 157     "specialized-arrays.prettyprint" require
 158 ] when