basis/syndication/syndication.factor

   1 ! Copyright (C) 2006 Chris Double, Daniel Ehrenberg.
   2 ! Portions copyright (C) 2008, 2009 Slava Pestov.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: xml.traversal kernel assocs math.order strings sequences
   5 xml.data xml.writer io.streams.string combinators xml
   6 xml.entities.html io.files io http.client namespaces make
   7 xml.syntax hashtables calendar.format accessors continuations
   8 urls present byte-arrays ;
   9 IN: syndication
  10
  11 : any-tag-named ( tag names -- tag-inside )
  12     [ f ] 2dip [ tag-named nip dup ] with find 2drop ;
  13
  14 TUPLE: feed title url entries ;
  15
  16 : <feed> ( -- feed ) feed new ;
  17
  18 TUPLE: entry title url description date ;
  19
  20 : set-entries ( feed entries -- feed )
  21     [ dup url>> ] dip
  22     [ [ derive-url ] change-url ] with map
  23     >>entries ;
  24
  25 : <entry> ( -- entry ) entry new ;
  26
  27 : try-parsing-timestamp ( string -- timestamp )
  28     [ rfc822>timestamp ] [ drop rfc3339>timestamp ] recover ;
  29
  30 : rss1.0-entry ( tag -- entry )
  31     <entry> swap {
  32         [ "title" tag-named children>string >>title ]
  33         [ "link" tag-named children>string >url >>url ]
  34         [ "description" tag-named children>string >>description ]
  35         [
  36             f "date" "http://purl.org/dc/elements/1.1/" <name>
  37             tag-named dup [ children>string try-parsing-timestamp ] when
  38             >>date
  39         ]
  40     } cleave ;
  41
  42 : rss1.0 ( xml -- feed )
  43     <feed> swap [
  44         "channel" tag-named
  45         [ "title" tag-named children>string >>title ]
  46         [ "link" tag-named children>string >url >>url ] bi
  47     ] [ "item" tags-named [ rss1.0-entry ] map set-entries ] bi ;
  48
  49 : rss2.0-entry ( tag -- entry )
  50     <entry> swap {
  51         [ "title" tag-named children>string >>title ]
  52         [ { "link" "guid" } any-tag-named children>string >url >>url ]
  53         [ { "description" "encoded" } any-tag-named children>string >>description ]
  54         [
  55             { "date" "pubDate" } any-tag-named
  56             children>string try-parsing-timestamp >>date
  57         ]
  58     } cleave ;
  59
  60 : rss2.0 ( xml -- feed )
  61     <feed> swap
  62     "channel" tag-named
  63     [ "title" tag-named children>string >>title ]
  64     [ "link" tag-named children>string >url >>url ]
  65     [ "item" tags-named [ rss2.0-entry ] map set-entries ]
  66     tri ;
  67
  68 : atom-entry-link ( tag -- url/f )
  69     "link" tags-named
  70     [ "rel" attr { f "alternate" } member? ] find nip
  71     dup [ "href" attr >url ] when ;
  72
  73 : atom1.0-entry ( tag -- entry )
  74     <entry> swap {
  75         [ "title" tag-named children>string >>title ]
  76         [ atom-entry-link >>url ]
  77         [
  78             { "content" "summary" } any-tag-named
  79             dup children>> [ string? not ] any?
  80             [ children>> xml>string ]
  81             [ children>string ] if >>description
  82         ]
  83         [
  84             { "published" "updated" "issued" "modified" }
  85             any-tag-named children>string try-parsing-timestamp
  86             >>date
  87         ]
  88     } cleave ;
  89
  90 : atom1.0 ( xml -- feed )
  91     <feed> swap
  92     [ "title" tag-named children>string >>title ]
  93     [ "link" tag-named "href" attr >url >>url ]
  94     [ "entry" tags-named [ atom1.0-entry ] map set-entries ]
  95     tri ;
  96
  97 : xml>feed ( xml -- feed )
  98     dup main>> {
  99         { "RDF" [ rss1.0 ] }
 100         { "rss" [ rss2.0 ] }
 101         { "feed" [ atom1.0 ] }
 102     } case ;
 103
 104 GENERIC: parse-feed ( seq -- feed )
 105
 106 M: string parse-feed [ string>xml xml>feed ] with-html-entities ;
 107
 108 M: byte-array parse-feed [ bytes>xml xml>feed ] with-html-entities ;
 109
 110 : download-feed ( url -- feed )
 111     #! Retrieve an news syndication file, return as a feed tuple.
 112     http-get nip parse-feed ;
 113
 114 ! Atom generation
 115
 116 : entry>xml ( entry -- xml )
 117     {
 118         [ title>> ]
 119         [ url>> present ]
 120         [ date>> timestamp>rfc3339 ]
 121         [ description>> ]
 122     } cleave
 123     [XML
 124         <entry>
 125             <title type="html"><-></title>
 126             <link href=<-> />
 127             <published><-></published>
 128             <content type="html"><-></content>
 129         </entry>
 130     XML] ;
 131
 132 : feed>xml ( feed -- xml )
 133     [ title>> ]
 134     [ url>> present ]
 135     [ entries>> [ entry>xml ] map ] tri
 136     <XML
 137         <feed xmlns="http://www.w3.org/2005/Atom">
 138             <title><-></title>
 139             <link href=<-> />
 140             <->
 141         </feed>
 142     XML> ;