basis/syndication/syndication.factor

   1 ! Copyright (C) 2006 Chris Double, Daniel Ehrenberg.
   2 ! Portions copyright (C) 2008, 2009 Slava Pestov.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: xml.traversal kernel assocs math.order strings sequences
   5 xml.data xml.writer io.streams.string combinators xml
   6 xml.entities.html io.files io http.client namespaces make
   7 xml.syntax hashtables calendar.format accessors continuations
   8 urls present byte-arrays ;
   9 IN: syndication
  10
  11 : any-tag-named ( tag names -- tag-inside )
  12     [ f ] 2dip [ tag-named nip dup ] with find 2drop ;
  13
  14 TUPLE: feed title url entries ;
  15
  16 : <feed> ( -- feed ) feed new ;
  17
  18 TUPLE: entry title url description date ;
  19
  20 : set-entries ( feed entries -- feed )
  21     [ dup url>> ] dip
  22     [ [ derive-url ] change-url ] with map
  23     >>entries ;
  24
  25 : <entry> ( -- entry ) entry new ;
  26
  27 : try-parsing-timestamp ( string -- timestamp )
  28     [ rfc822>timestamp ] [ drop rfc3339>timestamp ] recover ;
  29
  30 : rss1.0-entry ( tag -- entry )
  31     entry new
  32     swap {
  33         [ "title" tag-named children>string >>title ]
  34         [ "link" tag-named children>string >url >>url ]
  35         [ "description" tag-named children>string >>description ]
  36         [
  37             f "date" "http://purl.org/dc/elements/1.1/" <name>
  38             tag-named dup [ children>string try-parsing-timestamp ] when
  39             >>date
  40         ]
  41     } cleave ;
  42
  43 : rss1.0 ( xml -- feed )
  44     feed new
  45     swap [
  46         "channel" tag-named
  47         [ "title" tag-named children>string >>title ]
  48         [ "link" tag-named children>string >url >>url ] bi
  49     ] [ "item" tags-named [ rss1.0-entry ] map set-entries ] bi ;
  50
  51 : rss2.0-entry ( tag -- entry )
  52     entry new
  53     swap {
  54         [ "title" tag-named children>string >>title ]
  55         [ { "link" "guid" } any-tag-named children>string >url >>url ]
  56         [ { "description" "encoded" } any-tag-named children>string >>description ]
  57         [
  58             { "date" "pubDate" } any-tag-named
  59             children>string try-parsing-timestamp >>date
  60         ]
  61     } cleave ;
  62
  63 : rss2.0 ( xml -- feed )
  64     feed new
  65     swap
  66     "channel" tag-named
  67     [ "title" tag-named children>string >>title ]
  68     [ "link" tag-named children>string >url >>url ]
  69     [ "item" tags-named [ rss2.0-entry ] map set-entries ]
  70     tri ;
  71
  72 : atom-entry-link ( tag -- url/f )
  73     "link" tags-named [ "rel" attr "alternate" = ] find nip
  74     dup [ "href" attr >url ] when ;
  75
  76 : atom1.0-entry ( tag -- entry )
  77     entry new
  78     swap {
  79         [ "title" tag-named children>string >>title ]
  80         [ atom-entry-link >>url ]
  81         [
  82             { "content" "summary" } any-tag-named
  83             dup children>> [ string? not ] any?
  84             [ children>> xml>string ]
  85             [ children>string ] if >>description
  86         ]
  87         [
  88             { "published" "updated" "issued" "modified" }
  89             any-tag-named children>string try-parsing-timestamp
  90             >>date
  91         ]
  92     } cleave ;
  93
  94 : atom1.0 ( xml -- feed )
  95     feed new
  96     swap
  97     [ "title" tag-named children>string >>title ]
  98     [ "link" tag-named "href" attr >url >>url ]
  99     [ "entry" tags-named [ atom1.0-entry ] map set-entries ]
 100     tri ;
 101
 102 : xml>feed ( xml -- feed )
 103     dup main>> {
 104         { "RDF" [ rss1.0 ] }
 105         { "rss" [ rss2.0 ] }
 106         { "feed" [ atom1.0 ] }
 107     } case ;
 108
 109 GENERIC: parse-feed ( seq -- feed )
 110
 111 M: string parse-feed [ string>xml xml>feed ] with-html-entities ;
 112
 113 M: byte-array parse-feed [ bytes>xml xml>feed ] with-html-entities ;
 114
 115 : download-feed ( url -- feed )
 116     #! Retrieve an news syndication file, return as a feed tuple.
 117     http-get nip parse-feed ;
 118
 119 ! Atom generation
 120
 121 : entry>xml ( entry -- xml )
 122     {
 123         [ title>> ]
 124         [ url>> present ]
 125         [ date>> timestamp>rfc3339 ]
 126         [ description>> ]
 127     } cleave
 128     [XML
 129         <entry>
 130             <title type="html"><-></title>
 131             <link href=<-> />
 132             <published><-></published>
 133             <content type="html"><-></content>
 134         </entry>
 135     XML] ;
 136
 137 : feed>xml ( feed -- xml )
 138     [ title>> ]
 139     [ url>> present ]
 140     [ entries>> [ entry>xml ] map ] tri
 141     <XML
 142         <feed xmlns="http://www.w3.org/2005/Atom">
 143             <title><-></title>
 144             <link href=<-> />
 145             <->
 146         </feed>
 147     XML> ;