basis/stack-checker/known-words/known-words.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: fry accessors alien alien.accessors alien.private arrays
   4 byte-arrays classes continuations.private effects generic
   5 hashtables hashtables.private io io.backend io.files
   6 io.files.private io.streams.c kernel kernel.private math
   7 math.private math.parser.private memory memory.private
   8 namespaces namespaces.private parser quotations
   9 quotations.private sbufs sbufs.private sequences
  10 sequences.private slots.private strings strings.private system
  11 threads.private classes.tuple classes.tuple.private vectors
  12 vectors.private words words.private definitions assocs summary
  13 compiler.units system.private combinators
  14 combinators.short-circuit locals locals.backend locals.types
  15 combinators.private stack-checker.values generic.single
  16 generic.single.private alien.libraries tools.dispatch.private
  17 tools.profiler.private macros
  18 stack-checker.alien
  19 stack-checker.state
  20 stack-checker.errors
  21 stack-checker.visitor
  22 stack-checker.backend
  23 stack-checker.branches
  24 stack-checker.transforms
  25 stack-checker.dependencies
  26 stack-checker.recursive-state
  27 stack-checker.row-polymorphism ;
  28 IN: stack-checker.known-words
  29
  30 : infer-special ( word -- )
  31     [ current-word set ] [ "special" word-prop call( -- ) ] bi ;
  32
  33 : infer-shuffle ( shuffle -- )
  34     [ in>> length consume-d ] keep ! inputs shuffle
  35     [ drop ] [ shuffle dup copy-values dup output-d ] 2bi ! inputs outputs copies
  36     [ nip f f ] [ swap zip ] 2bi ! in-d out-d in-r out-r mapping
  37     #shuffle, ;
  38
  39 : infer-shuffle-word ( word -- )
  40     "shuffle" word-prop infer-shuffle ;
  41
  42 : infer-local-reader ( word -- )
  43     (( -- value )) apply-word/effect ;
  44
  45 : infer-local-writer ( word -- )
  46     (( value -- )) apply-word/effect ;
  47
  48 : non-inline-word ( word -- )
  49     dup depends-on-effect
  50     {
  51         { [ dup "shuffle" word-prop ] [ infer-shuffle-word ] }
  52         { [ dup "special" word-prop ] [ infer-special ] }
  53         { [ dup "transform-quot" word-prop ] [ apply-transform ] }
  54         { [ dup macro? ] [ apply-macro ] }
  55         { [ dup local? ] [ infer-local-reader ] }
  56         { [ dup local-reader? ] [ infer-local-reader ] }
  57         { [ dup local-writer? ] [ infer-local-writer ] }
  58         { [ dup "no-compile" word-prop ] [ do-not-compile ] }
  59         [ dup required-stack-effect apply-word/effect ]
  60     } cond ;
  61
  62 {
  63     { drop  (( x     --             )) }
  64     { 2drop (( x y   --             )) }
  65     { 3drop (( x y z --             )) }
  66     { dup   (( x     -- x x         )) }
  67     { 2dup  (( x y   -- x y x y     )) }
  68     { 3dup  (( x y z -- x y z x y z )) }
  69     { rot   (( x y z -- y z x       )) }
  70     { -rot  (( x y z -- z x y       )) }
  71     { dupd  (( x y   -- x x y       )) }
  72     { swapd (( x y z -- y x z       )) }
  73     { nip   (( x y   -- y           )) }
  74     { 2nip  (( x y z -- z           )) }
  75     { over  (( x y   -- x y x       )) }
  76     { pick  (( x y z -- x y z x     )) }
  77     { swap  (( x y   -- y x         )) }
  78 } [ "shuffle" set-word-prop ] assoc-each
  79
  80 : check-declaration ( declaration -- declaration )
  81     dup { [ array? ] [ [ class? ] all? ] } 1&&
  82     [ bad-declaration-error ] unless ;
  83
  84 : infer-declare ( -- )
  85     pop-literal nip check-declaration
  86     [ length ensure-d ] keep zip
  87     #declare, ;
  88
  89 \ declare [ infer-declare ] "special" set-word-prop
  90
  91 GENERIC: infer-call* ( value known -- )
  92
  93 : (infer-call) ( value -- ) dup known infer-call* ;
  94
  95 : infer-call ( -- ) pop-d (infer-call) ;
  96
  97 \ call [ infer-call ] "special" set-word-prop
  98
  99 \ (call) [ infer-call ] "special" set-word-prop
 100
 101 M: literal infer-call*
 102     [ 1array #drop, ] [ infer-literal-quot ] bi* ;
 103
 104 M: curried infer-call*
 105     swap push-d
 106     [ uncurry ] infer-quot-here
 107     [ quot>> known pop-d [ set-known ] keep ]
 108     [ obj>> known pop-d [ set-known ] keep ] bi
 109     push-d (infer-call) ;
 110
 111 M: composed infer-call*
 112     swap push-d
 113     [ uncompose ] infer-quot-here
 114     [ quot2>> known pop-d [ set-known ] keep ]
 115     [ quot1>> known pop-d [ set-known ] keep ] bi
 116     push-d push-d
 117     1 infer->r infer-call
 118     terminated? get [ 1 infer-r> infer-call ] unless ;
 119
 120 M: declared-effect infer-call*
 121     [ [ known>> infer-call* ] keep ] with-effect-here check-declared-effect ;
 122
 123 M: input-parameter infer-call* \ call unknown-macro-input ;
 124 M: object infer-call* \ call bad-macro-input ;
 125
 126 : infer-ndip ( word n -- )
 127     [ literals get ] 2dip
 128     [ '[ _ def>> infer-quot-here ] ]
 129     [ '[ _ [ pop ] dip [ infer->r infer-quot-here ] [ infer-r> ] bi ] ] bi*
 130     if-empty ;
 131
 132 : infer-dip ( -- ) \ dip 1 infer-ndip ;
 133
 134 \ dip [ infer-dip ] "special" set-word-prop
 135
 136 : infer-2dip ( -- ) \ 2dip 2 infer-ndip ;
 137
 138 \ 2dip [ infer-2dip ] "special" set-word-prop
 139
 140 : infer-3dip ( -- ) \ 3dip 3 infer-ndip ;
 141
 142 \ 3dip [ infer-3dip ] "special" set-word-prop
 143
 144 : infer-builder ( quot word -- )
 145     [
 146         [ 2 consume-d ] dip
 147         [ dup first2 ] dip call make-known
 148         [ push-d ] [ 1array ] bi
 149     ] dip #call, ; inline
 150
 151 : infer-curry ( -- ) [ <curried> ] \ curry infer-builder ;
 152
 153 \ curry [ infer-curry ] "special" set-word-prop
 154
 155 : infer-compose ( -- ) [ <composed> ] \ compose infer-builder ;
 156
 157 \ compose [ infer-compose ] "special" set-word-prop
 158
 159 : infer-execute ( -- )
 160     pop-literal nip
 161     dup word? [
 162         apply-object
 163     ] [
 164         \ execute time-bomb
 165     ] if ;
 166
 167 \ execute [ infer-execute ] "special" set-word-prop
 168
 169 \ (execute) [ infer-execute ] "special" set-word-prop
 170
 171 : infer-<tuple-boa> ( -- )
 172     \ <tuple-boa>
 173     peek-d literal value>> second 1 + "obj" <array> { tuple } <effect>
 174     apply-word/effect ;
 175
 176 \ <tuple-boa> [ infer-<tuple-boa> ] "special" set-word-prop
 177
 178 \ <tuple-boa> t "flushable" set-word-prop
 179
 180 : infer-effect-unsafe ( word -- )
 181     pop-literal nip
 182     add-effect-input
 183     apply-word/effect ;
 184
 185 : infer-execute-effect-unsafe ( -- )
 186     \ (execute) infer-effect-unsafe ;
 187
 188 \ execute-effect-unsafe [ infer-execute-effect-unsafe ] "special" set-word-prop
 189
 190 : infer-call-effect-unsafe ( -- )
 191     \ call infer-effect-unsafe ;
 192
 193 \ call-effect-unsafe [ infer-call-effect-unsafe ] "special" set-word-prop
 194
 195 : infer-load-locals ( -- )
 196     pop-literal nip
 197     consume-d dup copy-values dup output-r
 198     [ [ f f ] dip ] [ swap zip ] 2bi #shuffle, ;
 199
 200 \ load-locals [ infer-load-locals ] "special" set-word-prop
 201
 202 : infer-load-local ( -- )
 203     1 infer->r ;
 204
 205 \ load-local [ infer-load-local ] "special" set-word-prop
 206
 207 :: infer-get-local ( -- )
 208     pop-literal nip 1 swap - :> n
 209     n consume-r :> in-r
 210     in-r first copy-value 1array :> out-d
 211     in-r copy-values :> out-r
 212
 213     out-d output-d
 214     out-r output-r
 215     f out-d in-r out-r
 216     out-r in-r zip out-d first in-r first 2array suffix
 217     #shuffle, ;
 218
 219 \ get-local [ infer-get-local ] "special" set-word-prop
 220
 221 : infer-drop-locals ( -- )
 222     f f pop-literal nip consume-r f f #shuffle, ;
 223
 224 \ drop-locals [ infer-drop-locals ] "special" set-word-prop
 225
 226 : infer-call-effect ( word -- )
 227     1 ensure-d first literal value>>
 228     add-effect-input add-effect-input
 229     apply-word/effect ;
 230
 231 { call-effect execute-effect } [
 232     dup t "no-compile" set-word-prop
 233     dup '[ _ infer-call-effect ] "special" set-word-prop
 234 ] each
 235
 236 \ if [ infer-if ] "special" set-word-prop
 237 \ dispatch [ infer-dispatch ] "special" set-word-prop
 238
 239 \ alien-invoke [ infer-alien-invoke ] "special" set-word-prop
 240 \ alien-indirect [ infer-alien-indirect ] "special" set-word-prop
 241 \ alien-assembly [ infer-alien-assembly ] "special" set-word-prop
 242 \ alien-callback [ infer-alien-callback ] "special" set-word-prop
 243
 244 {
 245     do-primitive
 246     mega-cache-miss
 247     mega-cache-lookup
 248     inline-cache-miss
 249     inline-cache-miss-tail
 250     unwind-native-frames
 251     set-datastack
 252     set-callstack
 253     set-retainstack
 254     unwind-native-frames
 255     lazy-jit-compile
 256     c-to-factor
 257 } [ dup '[ _ do-not-compile ] "special" set-word-prop ] each
 258
 259 {
 260     declare call (call) dip 2dip 3dip curry compose
 261     execute (execute) call-effect-unsafe execute-effect-unsafe if
 262     dispatch <tuple-boa> load-local load-locals get-local
 263     drop-locals do-primitive alien-invoke alien-indirect
 264     alien-callback
 265 } [ t "no-compile" set-word-prop ] each
 266
 267 ! Exceptions to the above
 268 \ curry f "no-compile" set-word-prop
 269 \ compose f "no-compile" set-word-prop
 270
 271 ! More words not to compile
 272 \ clear t "no-compile" set-word-prop
 273
 274 : define-primitive ( word inputs outputs -- )
 275     [ "input-classes" set-word-prop ]
 276     [ "default-output-classes" set-word-prop ]
 277     bi-curry* bi ;
 278
 279 ! Stack effects for all primitives
 280 \ (byte-array) { integer } { byte-array } define-primitive \ (byte-array) make-flushable
 281 \ (clone) { object } { object } define-primitive \ (clone) make-flushable
 282 \ (code-blocks) { } { array } define-primitive \ (code-blocks)  make-flushable
 283 \ (dlopen) { byte-array } { dll } define-primitive
 284 \ (dlsym) { byte-array object } { c-ptr } define-primitive
 285 \ (exists?) { string } { object } define-primitive
 286 \ (exit) { integer } { } define-primitive
 287 \ (format-float) { float byte-array } { byte-array } define-primitive \ (format-float) make-foldable
 288 \ (fopen) { byte-array byte-array } { alien } define-primitive
 289 \ (identity-hashcode) { object } { fixnum } define-primitive
 290 \ (save-image) { byte-array byte-array } { } define-primitive
 291 \ (save-image-and-exit) { byte-array byte-array } { } define-primitive
 292 \ (set-context) { object alien } { object } define-primitive
 293 \ (set-context-and-delete) { object alien } { } define-primitive
 294 \ (sleep) { integer } { } define-primitive
 295 \ (start-context) { object quotation } { object } define-primitive
 296 \ (start-context-and-delete) { object quotation } { } define-primitive
 297 \ (word) { object object object } { word } define-primitive \ (word) make-flushable
 298 \ <array> { integer object } { array } define-primitive \ <array> make-flushable
 299 \ <byte-array> { integer } { byte-array } define-primitive \ <byte-array> make-flushable
 300 \ <callback> { integer word } { alien } define-primitive
 301 \ <displaced-alien> { integer c-ptr } { c-ptr } define-primitive \ <displaced-alien> make-flushable
 302 \ <string> { integer integer } { string } define-primitive \ <string> make-flushable
 303 \ <tuple> { array } { tuple } define-primitive \ <tuple> make-flushable
 304 \ <wrapper> { object } { wrapper } define-primitive \ <wrapper> make-foldable
 305 \ alien-address { alien } { integer } define-primitive \ alien-address make-flushable
 306 \ alien-cell { c-ptr integer } { pinned-c-ptr } define-primitive \ alien-cell make-flushable
 307 \ alien-double { c-ptr integer } { float } define-primitive \ alien-double make-flushable
 308 \ alien-float { c-ptr integer } { float } define-primitive \ alien-float make-flushable
 309 \ alien-signed-1 { c-ptr integer } { fixnum } define-primitive \ alien-signed-1 make-flushable
 310 \ alien-signed-2 { c-ptr integer } { fixnum } define-primitive \ alien-signed-2 make-flushable
 311 \ alien-signed-4 { c-ptr integer } { integer } define-primitive \ alien-signed-4 make-flushable
 312 \ alien-signed-8 { c-ptr integer } { integer } define-primitive \ alien-signed-8 make-flushable
 313 \ alien-signed-cell { c-ptr integer } { integer } define-primitive \ alien-signed-cell make-flushable
 314 \ alien-unsigned-1 { c-ptr integer } { fixnum } define-primitive \ alien-unsigned-1 make-flushable
 315 \ alien-unsigned-2 { c-ptr integer } { fixnum } define-primitive \ alien-unsigned-2 make-flushable
 316 \ alien-unsigned-4 { c-ptr integer } { integer } define-primitive \ alien-unsigned-4 make-flushable
 317 \ alien-unsigned-8 { c-ptr integer } { integer } define-primitive \ alien-unsigned-8 make-flushable
 318 \ alien-unsigned-cell { c-ptr integer } { integer } define-primitive \ alien-unsigned-cell make-flushable
 319 \ all-instances { } { array } define-primitive
 320 \ array>quotation { array } { quotation } define-primitive \ array>quotation make-foldable
 321 \ become { array array } { } define-primitive
 322 \ bignum* { bignum bignum } { bignum } define-primitive \ bignum* make-foldable
 323 \ bignum+ { bignum bignum } { bignum } define-primitive \ bignum+ make-foldable
 324 \ bignum- { bignum bignum } { bignum } define-primitive \ bignum- make-foldable
 325 \ bignum-bit? { bignum integer } { object } define-primitive \ bignum-bit? make-foldable
 326 \ bignum-bitand { bignum bignum } { bignum } define-primitive \ bignum-bitand make-foldable
 327 \ bignum-bitnot { bignum } { bignum } define-primitive \ bignum-bitnot make-foldable
 328 \ bignum-bitor { bignum bignum } { bignum } define-primitive \ bignum-bitor make-foldable
 329 \ bignum-bitxor { bignum bignum } { bignum } define-primitive \ bignum-bitxor make-foldable
 330 \ bignum-log2 { bignum } { bignum } define-primitive \ bignum-log2 make-foldable
 331 \ bignum-mod { bignum bignum } { bignum } define-primitive \ bignum-mod make-foldable
 332 \ bignum-shift { bignum fixnum } { bignum } define-primitive \ bignum-shift make-foldable
 333 \ bignum/i { bignum bignum } { bignum } define-primitive \ bignum/i make-foldable
 334 \ bignum/mod { bignum bignum } { bignum bignum } define-primitive \ bignum/mod make-foldable
 335 \ bignum< { bignum bignum } { object } define-primitive \ bignum< make-foldable
 336 \ bignum<= { bignum bignum } { object } define-primitive \ bignum<= make-foldable
 337 \ bignum= { bignum bignum } { object } define-primitive \ bignum= make-foldable
 338 \ bignum> { bignum bignum } { object } define-primitive \ bignum> make-foldable
 339 \ bignum>= { bignum bignum } { object } define-primitive \ bignum>= make-foldable
 340 \ bignum>fixnum { bignum } { fixnum } define-primitive \ bignum>fixnum make-foldable
 341 \ bits>double { integer } { float } define-primitive \ bits>double make-foldable
 342 \ bits>float { integer } { float } define-primitive \ bits>float make-foldable
 343 \ both-fixnums? { object object } { object } define-primitive
 344 \ byte-array>bignum { byte-array } { bignum } define-primitive \ byte-array>bignum make-foldable
 345 \ callstack { } { callstack } define-primitive \ callstack make-flushable
 346 \ callstack-bounds { } { alien alien } define-primitive \ callstack-bounds make-flushable
 347 \ callstack-for { c-ptr } { callstack } define-primitive \ callstack make-flushable
 348 \ callstack>array { callstack } { array } define-primitive \ callstack>array make-flushable
 349 \ check-datastack { array integer integer } { object } define-primitive \ check-datastack make-flushable
 350 \ code-room { } { byte-array } define-primitive \ code-room  make-flushable
 351 \ compact-gc { } { } define-primitive
 352 \ compute-identity-hashcode { object } { } define-primitive
 353 \ context-object { fixnum } { object } define-primitive \ context-object make-flushable
 354 \ context-object-for { fixnum c-ptr } { object } define-primitive \ context-object-for make-flushable
 355 \ current-callback { } { fixnum } define-primitive \ current-callback make-flushable
 356 \ data-room { } { byte-array } define-primitive \ data-room make-flushable
 357 \ datastack { } { array } define-primitive \ datastack make-flushable
 358 \ datastack-for { c-ptr } { array } define-primitive \ datastack-for make-flushable
 359 \ die { } { } define-primitive
 360 \ disable-gc-events { } { object } define-primitive
 361 \ dispatch-stats { } { byte-array } define-primitive
 362 \ dlclose { dll } { } define-primitive
 363 \ dll-valid? { object } { object } define-primitive
 364 \ double>bits { real } { integer } define-primitive \ double>bits make-foldable
 365 \ enable-gc-events { } { } define-primitive
 366 \ eq? { object object } { object } define-primitive \ eq? make-foldable
 367 \ fclose { alien } { } define-primitive
 368 \ fflush { alien } { } define-primitive
 369 \ fgetc { alien } { object } define-primitive
 370 \ fixnum* { fixnum fixnum } { integer } define-primitive \ fixnum* make-foldable
 371 \ fixnum*fast { fixnum fixnum } { fixnum } define-primitive \ fixnum*fast make-foldable
 372 \ fixnum+ { fixnum fixnum } { integer } define-primitive \ fixnum+ make-foldable
 373 \ fixnum+fast { fixnum fixnum } { fixnum } define-primitive \ fixnum+fast make-foldable
 374 \ fixnum- { fixnum fixnum } { integer } define-primitive \ fixnum- make-foldable
 375 \ fixnum-bitand { fixnum fixnum } { fixnum } define-primitive \ fixnum-bitand make-foldable
 376 \ fixnum-bitnot { fixnum } { fixnum } define-primitive \ fixnum-bitnot make-foldable
 377 \ fixnum-bitor { fixnum fixnum } { fixnum } define-primitive \ fixnum-bitor make-foldable
 378 \ fixnum-bitxor { fixnum fixnum } { fixnum } define-primitive \ fixnum-bitxor make-foldable
 379 \ fixnum-fast { fixnum fixnum } { fixnum } define-primitive \ fixnum-fast make-foldable
 380 \ fixnum-mod { fixnum fixnum } { fixnum } define-primitive \ fixnum-mod make-foldable
 381 \ fixnum-shift { fixnum fixnum } { integer } define-primitive \ fixnum-shift make-foldable
 382 \ fixnum-shift-fast { fixnum fixnum } { fixnum } define-primitive \ fixnum-shift-fast make-foldable
 383 \ fixnum/i { fixnum fixnum } { integer } define-primitive \ fixnum/i make-foldable
 384 \ fixnum/i-fast { fixnum fixnum } { fixnum } define-primitive \ fixnum/i-fast make-foldable
 385 \ fixnum/mod { fixnum fixnum } { integer fixnum } define-primitive \ fixnum/mod make-foldable
 386 \ fixnum/mod-fast { fixnum fixnum } { fixnum fixnum } define-primitive \ fixnum/mod-fast make-foldable
 387 \ fixnum< { fixnum fixnum } { object } define-primitive \ fixnum< make-foldable
 388 \ fixnum<= { fixnum fixnum } { object } define-primitive \ fixnum<= make-foldable
 389 \ fixnum> { fixnum fixnum } { object } define-primitive \ fixnum> make-foldable
 390 \ fixnum>= { fixnum fixnum } { object } define-primitive \ fixnum>= make-foldable
 391 \ fixnum>bignum { fixnum } { bignum } define-primitive \ fixnum>bignum make-foldable
 392 \ fixnum>float { fixnum } { float } define-primitive \ fixnum>float make-foldable
 393 \ float* { float float } { float } define-primitive \ float* make-foldable
 394 \ float+ { float float } { float } define-primitive \ float+ make-foldable
 395 \ float- { float float } { float } define-primitive \ float- make-foldable
 396 \ float-u< { float float } { object } define-primitive \ float-u< make-foldable
 397 \ float-u<= { float float } { object } define-primitive \ float-u<= make-foldable
 398 \ float-u> { float float } { object } define-primitive \ float-u> make-foldable
 399 \ float-u>= { float float } { object } define-primitive \ float-u>= make-foldable
 400 \ float/f { float float } { float } define-primitive \ float/f make-foldable
 401 \ float< { float float } { object } define-primitive \ float< make-foldable
 402 \ float<= { float float } { object } define-primitive \ float<= make-foldable
 403 \ float= { float float } { object } define-primitive \ float= make-foldable
 404 \ float> { float float } { object } define-primitive \ float> make-foldable
 405 \ float>= { float float } { object } define-primitive \ float>= make-foldable
 406 \ float>bignum { float } { bignum } define-primitive \ float>bignum make-foldable
 407 \ float>bits { real } { integer } define-primitive \ float>bits make-foldable
 408 \ float>fixnum { float } { fixnum } define-primitive \ bignum>fixnum make-foldable
 409 \ fpu-state { } { } define-primitive
 410 \ fputc { object alien } { } define-primitive
 411 \ fread { integer alien } { object } define-primitive
 412 \ fseek { integer integer alien } { } define-primitive
 413 \ ftell { alien } { integer } define-primitive
 414 \ fwrite { c-ptr integer alien } { } define-primitive
 415 \ gc { } { } define-primitive
 416 \ innermost-frame-executing { callstack } { object } define-primitive
 417 \ innermost-frame-scan { callstack } { fixnum } define-primitive
 418 \ jit-compile { quotation } { } define-primitive
 419 \ lookup-method { object array } { word } define-primitive
 420 \ minor-gc { } { } define-primitive
 421 \ modify-code-heap { array object object } { } define-primitive
 422 \ nano-count { } { integer } define-primitive \ nano-count make-flushable
 423 \ optimized? { word } { object } define-primitive
 424 \ profiling { object } { } define-primitive
 425 \ quot-compiled? { quotation } { object } define-primitive
 426 \ quotation-code { quotation } { integer integer } define-primitive \ quotation-code make-flushable
 427 \ reset-dispatch-stats { } { } define-primitive
 428 \ resize-array { integer array } { array } define-primitive
 429 \ resize-byte-array { integer byte-array } { byte-array } define-primitive
 430 \ resize-string { integer string } { string } define-primitive
 431 \ retainstack { } { array } define-primitive \ retainstack make-flushable
 432 \ retainstack-for { c-ptr } { array } define-primitive \ retainstack-for make-flushable
 433 \ set-alien-cell { c-ptr c-ptr integer } { } define-primitive
 434 \ set-alien-double { float c-ptr integer } { } define-primitive
 435 \ set-alien-float { float c-ptr integer } { } define-primitive
 436 \ set-alien-signed-1 { integer c-ptr integer } { } define-primitive
 437 \ set-alien-signed-2 { integer c-ptr integer } { } define-primitive
 438 \ set-alien-signed-4 { integer c-ptr integer } { } define-primitive
 439 \ set-alien-signed-8 { integer c-ptr integer } { } define-primitive
 440 \ set-alien-signed-cell { integer c-ptr integer } { } define-primitive
 441 \ set-alien-unsigned-1 { integer c-ptr integer } { } define-primitive
 442 \ set-alien-unsigned-2 { integer c-ptr integer } { } define-primitive
 443 \ set-alien-unsigned-4 { integer c-ptr integer } { } define-primitive
 444 \ set-alien-unsigned-8 { integer c-ptr integer } { } define-primitive
 445 \ set-alien-unsigned-cell { integer c-ptr integer } { } define-primitive
 446 \ set-context-object { object fixnum } { } define-primitive
 447 \ set-fpu-state { } { } define-primitive
 448 \ set-innermost-frame-quot { quotation callstack } { } define-primitive
 449 \ set-slot { object object fixnum } { } define-primitive
 450 \ set-special-object { object fixnum } { } define-primitive
 451 \ set-string-nth-fast { fixnum fixnum string } { } define-primitive
 452 \ size { object } { fixnum } define-primitive \ size make-flushable
 453 \ slot { object fixnum } { object } define-primitive \ slot make-flushable
 454 \ special-object { fixnum } { object } define-primitive \ special-object make-flushable
 455 \ string-nth-fast { fixnum string } { fixnum } define-primitive \ string-nth-fast make-flushable
 456 \ strip-stack-traces { } { } define-primitive
 457 \ tag { object } { fixnum } define-primitive \ tag make-foldable
 458 \ unimplemented { } { } define-primitive
 459 \ word-code { word } { integer integer } define-primitive \ word-code make-flushable