basis/tools/crossref/crossref.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: words assocs definitions io io.pathnames io.styles kernel
   4 prettyprint sorting see sets sequences arrays hashtables help.crossref
   5 help.topics help.markup quotations accessors source-files namespaces
   6 graphs vocabs generic generic.standard.engines.tuple threads
   7 compiler.units init ;
   8 IN: tools.crossref
   9
  10 SYMBOL: crossref
  11
  12 GENERIC: uses ( defspec -- seq )
  13
  14 <PRIVATE
  15
  16 SYMBOL: visited
  17
  18 GENERIC# quot-uses 1 ( obj assoc -- )
  19
  20 M: object quot-uses 2drop ;
  21
  22 M: word quot-uses over crossref? [ conjoin ] [ 2drop ] if ;
  23
  24 : (seq-uses) ( seq assoc -- )
  25     [ quot-uses ] curry each ;
  26
  27 : seq-uses ( seq assoc -- )
  28     over visited get memq? [ 2drop ] [
  29         over visited get push
  30         (seq-uses)
  31     ] if ;
  32
  33 : assoc-uses ( assoc' assoc -- )
  34     over visited get memq? [ 2drop ] [
  35         over visited get push
  36         [ >alist ] dip (seq-uses)
  37     ] if ;
  38
  39 M: array quot-uses seq-uses ;
  40
  41 M: hashtable quot-uses assoc-uses ;
  42
  43 M: callable quot-uses seq-uses ;
  44
  45 M: wrapper quot-uses [ wrapped>> ] dip quot-uses ;
  46
  47 M: callable uses ( quot -- assoc )
  48     V{ } clone visited [
  49         H{ } clone [ quot-uses ] keep keys
  50     ] with-variable ;
  51
  52 M: word uses def>> uses ;
  53
  54 M: link uses { $subsection $link $see-also } article-links ;
  55
  56 M: pathname uses string>> source-file top-level-form>> [ uses ] [ { } ] if* ;
  57
  58 GENERIC: crossref-def ( defspec -- )
  59
  60 M: object crossref-def
  61     dup uses crossref get add-vertex ;
  62
  63 M: word crossref-def
  64     [ call-next-method ] [ subwords [ crossref-def ] each ] bi ;
  65
  66 : build-crossref ( -- crossref )
  67     "Computing usage index... " write flush yield
  68     H{ } clone crossref [
  69         all-words
  70         source-files get keys [ <pathname> ] map
  71         [ [ crossref-def ] each ] bi@
  72         crossref get
  73     ] with-variable
  74     "done" print flush ;
  75
  76 : get-crossref ( -- crossref )
  77     crossref global [ drop build-crossref ] cache ;
  78
  79 GENERIC: irrelevant? ( defspec -- ? )
  80
  81 M: object irrelevant? drop f ;
  82
  83 M: default-method irrelevant? drop t ;
  84
  85 M: engine-word irrelevant? drop t ;
  86
  87 PRIVATE>
  88
  89 : usage ( defspec -- seq ) get-crossref at keys ;
  90
  91 GENERIC: smart-usage ( defspec -- seq )
  92
  93 M: object smart-usage usage [ irrelevant? not ] filter ;
  94
  95 M: method-body smart-usage "method-generic" word-prop smart-usage ;
  96
  97 M: f smart-usage drop \ f smart-usage ;
  98
  99 : synopsis-alist ( definitions -- alist )
 100     [ [ synopsis ] keep ] { } map>assoc ;
 101
 102 : definitions. ( alist -- )
 103     [ write-object nl ] assoc-each ;
 104
 105 : sorted-definitions. ( definitions -- )
 106     synopsis-alist sort-keys definitions. ;
 107
 108 : usage. ( word -- )
 109     smart-usage sorted-definitions. ;
 110
 111 : vocab-xref ( vocab quot -- vocabs )
 112     [ [ vocab-name ] [ words [ generic? not ] filter ] bi ] dip map
 113     [
 114         [ [ word? ] [ generic? not ] bi and ] filter [
 115             dup method-body?
 116             [ "method-generic" word-prop ] when
 117             vocabulary>>
 118         ] map
 119     ] gather natural-sort remove sift ; inline
 120
 121 : vocabs. ( seq -- )
 122     [ dup >vocab-link write-object nl ] each ;
 123
 124 : vocab-uses ( vocab -- vocabs ) [ uses ] vocab-xref ;
 125
 126 : vocab-uses. ( vocab -- ) vocab-uses vocabs. ;
 127
 128 : vocab-usage ( vocab -- vocabs ) [ usage ] vocab-xref ;
 129
 130 : vocab-usage. ( vocab -- ) vocab-usage vocabs. ;
 131
 132 <PRIVATE
 133
 134 SINGLETON: invalidate-crossref
 135
 136 M: invalidate-crossref definitions-changed 2drop crossref global delete-at ;
 137
 138 [ invalidate-crossref add-definition-observer ] "tools.crossref" add-init-hook
 139
 140 PRIVATE>