basis/specialized-arrays/specialized-arrays.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.data alien.parser
   4 assocs byte-arrays classes compiler.units functors kernel lexer
   5 libc math math.vectors math.vectors.private namespaces
   6 parser prettyprint.custom sequences sequences.private strings
   7 summary vocabs vocabs.loader vocabs.parser vocabs.generated
   8 words fry combinators make ;
   9 IN: specialized-arrays
  10
  11 MIXIN: specialized-array
  12
  13 INSTANCE: specialized-array sequence
  14
  15 GENERIC: direct-array-syntax ( obj -- word )
  16
  17 ERROR: bad-byte-array-length byte-array type ;
  18
  19 M: bad-byte-array-length summary
  20     drop "Byte array length doesn't divide type width" ;
  21
  22 : (underlying) ( n c-type -- array )
  23     heap-size * (byte-array) ; inline
  24
  25 : <underlying> ( n type -- array )
  26     heap-size * <byte-array> ; inline
  27
  28 <PRIVATE
  29
  30 FUNCTOR: define-array ( T -- )
  31
  32 A            DEFINES-CLASS ${T}-array
  33 <A>          DEFINES <${A}>
  34 (A)          DEFINES (${A})
  35 <direct-A>   DEFINES <direct-${A}>
  36 malloc-A     DEFINES malloc-${A}
  37 >A           DEFINES >${A}
  38 byte-array>A DEFINES byte-array>${A}
  39
  40 A{           DEFINES ${A}{
  41 A@           DEFINES ${A}@
  42
  43 NTH          [ T dup c-type-getter-boxer array-accessor ]
  44 SET-NTH      [ T dup c-setter array-accessor ]
  45
  46 WHERE
  47
  48 TUPLE: A
  49 { underlying c-ptr read-only }
  50 { length array-capacity read-only } ; final
  51
  52 : <direct-A> ( alien len -- specialized-array ) A boa ; inline
  53
  54 : <A> ( n -- specialized-array )
  55     [ \ T <underlying> ] keep <direct-A> ; inline
  56
  57 : (A) ( n -- specialized-array )
  58     [ \ T (underlying) ] keep <direct-A> ; inline
  59
  60 : malloc-A ( len -- specialized-array )
  61     [ \ T heap-size calloc ] keep <direct-A> ; inline
  62
  63 : byte-array>A ( byte-array -- specialized-array )
  64     >c-ptr dup length \ T heap-size /mod 0 =
  65     [ drop \ T bad-byte-array-length ] unless
  66     <direct-A> ; inline
  67
  68 M: A clone [ underlying>> clone ] [ length>> ] bi <direct-A> ; inline
  69
  70 M: A length length>> ; inline
  71
  72 M: A nth-unsafe underlying>> NTH call ; inline
  73
  74 M: A set-nth-unsafe underlying>> SET-NTH call ; inline
  75
  76 : >A ( seq -- specialized-array ) A new clone-like ;
  77
  78 M: A like drop dup A instance? [ >A ] unless ; inline
  79
  80 M: A new-sequence drop (A) ; inline
  81
  82 M: A equal? over A instance? [ sequence= ] [ 2drop f ] if ;
  83
  84 M: A resize
  85     [
  86         [ \ T heap-size * ] [ underlying>> ] bi*
  87         resize-byte-array
  88     ] [ drop ] 2bi
  89     <direct-A> ; inline
  90
  91 M: A byte-length length \ T heap-size * ; inline
  92
  93 M: A direct-array-syntax drop \ A@ ;
  94
  95 M: A pprint-delims drop \ A{ \ } ;
  96
  97 M: A >pprint-sequence ;
  98
  99 SYNTAX: A{ \ } [ >A ] parse-literal ;
 100 SYNTAX: A@ scan-object scan-object <direct-A> suffix! ;
 101
 102 INSTANCE: A specialized-array
 103
 104 M: A vs+ [ + \ T c-type-clamp ] 2map ; inline
 105 M: A vs- [ - \ T c-type-clamp ] 2map ; inline
 106 M: A vs* [ * \ T c-type-clamp ] 2map ; inline
 107
 108 M: A v*high [ * \ T heap-size neg shift ] 2map ; inline
 109
 110 ;FUNCTOR
 111
 112 GENERIC: (underlying-type) ( c-type -- c-type' )
 113
 114 M: string (underlying-type) c-types get at ;
 115 M: word (underlying-type) "c-type" word-prop ;
 116
 117 : underlying-type ( c-type -- c-type' )
 118     dup (underlying-type) {
 119         { [ dup not ] [ drop no-c-type ] }
 120         { [ dup c-type-name? ] [ nip underlying-type ] }
 121         [ drop ]
 122     } cond ;
 123
 124 : specialized-array-vocab ( c-type -- vocab )
 125     [
 126         "specialized-arrays.instances." %
 127         [ vocabulary>> % "." % ]
 128         [ name>> % ]
 129         bi
 130     ] "" make ;
 131
 132 PRIVATE>
 133
 134 : define-array-vocab ( type -- vocab )
 135     underlying-type
 136     [ specialized-array-vocab ] [ '[ _ define-array ] ] bi
 137     generate-vocab ;
 138
 139 M: c-type-name require-c-array define-array-vocab drop ;
 140
 141 ERROR: specialized-array-vocab-not-loaded c-type ;
 142
 143 M: c-type-name c-array-constructor
 144     underlying-type
 145     dup [ name>> "<" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 146     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 147
 148 M: c-type-name c-(array)-constructor
 149     underlying-type
 150     dup [ name>> "(" "-array)" surround ] [ specialized-array-vocab ] bi lookup
 151     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 152
 153 M: c-type-name c-direct-array-constructor
 154     underlying-type
 155     dup [ name>> "<direct-" "-array>" surround ] [ specialized-array-vocab ] bi lookup
 156     [ ] [ specialized-array-vocab-not-loaded ] ?if ; foldable
 157
 158 SYNTAX: SPECIALIZED-ARRAYS:
 159     ";" parse-tokens [ parse-c-type define-array-vocab use-vocab ] each ;
 160
 161 SYNTAX: SPECIALIZED-ARRAY:
 162     scan-c-type define-array-vocab use-vocab ;
 163
 164 "prettyprint" vocab [
 165     "specialized-arrays.prettyprint" require
 166 ] when
 167
 168 "mirrors" vocab [
 169     "specialized-arrays.mirrors" require
 170 ] when