basis/tools/disassembler/disassembler.factor

   1 ! Copyright (C) 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien alien.data arrays byte-arrays compiler.units destructors
   4 io kernel libc math quotations sequences stack-checker system tr
   5 vocabs words ;
   6 IN: tools.disassembler
   7
   8 GENERIC: disassemble ( obj -- )
   9
  10 <PRIVATE
  11
  12 SYMBOL: disassembler-backend
  13
  14 HOOK: disassemble* disassembler-backend ( from to -- lines )
  15
  16 TR: tabs>spaces "\t" "\s" ;
  17
  18 GENERIC: (>address) ( object -- n )
  19
  20 M: integer (>address) ;
  21 M: alien (>address) alien-address ;
  22
  23 PRIVATE>
  24
  25 M: byte-array disassemble
  26     [
  27         [ malloc-byte-array &free alien-address dup ]
  28         [ length + ] bi
  29         2array disassemble
  30     ] with-destructors ;
  31
  32 M: pair disassemble first2 [ (>address) ] bi@ disassemble* [ tabs>spaces print ] each ;
  33
  34 M: word disassemble word-code 2array disassemble ;
  35
  36 M: quotation disassemble [ dup infer define-temp ] with-compilation-unit disassemble ;
  37
  38 cpu x86?
  39 "tools.disassembler.udis"
  40 "tools.disassembler.gdb" ?
  41 require