basis/system-info/windows/windows.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.strings byte-arrays
   4 classes.struct combinators kernel math namespaces
   5 specialized-arrays system
   6 system-info.backend vocabs.loader windows windows.advapi32
   7 windows.errors windows.kernel32 words ;
   8 SPECIALIZED-ARRAY: ushort
   9 IN: system-info.windows
  10
  11 : system-info ( -- SYSTEM_INFO )
  12     SYSTEM_INFO <struct> [ GetSystemInfo ] keep ;
  13
  14 : page-size ( -- n )
  15     system-info dwPageSize>> ;
  16
  17 ! 386, 486, 586, 2200 (IA64), 8664 (AMD_X8664)
  18 : processor-type ( -- n )
  19     system-info dwProcessorType>> ;
  20
  21 ! 0 = x86, 6 = Intel Itanium, 9 = x64 (AMD or Intel), 10 = WOW64, 0xffff = Unk
  22 : processor-architecture ( -- n )
  23     system-info dwOemId>> HEX: ffff0000 bitand ;
  24
  25 : os-version ( -- os-version )
  26     OSVERSIONINFO <struct>
  27         OSVERSIONINFO heap-size >>dwOSVersionInfoSize
  28     dup GetVersionEx win32-error=0/f ;
  29
  30 : windows-major ( -- n )
  31     os-version dwMajorVersion>> ;
  32
  33 : windows-minor ( -- n )
  34     os-version dwMinorVersion>> ;
  35
  36 : windows-build# ( -- n )
  37     os-version dwBuildNumber>> ;
  38
  39 : windows-platform-id ( -- n )
  40     os-version dwPlatformId>> ;
  41
  42 : windows-service-pack ( -- string )
  43     os-version szCSDVersion>> alien>native-string ;
  44
  45 : feature-present? ( n -- ? )
  46     IsProcessorFeaturePresent zero? not ;
  47
  48 : sse2? ( -- ? )
  49     PF_XMMI64_INSTRUCTIONS_AVAILABLE feature-present? ;
  50
  51 : sse3? ( -- ? )
  52     PF_SSE3_INSTRUCTIONS_AVAILABLE feature-present? ;
  53
  54 : get-directory ( word -- str )
  55     [ MAX_UNICODE_PATH [ <ushort-array> ] keep dupd ] dip
  56     execute win32-error=0/f alien>native-string ; inline
  57
  58 : windows-directory ( -- str )
  59     \ GetWindowsDirectory get-directory ;
  60
  61 : system-directory ( -- str )
  62     \ GetSystemDirectory get-directory ;
  63
  64 : system-windows-directory ( -- str )
  65     \ GetSystemWindowsDirectory get-directory ;
  66
  67 M: winnt cpus ( -- n )
  68     system-info dwNumberOfProcessors>> ;
  69
  70 : memory-status ( -- MEMORYSTATUSEX )
  71     MEMORYSTATUSEX <struct>
  72     MEMORYSTATUSEX heap-size >>dwLength
  73     dup GlobalMemoryStatusEx win32-error=0/f ;
  74
  75 M: winnt memory-load ( -- n )
  76     memory-status dwMemoryLoad>> ;
  77
  78 M: winnt physical-mem ( -- n )
  79     memory-status ullTotalPhys>> ;
  80
  81 M: winnt available-mem ( -- n )
  82     memory-status ullAvailPhys>> ;
  83
  84 M: winnt total-page-file ( -- n )
  85     memory-status ullTotalPageFile>> ;
  86
  87 M: winnt available-page-file ( -- n )
  88     memory-status ullAvailPageFile>> ;
  89
  90 M: winnt total-virtual-mem ( -- n )
  91     memory-status ullTotalVirtual>> ;
  92
  93 M: winnt available-virtual-mem ( -- n )
  94     memory-status ullAvailVirtual>> ;
  95
  96 : computer-name ( -- string )
  97     MAX_COMPUTERNAME_LENGTH 1 +
  98     [ <byte-array> dup ] keep <uint>
  99     GetComputerName win32-error=0/f alien>native-string ;
 100
 101 : username ( -- string )
 102     UNLEN 1 +
 103     [ <byte-array> dup ] keep <uint>
 104     GetUserName win32-error=0/f alien>native-string ;