basis/tools/disassembler/udis/udis.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov, Jorge Acereda Macia.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien alien.c-types alien.libraries alien.syntax arrays
   4 combinators destructors kernel layouts libc make math
   5 math.order math.parser namespaces sequences splitting system
   6 tools.disassembler.private tools.disassembler.utils tools.memory ;
   7 IN: tools.disassembler.udis
   8
   9 << "libudis86" {
  10     { [ os windows? ] [ "libudis86.dll" ] }
  11     { [ os macosx? ] [ "libudis86.dylib" ] }
  12     { [ os unix? ] [ "libudis86.so" ] }
  13 } cond cdecl add-library >>
  14
  15 LIBRARY: libudis86
  16
  17 TYPEDEF: void ud
  18
  19 FUNCTION: void ud_translate_intel ( ud* u )
  20 FUNCTION: void ud_translate_att ( ud* u )
  21
  22 : UD_SYN_INTEL ( -- addr ) &: ud_translate_intel ; inline
  23 : UD_SYN_ATT ( -- addr ) &: ud_translate_att ; inline
  24
  25 CONSTANT: UD_EOI          -1
  26 CONSTANT: UD_INP_CACHE_SZ 32
  27 CONSTANT: UD_VENDOR_AMD   0
  28 CONSTANT: UD_VENDOR_INTEL 1
  29
  30 FUNCTION: void ud_init ( ud* u )
  31 FUNCTION: void ud_set_mode ( ud* u, uchar mode )
  32 FUNCTION: void ud_set_pc ( ud* u, ulonglong pc )
  33 FUNCTION: void ud_set_input_buffer ( ud* u, c-string offset, size_t size )
  34 FUNCTION: void ud_set_vendor ( ud* u, uint vendor )
  35 FUNCTION: void ud_set_syntax ( ud* u, void* syntax )
  36 FUNCTION: void ud_input_skip ( ud* u, size_t size )
  37 FUNCTION: int ud_input_end ( ud* u )
  38 FUNCTION: uint ud_decode ( ud* u )
  39 FUNCTION: uint ud_disassemble ( ud* u )
  40 FUNCTION: c-string ud_insn_asm ( ud* u )
  41 FUNCTION: void* ud_insn_ptr ( ud* u )
  42 FUNCTION: ulonglong ud_insn_off ( ud* u )
  43 FUNCTION: c-string ud_insn_hex ( ud* u )
  44 FUNCTION: uint ud_insn_len ( ud* u )
  45 FUNCTION: c-string ud_lookup_mnemonic ( int c )
  46
  47 : <ud> ( -- ud )
  48     1,000 malloc &free
  49     dup ud_init
  50     dup cell-bits ud_set_mode
  51     dup UD_SYN_INTEL ud_set_syntax ;
  52
  53 : with-ud ( ..a quot: ( ..a ud -- ..b ) -- ..b )
  54     [ [ [ <ud> ] dip call ] with-destructors ] with-code-blocks ; inline
  55
  56 SINGLETON: udis-disassembler
  57
  58 : buf/len ( from to -- buf len ) [ drop <alien> ] [ swap - ] 2bi ;
  59
  60 : resolve-call ( str -- str' ) "0x" split1-last [ resolve-xt append ] when* ;
  61
  62 : format-disassembly ( lines -- lines' )
  63     dup [ second length ] [ max ] map-reduce
  64     '[
  65         [
  66             [ first >hex cell 2 * CHAR: 0 pad-head % ": " % ]
  67             [ second _ CHAR: \s pad-tail % "  " % ]
  68             [ third resolve-call % ]
  69             tri
  70         ] "" make
  71     ] map ;
  72
  73 : (disassemble) ( ud -- lines )
  74     [
  75         dup '[
  76             _ ud_disassemble 0 =
  77             [ f ] [
  78                 _
  79                 [ ud_insn_off ]
  80                 [ ud_insn_hex ]
  81                 [ ud_insn_asm ]
  82                 tri 3array , t
  83             ] if
  84         ] loop
  85     ] { } make ;
  86
  87 M: udis-disassembler disassemble*
  88     '[
  89         _ _
  90         [ drop ud_set_pc ]
  91         [ buf/len ud_set_input_buffer ]
  92         [ 2drop (disassemble) format-disassembly ]
  93         3tri
  94     ] with-ud ;
  95
  96 udis-disassembler disassembler-backend set-global