basis/specialized-vectors/specialized-vectors.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.parser assocs
   4 classes compiler.units functors growable kernel lexer math
   5 namespaces parser prettyprint.custom sequences
   6 specialized-arrays specialized-arrays.private strings
   7 vocabs vocabs.loader vocabs.parser vocabs.generated fry make ;
   8 FROM: sequences.private => nth-unsafe ;
   9 FROM: specialized-arrays.private => nth-c-ptr direct-like ;
  10 QUALIFIED: vectors.functor
  11 IN: specialized-vectors
  12
  13 MIXIN: specialized-vector
  14
  15 <PRIVATE
  16
  17 FUNCTOR: define-vector ( T -- )
  18
  19 V DEFINES-CLASS ${T}-vector
  20
  21 A          IS ${T}-array
  22 >A         IS >${A}
  23 <A>        IS <${A}>
  24 <direct-A> IS <direct-${A}>
  25
  26 >V DEFERS >${V}
  27 V{ DEFINES ${V}{
  28
  29 WHERE
  30
  31 V A <A> vectors.functor:define-vector
  32
  33 M: V contract 2drop ; inline
  34
  35 M: V element-size drop \ T heap-size ; inline
  36
  37 M: V pprint-delims drop \ V{ \ } ;
  38
  39 M: V >pprint-sequence ;
  40
  41 M: V pprint* pprint-object ;
  42
  43 M: V >c-ptr underlying>> underlying>> ; inline
  44 M: V byte-length [ length ] [ element-size ] bi * ; inline
  45
  46 M: V direct-like drop <direct-A> ; inline
  47 M: V nth-c-ptr underlying>> nth-c-ptr ; inline
  48
  49 M: A like
  50     drop dup A instance? [
  51         dup V instance? [ [ >c-ptr ] [ length>> ] bi <direct-A> ] [ >A ] if
  52     ] unless ; inline
  53
  54 SYNTAX: V{ \ } [ >V ] parse-literal ;
  55
  56 INSTANCE: V specialized-vector
  57 INSTANCE: V growable
  58
  59 ;FUNCTOR
  60
  61 : specialized-vector-vocab ( c-type -- vocab )
  62     [
  63         "specialized-vectors.instances." %
  64         [ vocabulary>> % "." % ]
  65         [ name>> % ]
  66         bi
  67     ] "" make ;
  68
  69 PRIVATE>
  70
  71 : push-new ( vector -- new )
  72     [ length ] keep ensure nth-unsafe ; inline
  73
  74 : define-vector-vocab ( type -- vocab )
  75     underlying-type
  76     [ specialized-vector-vocab ] [ '[ _ define-vector ] ] bi
  77     generate-vocab ;
  78
  79 SYNTAX: SPECIALIZED-VECTORS:
  80     ";" [
  81         parse-c-type
  82         [ define-array-vocab use-vocab ]
  83         [ define-vector-vocab use-vocab ] bi
  84     ] each-token ;
  85
  86 SYNTAX: SPECIALIZED-VECTOR:
  87     scan-c-type
  88     [ define-array-vocab use-vocab ]
  89     [ define-vector-vocab use-vocab ] bi ;
  90
  91 { "specialized-vectors" "mirrors" } "specialized-vectors.mirrors" require-when