basis/tools/disassembler/udis/udis.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov, Jorge Acereda Macia.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: tools.disassembler namespaces combinators alien
   4 alien.syntax alien.c-types lexer parser kernel sequences layouts
   5 math math.order alien.libraries math.parser system make fry
   6 arrays libc destructors tools.memory tools.disassembler.utils
   7 tools.disassembler.private splitting alien.data classes.struct ;
   8 IN: tools.disassembler.udis
   9
  10 <<
  11 "libudis86" {
  12     { [ os macosx? ] [ "libudis86.0.dylib" ] }
  13     { [ os unix? ] [ "libudis86.so.0" ] }
  14     { [ os winnt? ] [ "libudis86.dll" ] }
  15 } cond "cdecl" add-library
  16 >>
  17
  18 LIBRARY: libudis86
  19
  20 STRUCT: ud_operand
  21     { type int }
  22     { size uchar }
  23     { lval ulonglong }
  24     { base int }
  25     { index int }
  26     { offset uchar }
  27     { scale uchar } ;
  28
  29 STRUCT: ud
  30     { inp_hook void* }
  31     { inp_curr uchar }
  32     { inp_fill uchar }
  33     { inp_file void* }
  34     { inp_ctr uchar }
  35     { inp_buff uchar* }
  36     { inp_buff_end uchar* }
  37     { inp_end uchar }
  38     { translator void* }
  39     { insn_offset ulonglong }
  40     { insn_hexcode char[32] }
  41     { insn_buffer char[64] }
  42     { insn_fill uint }
  43     { dis_mode uchar }
  44     { pc ulonglong }
  45     { vendor uchar }
  46     { mapen void* }
  47     { mnemonic int }
  48     { operand ud_operand[3] }
  49     { error uchar }
  50     { pfx_rex uchar }
  51     { pfx_seg uchar }
  52     { pfx_opr uchar }
  53     { pfx_adr uchar }
  54     { pfx_lock uchar }
  55     { pfx_rep uchar }
  56     { pfx_repe uchar }
  57     { pfx_repne uchar }
  58     { pfx_insn uchar }
  59     { default64 uchar }
  60     { opr_mode uchar }
  61     { adr_mode uchar }
  62     { br_far uchar }
  63     { br_near uchar }
  64     { implicit_addr uchar }
  65     { c1 uchar }
  66     { c2 uchar }
  67     { c3 uchar }
  68     { inp_cache uchar[256] }
  69     { inp_sess uchar[64] }
  70     { itab_entry void* } ;
  71
  72 FUNCTION: void ud_translate_intel ( ud* u ) ;
  73 FUNCTION: void ud_translate_att ( ud* u ) ;
  74
  75 : UD_SYN_INTEL ( -- addr ) &: ud_translate_intel ; inline
  76 : UD_SYN_ATT ( -- addr ) &: ud_translate_att ; inline
  77
  78 CONSTANT: UD_EOI          -1
  79 CONSTANT: UD_INP_CACHE_SZ 32
  80 CONSTANT: UD_VENDOR_AMD   0
  81 CONSTANT: UD_VENDOR_INTEL 1
  82
  83 FUNCTION: void ud_init ( ud* u ) ;
  84 FUNCTION: void ud_set_mode ( ud* u, uchar mode ) ;
  85 FUNCTION: void ud_set_pc ( ud* u, ulonglong pc ) ;
  86 FUNCTION: void ud_set_input_buffer ( ud* u, uchar* offset, size_t size ) ;
  87 FUNCTION: void ud_set_vendor ( ud* u, uint vendor ) ;
  88 FUNCTION: void ud_set_syntax ( ud* u, void* syntax ) ;
  89 FUNCTION: void ud_input_skip ( ud* u, size_t size ) ;
  90 FUNCTION: int ud_input_end ( ud* u ) ;
  91 FUNCTION: uint ud_decode ( ud* u ) ;
  92 FUNCTION: uint ud_disassemble ( ud* u ) ;
  93 FUNCTION: char* ud_insn_asm ( ud* u ) ;
  94 FUNCTION: void* ud_insn_ptr ( ud* u ) ;
  95 FUNCTION: ulonglong ud_insn_off ( ud* u ) ;
  96 FUNCTION: char* ud_insn_hex ( ud* u ) ;
  97 FUNCTION: uint ud_insn_len ( ud* u ) ;
  98 FUNCTION: char* ud_lookup_mnemonic ( int c ) ;
  99
 100 : <ud> ( -- ud )
 101     ud malloc-struct &free
 102     dup ud_init
 103     dup cell-bits ud_set_mode
 104     dup UD_SYN_INTEL ud_set_syntax ;
 105
 106 : with-ud ( quot: ( ud -- ) -- )
 107     [ [ [ <ud> ] dip call ] with-destructors ] with-code-blocks ; inline
 108
 109 SINGLETON: udis-disassembler
 110
 111 : buf/len ( from to -- buf len ) [ drop <alien> ] [ swap - ] 2bi ;
 112
 113 : resolve-call ( str -- str' ) "0x" split1-last [ resolve-xt append ] when* ;
 114
 115 : format-disassembly ( lines -- lines' )
 116     dup [ second length ] [ max ] map-reduce
 117     '[
 118         [
 119             [ first >hex cell 2 * CHAR: 0 pad-head % ": " % ]
 120             [ second _ CHAR: \s pad-tail % "  " % ]
 121             [ third resolve-call % ]
 122             tri
 123         ] "" make
 124     ] map ;
 125
 126 : (disassemble) ( ud -- lines )
 127     [
 128         dup '[
 129             _ ud_disassemble 0 =
 130             [ f ] [
 131                 _
 132                 [ ud_insn_off ]
 133                 [ ud_insn_hex ]
 134                 [ ud_insn_asm ]
 135                 tri 3array , t
 136             ] if
 137         ] loop
 138     ] { } make ;
 139
 140 M: udis-disassembler disassemble* ( from to -- buffer )
 141     '[
 142         _ _
 143         [ drop ud_set_pc ]
 144         [ buf/len ud_set_input_buffer ]
 145         [ 2drop (disassemble) format-disassembly ]
 146         3tri
 147     ] with-ud ;
 148
 149 udis-disassembler disassembler-backend set-global