basis/tools/disassembler/udis/udis.factor

   1 ! Copyright (C) 2008 Slava Pestov, Jorge Acereda Macia.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: tools.disassembler namespaces combinators
   4 alien alien.syntax alien.c-types lexer parser kernel
   5 sequences layouts math math.parser system make fry arrays ;
   6 IN: tools.disassembler.udis
   7
   8 <<
   9 "libudis86" {
  10     { [ os macosx? ] [ "libudis86.0.dylib" ] }
  11     { [ os unix? ] [ "libudis86.so.0" ] }
  12     { [ os winnt? ] [ "libudis86.dll" ] }
  13 } cond "cdecl" add-library
  14 >>
  15
  16 LIBRARY: libudis86
  17
  18 TYPEDEF: char[592] ud
  19
  20 FUNCTION: void ud_translate_intel ( ud* u ) ;
  21 FUNCTION: void ud_translate_att ( ud* u ) ;
  22
  23 : UD_SYN_INTEL    &: ud_translate_intel ; inline
  24 : UD_SYN_ATT      &: ud_translate_att ; inline
  25 : UD_EOI          -1 ; inline
  26 : UD_INP_CACHE_SZ 32 ; inline
  27 : UD_VENDOR_AMD   0 ; inline
  28 : UD_VENDOR_INTEL 1 ; inline
  29
  30 FUNCTION: void ud_init ( ud* u ) ;
  31 FUNCTION: void ud_set_mode ( ud* u, uint8_t mode ) ;
  32 FUNCTION: void ud_set_pc ( ud* u, ulonglong pc ) ;
  33 FUNCTION: void ud_set_input_buffer ( ud* u, uint8_t* offset, size_t size ) ;
  34 FUNCTION: void ud_set_vendor ( ud* u, uint vendor ) ;
  35 FUNCTION: void ud_set_syntax ( ud* u, void* syntax ) ;
  36 FUNCTION: void ud_input_skip ( ud* u, size_t size ) ;
  37 FUNCTION: int ud_input_end ( ud* u ) ;
  38 FUNCTION: uint ud_decode ( ud* u ) ;
  39 FUNCTION: uint ud_disassemble ( ud* u ) ;
  40 FUNCTION: char* ud_insn_asm ( ud* u ) ;
  41 FUNCTION: void* ud_insn_ptr ( ud* u ) ;
  42 FUNCTION: ulonglong ud_insn_off ( ud* u ) ;
  43 FUNCTION: char* ud_insn_hex ( ud* u ) ;
  44 FUNCTION: uint ud_insn_len ( ud* u ) ;
  45 FUNCTION: char* ud_lookup_mnemonic ( int c ) ;
  46
  47 : <ud> ( -- ud )
  48     "ud" <c-object>
  49     dup ud_init
  50     dup cell-bits ud_set_mode
  51     dup UD_SYN_INTEL ud_set_syntax ;
  52
  53 SINGLETON: udis-disassembler
  54
  55 : buf/len ( from to -- buf len ) [ drop <alien> ] [ swap - ] 2bi ;
  56
  57 : format-disassembly ( lines -- lines' )
  58     dup [ second length ] map supremum
  59     '[
  60         [
  61             [ first >hex cell 2 * CHAR: 0 pad-left % ": " % ]
  62             [ second _ CHAR: \s pad-right % "  " % ]
  63             [ third % ]
  64             tri
  65         ] "" make
  66     ] map ;
  67
  68 : (disassemble) ( ud -- lines )
  69     [
  70         dup '[
  71             _ ud_disassemble 0 =
  72             [ f ] [
  73                 _
  74                 [ ud_insn_off ]
  75                 [ ud_insn_hex ]
  76                 [ ud_insn_asm ]
  77                 tri 3array , t
  78             ] if
  79         ] loop
  80     ] { } make ;
  81
  82 M: udis-disassembler disassemble* ( from to -- buffer )
  83     [ <ud> ] 2dip {
  84         [ drop ud_set_pc ]
  85         [ buf/len ud_set_input_buffer ]
  86         [ 2drop (disassemble) format-disassembly ]
  87     } 3cleave ;
  88
  89 udis-disassembler disassembler-backend set-global