basis/stack-checker/transforms/transforms.factor

   1 ! Copyright (C) 2007, 2009 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3
   4 USING: accessors classes.struct classes.tuple
   5 classes.tuple.private combinators combinators.short-circuit
   6 continuations generic kernel namespaces quotations sequences
   7 stack-checker.backend stack-checker.dependencies
   8 stack-checker.errors stack-checker.recursive-state
   9 stack-checker.values stack-checker.visitor words ;
  10
  11 IN: stack-checker.transforms
  12
  13 : call-transformer ( stack quot -- newquot )
  14     '[ _ _ with-datastack [ length 1 assert= ] [ first ] bi ]
  15     [ error-continuation get current-word get transform-expansion-error ]
  16     recover ;
  17
  18 :: apply-literal-values-transform ( quot values stack rstate -- )
  19     rstate recursive-state [ stack quot call-transformer ] with-variable
  20     values [ length shorten-d ] [ #drop, ] bi
  21     rstate infer-quot ;
  22
  23 : literal-values? ( values -- ? ) [ literal-value? ] all? ;
  24
  25 : input-values? ( values -- ? )
  26     [ { [ literal-value? ] [ input-value? ] } 1|| ] all? ;
  27
  28 : (apply-transform) ( quot n -- )
  29     ensure-d {
  30         { [ dup literal-values? ] [
  31             dup empty? [ dup recursive-state get ] [
  32                 [ ]
  33                 [ [ literal value>> ] map ]
  34                 [ first literal recursion>> ] tri
  35             ] if
  36             apply-literal-values-transform
  37         ] }
  38         { [ dup input-values? ] [ drop current-word get unknown-macro-input ] }
  39         [ drop current-word get bad-macro-input ]
  40     } cond ;
  41
  42 : apply-transform ( word -- )
  43     [ current-word set ]
  44     [ "transform-quot" word-prop ]
  45     [ "transform-n" word-prop ] tri
  46     (apply-transform) ;
  47
  48 : apply-macro ( word -- )
  49     [ current-word set ]
  50     [ "macro" word-prop ]
  51     [ "declared-effect" word-prop in>> length ] tri
  52     (apply-transform) ;
  53
  54 : define-transform ( word quot n -- )
  55     [ drop "transform-quot" set-word-prop ]
  56     [ nip "transform-n" set-word-prop ]
  57     3bi ;
  58
  59 ! Combinators
  60 \ cond [ cond>quot ] 1 define-transform
  61
  62 \ cond t "no-compile" set-word-prop
  63
  64 \ case [
  65     [
  66         [ no-case ]
  67     ] [
  68         dup [ callable? ] find dup
  69         [ [ head ] dip ] [ 2drop [ no-case ] ] if
  70         swap case>quot
  71     ] if-empty
  72 ] 1 define-transform
  73
  74 \ case t "no-compile" set-word-prop
  75
  76 \ cleave [ cleave>quot ] 1 define-transform
  77
  78 \ cleave t "no-compile" set-word-prop
  79
  80 \ 2cleave [ 2cleave>quot ] 1 define-transform
  81
  82 \ 2cleave t "no-compile" set-word-prop
  83
  84 \ 3cleave [ 3cleave>quot ] 1 define-transform
  85
  86 \ 3cleave t "no-compile" set-word-prop
  87
  88 \ 4cleave [ 4cleave>quot ] 1 define-transform
  89
  90 \ 4cleave t "no-compile" set-word-prop
  91
  92 \ spread [ deep-spread>quot ] 1 define-transform
  93
  94 \ spread t "no-compile" set-word-prop
  95
  96 \ 0&& [ '[ _ 0 n&& ] ] 1 define-transform
  97
  98 \ 0&& t "no-compile" set-word-prop
  99
 100 \ 1&& [ '[ _ 1 n&& ] ] 1 define-transform
 101
 102 \ 1&& t "no-compile" set-word-prop
 103
 104 \ 2&& [ '[ _ 2 n&& ] ] 1 define-transform
 105
 106 \ 2&& t "no-compile" set-word-prop
 107
 108 \ 3&& [ '[ _ 3 n&& ] ] 1 define-transform
 109
 110 \ 3&& t "no-compile" set-word-prop
 111
 112 \ 0|| [ '[ _ 0 n|| ] ] 1 define-transform
 113
 114 \ 0|| t "no-compile" set-word-prop
 115
 116 \ 1|| [ '[ _ 1 n|| ] ] 1 define-transform
 117
 118 \ 1|| t "no-compile" set-word-prop
 119
 120 \ 2|| [ '[ _ 2 n|| ] ] 1 define-transform
 121
 122 \ 2|| t "no-compile" set-word-prop
 123
 124 \ 3|| [ '[ _ 3 n|| ] ] 1 define-transform
 125
 126 \ 3|| t "no-compile" set-word-prop
 127
 128 : add-next-method-dependency ( method -- )
 129     [ "method-class" word-prop ]
 130     [ "method-generic" word-prop ] bi
 131     2dup next-method
 132     add-depends-on-next-method ;
 133
 134 \ (call-next-method) [
 135     [ add-next-method-dependency ]
 136     [ [ next-method-quot ] [ '[ _ no-next-method ] ] bi or ] bi
 137 ] 1 define-transform
 138
 139 \ (call-next-method) t "no-compile" set-word-prop
 140
 141 ! Constructors
 142 \ boa [
 143     {
 144         { [ dup struct-class? ] [
 145             dup dup struct-slots add-depends-on-struct-slots
 146             '[ _ <struct-boa> ] ] }
 147         { [ dup tuple-class? ] [
 148             dup tuple-layout
 149             [ add-depends-on-tuple-layout ]
 150             [ [ "boa-check" word-prop [ ] or ] dip ] 2bi
 151             '[ @ _ <tuple-boa> ]
 152             ] }
 153         [ \ boa time-bomb ]
 154     } cond
 155 ] 1 define-transform
 156
 157 \ boa t "no-compile" set-word-prop