basis/system-info/macosx/macosx.factor

   1 ! Copyright (C) 2008 Doug Coleman, John Benediktsson.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien.c-types alien.data alien.strings alien.syntax arrays
   4 assocs byte-arrays core-foundation endian io.encodings.utf8 kernel
   5 libc sequences splitting system system-info unix.sysctl unix.users ;
   6 IN: system-info.macosx
   7
   8 <PRIVATE
   9
  10 TYPEDEF: SInt16 OSErr
  11 TYPEDEF: UInt32 OSType
  12 FUNCTION: OSErr Gestalt ( OSType selector, SInt32* response )
  13
  14 : gestalt ( selector -- response )
  15     { SInt32 } [ Gestalt 0 assert= ] with-out-parameters ;
  16
  17 : system-version ( -- n ) "sysv" be> gestalt ;
  18 : system-version-major ( -- n ) "sys1" be> gestalt ;
  19 : system-version-minor ( -- n ) "sys2" be> gestalt ;
  20 : system-version-bugfix ( -- n ) "sys3" be> gestalt ;
  21
  22 CONSTANT: system-code-names H{
  23     { { 12 0 } "Monterey" }
  24     { { 11 0 } "Big Sur" }
  25     { { 10 16 } "Big Sur" }
  26     { { 10 15 } "Catalina" }
  27     { { 10 14 } "Mojave" }
  28     { { 10 13 } "High Sierra" }
  29     { { 10 12 } "Sierra" }
  30     { { 10 11 } "El Capitan" }
  31     { { 10 10 } "Yosemite" }
  32     { { 10 9 } "Mavericks" }
  33     { { 10 8 } "Mountain Lion" }
  34     { { 10 7 } "Lion" }
  35     { { 10 6 } "Snow Leopard" }
  36     { { 10 5 } "Leopard" }
  37     { { 10 4 } "Tiger" }
  38     { { 10 3 } "Panther" }
  39     { { 10 2 } "Jaguar" }
  40     { { 10 1 } "Puma" }
  41     { { 10 0 } "Cheetah" }
  42 }
  43
  44 : system-code-name ( -- str/f )
  45     system-version-major
  46     dup 10 = [ system-version-minor ] [ 0 ] if 2array
  47     system-code-names at ;
  48
  49 PRIVATE>
  50
  51 M: macosx os-version
  52     system-version-major
  53     system-version-minor
  54     system-version-bugfix 3array ;
  55
  56 ! See /usr/include/sys/sysctl.h for constants
  57
  58 : machine ( -- str ) { 6 1 } sysctl-query-string ;
  59 : model ( -- str ) { 6 2 } sysctl-query-string ;
  60 M: macosx cpus { 6 3 } sysctl-query-uint ;
  61 : byte-order ( -- n ) { 6 4 } sysctl-query-uint ;
  62
  63 ! Only an int, not large enough. Deprecated.
  64 ! M: macosx physical-mem { 6 5 } sysctl-query-int ;
  65 ! : user-mem ( -- n ) { 6 6 } sysctl-query-uint ;
  66
  67 : page-size ( -- n ) { 6 7 } sysctl-query-uint ;
  68 : disknames ( -- n ) { 6 8 } 8 sysctl-query ;
  69 : diskstats ( -- n ) { 6 9 } 8 sysctl-query ;
  70 : epoch ( -- n ) { 6 10 } sysctl-query-uint ;
  71 : floating-point ( -- n ) { 6 11 } sysctl-query-uint ;
  72 : machine-arch ( -- n ) { 6 12 } sysctl-query-string ;
  73 : vector-unit ( -- n ) { 6 13 } sysctl-query-uint ;
  74 : bus-frequency ( -- n ) { 6 14 } sysctl-query-uint ;
  75 M: macosx cpu-mhz { 6 15 } sysctl-query-uint ;
  76 : cacheline-size ( -- n ) { 6 16 } sysctl-query-uint ;
  77 : l1-icache-size ( -- n ) { 6 17 } sysctl-query-uint ;
  78 : l1-dcache-size ( -- n ) { 6 18 } sysctl-query-uint ;
  79 : l2-cache-settings ( -- n ) { 6 19 } sysctl-query-uint ;
  80 : l2-cache-size ( -- n ) { 6 20 } sysctl-query-uint ;
  81 : l3-cache-settings ( -- n ) { 6 21 } sysctl-query-uint ;
  82 : l3-cache-size ( -- n ) { 6 22 } sysctl-query-uint ;
  83 : tb-frequency ( -- n ) { 6 23 } sysctl-query-uint ;
  84 M: macosx physical-mem { 6 24 } sysctl-query-ulonglong ;
  85 : available-cpus ( -- n ) { 6 25 } sysctl-query-uint ;
  86
  87 M: macosx computer-name { 1 10 } sysctl-query-string "." split1 drop ;
  88 M: macosx username real-user-name ;