basis/tools/crossref/crossref.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: words assocs definitions io io.pathnames io.styles kernel
   4 prettyprint sorting see sets sequences arrays hashtables help
   5 help.crossref help.topics help.markup quotations accessors
   6 source-files namespaces graphs vocabs generic generic.single
   7 threads compiler.units init combinators.smart ;
   8 IN: tools.crossref
   9
  10 SYMBOL: crossref
  11
  12 GENERIC: uses ( defspec -- seq )
  13
  14 <PRIVATE
  15
  16 SYMBOL: visited
  17
  18 GENERIC# quot-uses 1 ( obj assoc -- )
  19
  20 M: object quot-uses 2drop ;
  21
  22 M: word quot-uses over crossref? [ conjoin ] [ 2drop ] if ;
  23
  24 : (seq-uses) ( seq assoc -- )
  25     [ quot-uses ] curry each ;
  26
  27 : seq-uses ( seq assoc -- )
  28     over visited get member-eq? [ 2drop ] [
  29         over visited get push
  30         (seq-uses)
  31     ] if ;
  32
  33 : assoc-uses ( assoc' assoc -- )
  34     over visited get member-eq? [ 2drop ] [
  35         over visited get push
  36         [ >alist ] dip (seq-uses)
  37     ] if ;
  38
  39 M: array quot-uses seq-uses ;
  40
  41 M: hashtable quot-uses assoc-uses ;
  42
  43 M: callable quot-uses seq-uses ;
  44
  45 M: wrapper quot-uses [ wrapped>> ] dip quot-uses ;
  46
  47 M: callable uses ( quot -- assoc )
  48     V{ } clone visited [
  49         H{ } clone [ quot-uses ] keep keys
  50     ] with-variable ;
  51
  52 M: word uses def>> uses ;
  53
  54 M: link uses
  55     [ { $subsection $subsections $link $see-also } article-links [ >link ] map ]
  56     [ { $vocab-link } article-links [ >vocab-link ] map ]
  57     bi append ;
  58
  59 M: pathname uses string>> source-file top-level-form>> [ uses ] [ { } ] if* ;
  60
  61 ! To make UI browser happy
  62 M: vocab uses drop f ;
  63
  64 : crossref-def ( defspec -- )
  65     dup uses crossref get add-vertex ;
  66
  67 : defs-to-crossref ( -- seq )
  68     [
  69         all-words
  70         [ [ generic? not ] filter ]
  71         [ [ subwords ] map concat ] bi
  72
  73         all-articles [ >link ] map
  74
  75         source-files get keys [ <pathname> ] map
  76     ] append-outputs ;
  77
  78 : build-crossref ( -- crossref )
  79     "Computing usage index... " write flush yield
  80     H{ } clone [
  81         crossref set-global
  82         defs-to-crossref [ crossref-def ] each
  83     ] keep
  84     "done" print flush ;
  85
  86 : get-crossref ( -- crossref )
  87     crossref get-global [ build-crossref ] unless* ;
  88
  89 GENERIC: irrelevant? ( defspec -- ? )
  90
  91 M: object irrelevant? drop f ;
  92
  93 M: default-method irrelevant? drop t ;
  94
  95 M: predicate-engine irrelevant? drop t ;
  96
  97 PRIVATE>
  98
  99 : usage ( defspec -- seq ) get-crossref at keys ;
 100
 101 GENERIC: smart-usage ( defspec -- seq )
 102
 103 M: object smart-usage usage [ irrelevant? not ] filter ;
 104
 105 M: method smart-usage "method-generic" word-prop smart-usage ;
 106
 107 M: f smart-usage drop \ f smart-usage ;
 108
 109 : synopsis-alist ( definitions -- alist )
 110     [ [ synopsis ] keep ] { } map>assoc ;
 111
 112 : definitions. ( alist -- )
 113     [ write-object nl ] assoc-each ;
 114
 115 : sorted-definitions. ( definitions -- )
 116     synopsis-alist sort-keys definitions. ;
 117
 118 : usage. ( word -- )
 119     smart-usage
 120     [ "No usages." print ] [ sorted-definitions. ] if-empty ;
 121
 122 : vocab-xref ( vocab quot -- vocabs )
 123     [ [ vocab-name ] [ words [ generic? not ] filter ] bi ] dip map
 124     [
 125         [ [ word? ] [ generic? not ] bi and ] filter [
 126             dup method?
 127             [ "method-generic" word-prop ] when
 128             vocabulary>>
 129         ] map
 130     ] gather natural-sort remove sift ; inline
 131
 132 : vocabs. ( seq -- )
 133     [ dup >vocab-link write-object nl ] each ;
 134
 135 : vocab-uses ( vocab -- vocabs ) [ uses ] vocab-xref ;
 136
 137 : vocab-uses. ( vocab -- ) vocab-uses vocabs. ;
 138
 139 : vocab-usage ( vocab -- vocabs ) [ usage ] vocab-xref ;
 140
 141 : vocab-usage. ( vocab -- ) vocab-usage vocabs. ;
 142
 143 <PRIVATE
 144
 145 SINGLETON: invalidate-crossref
 146
 147 M: invalidate-crossref definitions-changed 2drop crossref global delete-at ;
 148
 149 [ invalidate-crossref add-definition-observer ] "tools.crossref" add-startup-hook
 150
 151 PRIVATE>