basis/specialized-vectors/specialized-vectors.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.parser assocs
   4 compiler.units functors growable kernel lexer math namespaces
   5 parser prettyprint.custom sequences specialized-arrays
   6 specialized-arrays.private strings vocabs vocabs.loader
   7 vocabs.parser vocabs.generated fry make ;
   8 FROM: sequences.private => nth-unsafe ;
   9 FROM: specialized-arrays.private => nth-c-ptr direct-like ;
  10 QUALIFIED: vectors.functor
  11 IN: specialized-vectors
  12
  13 MIXIN: specialized-vector
  14
  15 <PRIVATE
  16
  17 FUNCTOR: define-vector ( T -- )
  18
  19 V DEFINES-CLASS ${T}-vector
  20
  21 A          IS ${T}-array
  22 <A>        IS <${A}>
  23 <direct-A> IS <direct-${A}>
  24
  25 >V DEFERS >${V}
  26 V{ DEFINES ${V}{
  27
  28 WHERE
  29
  30 V A <A> vectors.functor:define-vector
  31
  32 M: V contract 2drop ; inline
  33
  34 M: V element-size drop \ T heap-size ; inline
  35
  36 M: V pprint-delims drop \ V{ \ } ;
  37
  38 M: V >pprint-sequence ;
  39
  40 M: V pprint* pprint-object ;
  41
  42 M: V >c-ptr underlying>> underlying>> ; inline
  43 M: V byte-length [ length ] [ element-size ] bi * ; inline
  44
  45 M: V direct-like drop <direct-A> ; inline
  46 M: V nth-c-ptr underlying>> nth-c-ptr ; inline
  47
  48 SYNTAX: V{ \ } [ >V ] parse-literal ;
  49
  50 INSTANCE: V specialized-vector
  51 INSTANCE: V growable
  52
  53 ;FUNCTOR
  54
  55 : specialized-vector-vocab ( c-type -- vocab )
  56     [
  57         "specialized-vectors.instances." %
  58         [ vocabulary>> % "." % ]
  59         [ name>> % ]
  60         bi
  61     ] "" make ;
  62
  63 PRIVATE>
  64
  65 : push-new ( vector -- new )
  66     [ length ] keep ensure nth-unsafe ; inline
  67
  68 : define-vector-vocab ( type -- vocab )
  69     underlying-type
  70     [ specialized-vector-vocab ] [ '[ _ define-vector ] ] bi
  71     generate-vocab ;
  72
  73 SYNTAX: SPECIALIZED-VECTORS:
  74     ";" [
  75         parse-c-type
  76         [ define-array-vocab use-vocab ]
  77         [ define-vector-vocab use-vocab ] bi
  78     ] each-token ;
  79
  80 SYNTAX: SPECIALIZED-VECTOR:
  81     scan-c-type
  82     [ define-array-vocab use-vocab ]
  83     [ define-vector-vocab use-vocab ] bi ;
  84
  85 { "specialized-vectors" "mirrors" } "specialized-vectors.mirrors" require-when