basis/tools/scaffold/scaffold.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs io.files io.pathnames io.directories
   4 io.encodings.utf8 hashtables kernel namespaces sequences
   5 vocabs.loader vocabs.metadata io combinators calendar accessors
   6 math.parser io.streams.string ui.tools.operations quotations
   7 strings arrays prettyprint words vocabs sorting sets classes
   8 math alien urls splitting ascii combinators.short-circuit timers
   9 words.symbol system summary ;
  10 FROM: sets => members ;
  11 IN: tools.scaffold
  12
  13 SYMBOL: developer-name
  14 SYMBOL: using
  15
  16 ERROR: not-a-vocab-root string ;
  17 ERROR: vocab-name-contains-separator path ;
  18 ERROR: vocab-name-contains-dot path ;
  19 ERROR: bad-developer-name name ;
  20
  21 M: bad-developer-name summary
  22     drop "Developer name must be a string." ;
  23
  24 <PRIVATE
  25
  26 : vocab-root? ( string -- ? )
  27     trim-tail-separators
  28     vocab-roots get member? ;
  29
  30 : contains-dot? ( string -- ? ) ".." swap subseq? ;
  31
  32 : contains-separator? ( string -- ? ) [ path-separator? ] any? ;
  33
  34 : ensure-vocab-exists ( string -- string )
  35     dup vocabs member? [ no-vocab ] unless ;
  36
  37 : check-vocab-name ( string -- string )
  38     [ ]
  39     [ contains-dot? [ vocab-name-contains-dot ] when ]
  40     [ contains-separator? [ vocab-name-contains-separator ] when ] tri ;
  41
  42 : check-root ( string -- string )
  43     dup vocab-root? [ not-a-vocab-root ] unless ;
  44
  45 : check-vocab-root/vocab ( vocab-root string -- vocab-root string )
  46     [ check-root ] [ check-vocab-name ] bi* ;
  47
  48 : replace-vocab-separators ( vocab -- path )
  49     path-separator first CHAR: . associate substitute ; inline
  50
  51 : vocab-root/vocab>path ( vocab-root vocab -- path )
  52     check-vocab-root/vocab
  53     [ ] [ replace-vocab-separators ] bi* append-path ;
  54
  55 : vocab>path ( vocab -- path )
  56     check-vocab
  57     [ find-vocab-root ] keep vocab-root/vocab>path ;
  58
  59 : vocab-root/vocab/file>path ( vocab-root vocab file -- path )
  60     [ vocab-root/vocab>path ] dip append-path ;
  61
  62 : vocab-root/vocab/suffix>path ( vocab-root vocab suffix -- path )
  63     [ vocab-root/vocab>path dup file-name append-path ] dip append ;
  64
  65 : vocab/file>path ( vocab file -- path )
  66     [ vocab>path ] dip append-path ;
  67
  68 : vocab/suffix>path ( vocab suffix -- path )
  69     [ vocab>path dup file-name append-path ] dip append ;
  70
  71 : directory-exists ( path -- )
  72     "Not creating a directory, it already exists: " write print ;
  73
  74 : scaffold-directory ( vocab-root vocab -- )
  75     vocab-root/vocab>path
  76     dup exists? [ directory-exists ] [ make-directories ] if ;
  77
  78 : not-scaffolding ( path -- path )
  79     "Not creating scaffolding for " write dup <pathname> . ;
  80
  81 : scaffolding ( path -- path )
  82     "Creating scaffolding for " write dup <pathname> . ;
  83
  84 : scaffolding? ( path -- path ? )
  85     dup exists? [ not-scaffolding f ] [ scaffolding t ] if ;
  86
  87 : scaffold-copyright ( -- )
  88     "! Copyright (C) " write now year>> number>string write
  89     developer-name get [ "Your name" ] unless* bl write "." print
  90     "! See http://factorcode.org/license.txt for BSD license." print ;
  91
  92 : main-file-string ( vocab -- string )
  93     [
  94         scaffold-copyright
  95         "USING: ;" print
  96         "IN: " write print
  97     ] with-string-writer ;
  98
  99 : set-scaffold-main-file ( vocab path -- )
 100     [ main-file-string 1array ] dip utf8 set-file-lines ;
 101
 102 : scaffold-main ( vocab-root vocab -- )
 103     [ ".factor" vocab-root/vocab/suffix>path ] keep swap scaffolding? [
 104         set-scaffold-main-file
 105     ] [
 106         2drop
 107     ] if ;
 108
 109 : scaffold-metadata ( vocab file contents -- )
 110     [ ensure-vocab-exists ] 2dip
 111     [
 112         [ vocab/file>path ] dip 1array swap scaffolding? [
 113             utf8 set-file-lines
 114         ] [
 115             2drop
 116         ] if
 117     ] [
 118         2drop
 119     ] if* ;
 120
 121 : lookup-type ( string -- object/string ? )
 122     "new" ?head drop [ { [ CHAR: ' = ] [ digit? ] } 1|| ] trim-tail
 123     H{
 124         { "object" object } { "obj" object }
 125         { "quot" quotation }
 126         { "string" string }
 127         { "str" string }
 128         { "hash" hashtable }
 129         { "hashtable" hashtable }
 130         { "?" boolean }
 131         { "ch" "a character" }
 132         { "word" word }
 133         { "array" array }
 134         { "timers" timer }
 135         { "duration" duration }
 136         { "path" "a pathname string" }
 137         { "vocab" "a vocabulary specifier" }
 138         { "vocab-root" "a vocabulary root string" }
 139         { "c-ptr" c-ptr }
 140         { "seq" sequence }
 141         { "assoc" assoc }
 142         { "alist" "an array of key/value pairs" }
 143         { "keys" sequence } { "values" sequence }
 144         { "class" class } { "tuple" tuple }
 145         { "url" url }
 146     } at* ;
 147
 148 : add-using ( object -- )
 149     vocabulary>> using get [ conjoin ] [ drop ] if* ;
 150
 151 : ($values.) ( array -- )
 152     [ bl ] [
 153         "{ " write
 154         dup array? [ first ] when
 155         dup lookup-type [
 156             [ unparse write bl ]
 157             [ [ pprint ] [ dup string? [ drop ] [ add-using ] if ] bi ] bi*
 158         ] [
 159             drop unparse write bl null pprint
 160             null add-using
 161         ] if
 162         " }" write
 163     ] interleave ;
 164
 165 : 4bl ( -- )
 166     "    " write ; inline
 167
 168 : $values. ( word -- )
 169     "declared-effect" word-prop [
 170         [ in>> ] [ out>> ] bi
 171         2dup [ empty? ] bi@ and [
 172             2drop
 173         ] [
 174             [ members ] dip over diff
 175             "{ $values" print
 176             [ 4bl ($values.) ]
 177             [ [ nl 4bl ($values.) ] unless-empty ] bi*
 178             nl "}" print
 179         ] if
 180     ] when* ;
 181
 182 : symbol-description. ( word -- )
 183     drop
 184     "{ $var-description \"\" } ;" print ;
 185
 186 : $description. ( word -- )
 187     drop
 188     "{ $description \"\" } ;" print ;
 189
 190 : docs-body. ( word/symbol -- )
 191     dup symbol? [
 192         symbol-description.
 193     ] [
 194         [ $values. ] [ $description. ] bi
 195     ] if ;
 196
 197 : docs-header. ( word -- )
 198     "HELP: " write name>> print ;
 199
 200 : (help.) ( word -- )
 201     [ docs-header. ] [ docs-body. ] bi ;
 202
 203 : interesting-words ( vocab -- array )
 204     words
 205     [ { [ "help" word-prop ] [ predicate? ] } 1|| not ] filter
 206     natural-sort ;
 207
 208 : interesting-words. ( vocab -- )
 209     interesting-words [ (help.) nl ] each ;
 210
 211 : docs-file-string ( vocab -- str2 )
 212     [
 213         {
 214             [ "IN: " write print nl ]
 215             [ interesting-words. ]
 216             [
 217                 [ "ARTICLE: " write unparse dup write bl print ]
 218                 [ "{ $vocab-link " write pprint " }" print ] bi
 219                 ";" print nl
 220             ]
 221             [ "ABOUT: " write unparse print ]
 222         } cleave
 223     ] with-string-writer ;
 224
 225 : write-using ( vocab -- )
 226     "USING:" write
 227     using get keys
 228     { "help.markup" "help.syntax" } append natural-sort remove
 229     [ bl write ] each
 230     " ;" print ;
 231
 232 : set-scaffold-docs-file ( vocab path -- )
 233     utf8 <file-writer> [
 234         scaffold-copyright
 235         [ docs-file-string ] [ write-using ] bi
 236         write
 237     ] with-output-stream ;
 238
 239 : with-scaffold ( quot -- )
 240     [ H{ } clone using ] dip with-variable ; inline
 241
 242 : link-vocab ( vocab -- )
 243     check-vocab
 244     "Edit documentation: " write
 245     "-docs.factor" vocab/suffix>path <pathname> . ;
 246
 247 PRIVATE>
 248
 249 : help. ( word -- )
 250     [ (help.) ] [ nl vocabulary>> link-vocab ] bi ;
 251
 252 : scaffold-help ( vocab -- )
 253     ensure-vocab-exists
 254     [
 255         dup "-docs.factor" vocab/suffix>path scaffolding? [
 256             set-scaffold-docs-file
 257         ] [
 258             2drop
 259         ] if
 260     ] with-scaffold ;
 261
 262 : scaffold-undocumented ( string -- )
 263     [ interesting-words. ] [ link-vocab ] bi ;
 264
 265 : scaffold-authors ( vocab -- )
 266     "authors.txt" developer-name get scaffold-metadata ;
 267
 268 : scaffold-tags ( vocab tags -- )
 269     [ "tags.txt" ] dip scaffold-metadata ;
 270
 271 : scaffold-summary ( vocab summary -- )
 272     [ "summary.txt" ] dip scaffold-metadata ;
 273
 274 : scaffold-platforms ( vocab platforms -- )
 275     [ "platforms.txt" ] dip scaffold-metadata ;
 276
 277 : scaffold-vocab ( vocab-root string -- )
 278     {
 279         [ scaffold-directory ]
 280         [ scaffold-main ]
 281         [ nip require ]
 282         [ nip scaffold-authors ]
 283     } 2cleave ;
 284
 285 : scaffold-core ( string -- ) "resource:core" swap scaffold-vocab ;
 286
 287 : scaffold-basis ( string -- ) "resource:basis" swap scaffold-vocab ;
 288
 289 : scaffold-extra ( string -- ) "resource:extra" swap scaffold-vocab ;
 290
 291 : scaffold-work ( string -- ) "resource:work" swap scaffold-vocab ;
 292
 293 <PRIVATE
 294
 295 : tests-file-string ( vocab -- string )
 296     [
 297         scaffold-copyright
 298         "USING: tools.test " write dup write " ;" print
 299         "IN: " write write ".tests" print
 300     ] with-string-writer ;
 301
 302 : set-scaffold-tests-file ( vocab path -- )
 303     [ tests-file-string ] dip utf8 set-file-contents ;
 304
 305 PRIVATE>
 306
 307 : scaffold-tests ( vocab -- )
 308     ensure-vocab-exists
 309     dup "-tests.factor" vocab/suffix>path
 310     scaffolding? [
 311         set-scaffold-tests-file
 312     ] [
 313         2drop
 314     ] if ;
 315
 316 SYMBOL: examples-flag
 317
 318 : example ( -- )
 319     {
 320         "{ $example \"\" \"USING: prettyprint ;\""
 321         "           \"\""
 322         "           \"\""
 323         "}"
 324     } [ examples-flag get [ 4bl ] when print ] each ;
 325
 326 : examples ( n -- )
 327     t \ examples-flag [
 328         "{ $examples " print
 329         [ example ] times
 330         "}" print
 331     ] with-variable ;
 332
 333 : touch. ( path -- )
 334     [ touch-file ]
 335     [ "Click to edit: " write <pathname> . ] bi ;
 336
 337 : scaffold-rc ( path -- )
 338     [ home ] dip append-path touch. ;
 339
 340 : scaffold-factor-boot-rc ( -- )
 341     os windows? "factor-boot-rc" ".factor-boot-rc" ? scaffold-rc ;
 342
 343 : scaffold-factor-rc ( -- )
 344     os windows? "factor-rc" ".factor-rc" ? scaffold-rc ;
 345
 346
 347 HOOK: scaffold-emacs os ( -- )
 348
 349 M: unix scaffold-emacs ( -- ) ".emacs" scaffold-rc ;