basis/tools/crossref/crossref.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: words assocs definitions io io.pathnames io.styles kernel
   4 prettyprint sorting see sets sequences arrays hashtables help
   5 help.crossref help.topics help.markup quotations accessors
   6 source-files namespaces graphs vocabs generic generic.single
   7 threads compiler.units init combinators.smart ;
   8 IN: tools.crossref
   9
  10 SYMBOL: crossref
  11
  12 GENERIC: uses ( defspec -- seq )
  13
  14 <PRIVATE
  15
  16 SYMBOL: visited
  17
  18 GENERIC# quot-uses 1 ( obj assoc -- )
  19
  20 M: object quot-uses 2drop ;
  21
  22 M: word quot-uses over crossref? [ conjoin ] [ 2drop ] if ;
  23
  24 : seq-uses ( seq assoc -- )
  25     over visited get member-eq? [ 2drop ] [
  26         over visited get push
  27         [ quot-uses ] curry each
  28     ] if ;
  29
  30 : assoc-uses ( assoc' assoc -- )
  31     over visited get member-eq? [ 2drop ] [
  32         over visited get push
  33         [ quot-uses ] curry [ bi@ ] curry assoc-each
  34     ] if ;
  35
  36 M: array quot-uses seq-uses ;
  37
  38 M: hashtable quot-uses assoc-uses ;
  39
  40 M: callable quot-uses seq-uses ;
  41
  42 M: wrapper quot-uses [ wrapped>> ] dip quot-uses ;
  43
  44 M: callable uses ( quot -- assoc )
  45     V{ } clone visited [
  46         H{ } clone [ quot-uses ] keep keys
  47     ] with-variable ;
  48
  49 M: word uses def>> uses ;
  50
  51 M: link uses
  52     [ { $subsection $subsections $link $see-also } article-links [ >link ] map ]
  53     [ { $vocab-link } article-links [ >vocab-link ] map ]
  54     bi append ;
  55
  56 M: pathname uses string>> source-file top-level-form>> [ uses ] [ { } ] if* ;
  57
  58 ! To make UI browser happy
  59 M: vocab uses drop f ;
  60
  61 : crossref-def ( defspec -- )
  62     dup uses crossref get-global add-vertex ;
  63
  64 : defs-to-crossref ( -- seq )
  65     [
  66         all-words
  67         [ [ generic? not ] filter ]
  68         [ [ subwords ] map concat ] bi
  69
  70         all-articles [ >link ] map
  71
  72         source-files get keys [ <pathname> ] map
  73     ] append-outputs ;
  74
  75 : build-crossref ( -- crossref )
  76     "Computing usage index... " write flush yield
  77     H{ } clone [
  78         crossref set-global
  79         defs-to-crossref [ crossref-def ] each
  80     ] keep
  81     "done" print flush ;
  82
  83 : get-crossref ( -- crossref )
  84     crossref get-global [ build-crossref ] unless* ;
  85
  86 GENERIC: irrelevant? ( defspec -- ? )
  87
  88 M: object irrelevant? drop f ;
  89
  90 M: default-method irrelevant? drop t ;
  91
  92 M: predicate-engine irrelevant? drop t ;
  93
  94 PRIVATE>
  95
  96 : usage ( defspec -- seq ) get-crossref at keys ;
  97
  98 GENERIC: smart-usage ( defspec -- seq )
  99
 100 M: object smart-usage usage [ irrelevant? not ] filter ;
 101
 102 M: method smart-usage "method-generic" word-prop smart-usage ;
 103
 104 M: f smart-usage drop \ f smart-usage ;
 105
 106 : synopsis-alist ( definitions -- alist )
 107     [ [ synopsis ] keep ] { } map>assoc ;
 108
 109 : definitions. ( alist -- )
 110     [ write-object nl ] assoc-each ;
 111
 112 : sorted-definitions. ( definitions -- )
 113     synopsis-alist sort-keys definitions. ;
 114
 115 : usage. ( word -- )
 116     smart-usage
 117     [ "No usages." print ] [ sorted-definitions. ] if-empty ;
 118
 119 : vocab-xref ( vocab quot: ( defspec -- seq ) -- vocabs )
 120     [ [ vocab-name ] [ words [ generic? not ] filter ] bi ] dip map
 121     [
 122         [ [ word? ] [ generic? not ] bi and ] filter [
 123             dup method?
 124             [ "method-generic" word-prop ] when
 125             vocabulary>>
 126         ] map
 127     ] gather natural-sort remove sift ; inline
 128
 129 : vocabs. ( seq -- )
 130     [ dup >vocab-link write-object nl ] each ;
 131
 132 : vocab-uses ( vocab -- vocabs ) [ uses ] vocab-xref ;
 133
 134 : vocab-uses. ( vocab -- ) vocab-uses vocabs. ;
 135
 136 : vocab-usage ( vocab -- vocabs ) [ usage ] vocab-xref ;
 137
 138 : vocab-usage. ( vocab -- ) vocab-usage vocabs. ;
 139
 140 <PRIVATE
 141
 142 SINGLETON: invalidate-crossref
 143
 144 M: invalidate-crossref definitions-changed 2drop crossref global delete-at ;
 145
 146 [ invalidate-crossref add-definition-observer ] "tools.crossref" add-startup-hook
 147
 148 PRIVATE>