basis/specialized-vectors/specialized-vectors.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.parser assocs
   4 compiler.units functors growable kernel lexer math namespaces
   5 parser prettyprint.custom sequences specialized-arrays
   6 specialized-arrays.private strings vocabs vocabs.parser
   7 vocabs.generated fry make ;
   8 FROM: sequences.private => nth-unsafe ;
   9 QUALIFIED: vectors.functor
  10 IN: specialized-vectors
  11
  12 <PRIVATE
  13
  14 FUNCTOR: define-vector ( T -- )
  15
  16 V   DEFINES-CLASS ${T}-vector
  17
  18 A   IS      ${T}-array
  19 <A> IS      <${A}>
  20
  21 >V  DEFERS >${V}
  22 V{  DEFINES ${V}{
  23
  24 WHERE
  25
  26 V A <A> vectors.functor:define-vector
  27
  28 M: V contract 2drop ; inline
  29
  30 M: V element-size drop \ T heap-size ; inline
  31
  32 M: V pprint-delims drop \ V{ \ } ;
  33
  34 M: V >pprint-sequence ;
  35
  36 M: V pprint* pprint-object ;
  37
  38 SYNTAX: V{ \ } [ >V ] parse-literal ;
  39
  40 INSTANCE: V growable
  41
  42 ;FUNCTOR
  43
  44 : specialized-vector-vocab ( c-type -- vocab )
  45     [
  46         "specialized-vectors.instances." %
  47         [ vocabulary>> % "." % ]
  48         [ name>> % ]
  49         bi
  50     ] "" make ;
  51
  52 PRIVATE>
  53
  54 : push-new ( vector -- new )
  55     [ length ] keep ensure nth-unsafe ; inline
  56
  57 : define-vector-vocab ( type -- vocab )
  58     underlying-type
  59     [ specialized-vector-vocab ] [ '[ _ define-vector ] ] bi
  60     generate-vocab ;
  61
  62 SYNTAX: SPECIALIZED-VECTORS:
  63     ";" [
  64         parse-c-type
  65         [ define-array-vocab use-vocab ]
  66         [ define-vector-vocab use-vocab ] bi
  67     ] each-token ;
  68
  69 SYNTAX: SPECIALIZED-VECTOR:
  70     scan-c-type
  71     [ define-array-vocab use-vocab ]
  72     [ define-vector-vocab use-vocab ] bi ;