basis/tools/walker/walker.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: threads kernel namespaces continuations combinators
   4 sequences math namespaces.private continuations.private
   5 concurrency.messaging quotations kernel.private words
   6 sequences.private assocs models models.arrow arrays accessors
   7 generic generic.standard definitions make sbufs ;
   8 IN: tools.walker
   9
  10 SYMBOL: show-walker-hook ! ( status continuation thread -- )
  11
  12 ! Thread local in thread being walked
  13 SYMBOL: walker-thread
  14
  15 ! Thread local in walker thread
  16 SYMBOL: walking-thread
  17 SYMBOL: walker-status
  18 SYMBOL: walker-continuation
  19 SYMBOL: walker-history
  20
  21 DEFER: start-walker-thread
  22
  23 : get-walker-thread ( -- status continuation thread )
  24     walker-thread tget [
  25         [ variables>> walker-status swap at ]
  26         [ variables>> walker-continuation swap at ]
  27         [ ] tri
  28     ] [
  29         f <model>
  30         f <model>
  31         2dup start-walker-thread
  32     ] if* ;
  33
  34 : show-walker ( -- thread )
  35     get-walker-thread
  36     [ show-walker-hook get call ] keep ;
  37
  38 : after-break ( object -- )
  39     {
  40         { [ dup continuation? ] [ (continue) ] }
  41         { [ dup quotation? ] [ call ] }
  42         { [ dup not ] [ "Single stepping abandoned" rethrow ] }
  43     } cond ;
  44
  45 : break ( -- )
  46     continuation callstack >>call
  47     show-walker send-synchronous
  48     after-break ;
  49
  50 \ break t "break?" set-word-prop
  51
  52 : walk ( quot -- quot' )
  53     \ break prefix [ break rethrow ] recover ;
  54
  55 GENERIC: add-breakpoint ( quot -- quot' )
  56
  57 M: callable add-breakpoint
  58     dup [ break ] head? [ \ break prefix ] unless ;
  59
  60 M: array add-breakpoint
  61     [ add-breakpoint ] map ;
  62
  63 M: object add-breakpoint ;
  64
  65 : (step-into-quot) ( quot -- ) add-breakpoint call ;
  66
  67 : (step-into-dip) ( quot -- ) add-breakpoint dip ;
  68
  69 : (step-into-2dip) ( quot -- ) add-breakpoint 2dip ;
  70
  71 : (step-into-3dip) ( quot -- ) add-breakpoint 3dip ;
  72
  73 : (step-into-if) ( true false ? -- ) ? (step-into-quot) ;
  74
  75 : (step-into-dispatch) ( array n -- ) nth (step-into-quot) ;
  76
  77 : (step-into-execute) ( word -- )
  78     {
  79         { [ dup "step-into" word-prop ] [ "step-into" word-prop call ] }
  80         { [ dup standard-generic? ] [ effective-method (step-into-execute) ] }
  81         { [ dup hook-generic? ] [ effective-method (step-into-execute) ] }
  82         { [ dup uses \ suspend swap member? ] [ execute break ] }
  83         { [ dup primitive? ] [ execute break ] }
  84         [ def>> (step-into-quot) ]
  85     } cond ;
  86
  87 \ (step-into-execute) t "step-into?" set-word-prop
  88
  89 : (step-into-continuation) ( -- )
  90     continuation callstack >>call break ;
  91
  92 : (step-into-call-next-method) ( method -- )
  93     next-method-quot (step-into-quot) ;
  94
  95 ! Messages sent to walker thread
  96 SYMBOL: step
  97 SYMBOL: step-out
  98 SYMBOL: step-into
  99 SYMBOL: step-all
 100 SYMBOL: step-into-all
 101 SYMBOL: step-back
 102 SYMBOL: abandon
 103 SYMBOL: call-in
 104
 105 SYMBOL: +running+
 106 SYMBOL: +suspended+
 107 SYMBOL: +stopped+
 108
 109 : change-frame ( continuation quot -- continuation' )
 110     #! Applies quot to innermost call frame of the
 111     #! continuation.
 112     [ clone ] dip [
 113         [ clone ] dip
 114         [
 115             [
 116                 [ innermost-frame-scan 1+ ]
 117                 [ innermost-frame-quot ] bi
 118             ] dip call
 119         ]
 120         [ drop set-innermost-frame-quot ]
 121         [ drop ]
 122         2tri
 123     ] curry change-call ; inline
 124
 125 : step-msg ( continuation -- continuation' ) USE: io
 126     [
 127         2dup length = [ nip [ break ] append ] [
 128             2dup nth \ break = [ nip ] [
 129                 swap 1+ cut [ break ] glue
 130             ] if
 131         ] if
 132     ] change-frame ;
 133
 134 : step-out-msg ( continuation -- continuation' )
 135     [ nip \ break suffix ] change-frame ;
 136
 137 {
 138     { call [ (step-into-quot) ] }
 139     { dip [ (step-into-dip) ] }
 140     { 2dip [ (step-into-2dip) ] }
 141     { 3dip [ (step-into-3dip) ] }
 142     { (throw) [ drop (step-into-quot) ] }
 143     { execute [ (step-into-execute) ] }
 144     { if [ (step-into-if) ] }
 145     { dispatch [ (step-into-dispatch) ] }
 146     { continuation [ (step-into-continuation) ] }
 147     { (call-next-method) [ (step-into-call-next-method) ] }
 148 } [ "step-into" set-word-prop ] assoc-each
 149
 150 ! Never step into these words
 151 {
 152     >n ndrop >c c>
 153     continue continue-with
 154     stop suspend (spawn)
 155 } [
 156     dup [ execute break ] curry
 157     "step-into" set-word-prop
 158 ] each
 159
 160 \ break [ break ] "step-into" set-word-prop
 161
 162 : step-into-msg ( continuation -- continuation' )
 163     [
 164         swap cut [
 165             swap %
 166             [ \ break , ] [
 167                 unclip {
 168                     { [ dup \ break eq? ] [ , ] }
 169                     { [ dup quotation? ] [ add-breakpoint , \ break , ] }
 170                     { [ dup array? ] [ add-breakpoint , \ break , ] }
 171                     { [ dup word? ] [ literalize , \ (step-into-execute) , ] }
 172                     [ , \ break , ]
 173                 } cond %
 174             ] if-empty
 175         ] [ ] make
 176     ] change-frame ;
 177
 178 : status ( -- symbol )
 179     walker-status tget value>> ;
 180
 181 : set-status ( symbol -- )
 182     walker-status tget set-model ;
 183
 184 : keep-running ( -- )
 185     +running+ set-status ;
 186
 187 : walker-stopped ( -- )
 188     +stopped+ set-status ;
 189
 190 : step-into-all-loop ( -- )
 191     +running+ set-status
 192     [ status +running+ eq? ] [
 193         [
 194             {
 195                 { step [ f ] }
 196                 { step-out [ f ] }
 197                 { step-into [ f ] }
 198                 { step-all [ f ] }
 199                 { step-into-all [ f ] }
 200                 { step-back [ f ] }
 201                 { f [ +stopped+ set-status f ] }
 202                 [
 203                     [ walker-continuation tget set-model ]
 204                     [ step-into-msg ] bi
 205                 ]
 206             } case
 207         ] handle-synchronous
 208     ] while ;
 209
 210 : step-back-msg ( continuation -- continuation' )
 211     walker-history tget
 212     [ pop* ]
 213     [ [ nip pop ] unless-empty ] bi ;
 214
 215 : walker-suspended ( continuation -- continuation' )
 216     +suspended+ set-status
 217     [ status +suspended+ eq? ] [
 218         dup walker-history tget push
 219         dup walker-continuation tget set-model
 220         [
 221             {
 222                 ! These are sent by the walker tool. We reply
 223                 ! and keep cycling.
 224                 { step [ step-msg keep-running ] }
 225                 { step-out [ step-out-msg keep-running ] }
 226                 { step-into [ step-into-msg keep-running ] }
 227                 { step-all [ keep-running ] }
 228                 { step-into-all [ step-into-all-loop ] }
 229                 { abandon [ drop f keep-running ] }
 230                 ! Pass quotation to debugged thread
 231                 { call-in [ keep-running ] }
 232                 ! Pass previous continuation to debugged thread
 233                 { step-back [ step-back-msg ] }
 234             } case f
 235         ] handle-synchronous
 236     ] while ;
 237
 238 : walker-loop ( -- )
 239     +running+ set-status
 240     [ status +stopped+ eq? ] [
 241         [
 242             {
 243                 ! ignore these commands while the thread is
 244                 ! running
 245                 { step [ f ] }
 246                 { step-out [ f ] }
 247                 { step-into [ f ] }
 248                 { step-all [ f ] }
 249                 { step-into-all [ step-into-all-loop f ] }
 250                 { step-back [ f ] }
 251                 { abandon [ f ] }
 252                 { f [ walker-stopped f ] }
 253                 ! thread hit a breakpoint and sent us the
 254                 ! continuation, so we modify it and send it
 255                 ! back.
 256                 [ walker-suspended ]
 257             } case
 258         ] handle-synchronous
 259     ] until ;
 260
 261 : associate-thread ( walker -- )
 262     walker-thread tset
 263     [ f walker-thread tget send-synchronous drop ]
 264     self (>>exit-handler) ;
 265
 266 : start-walker-thread ( status continuation -- thread' )
 267     self [
 268         walking-thread tset
 269         walker-continuation tset
 270         walker-status tset
 271         V{ } clone walker-history tset
 272         walker-loop
 273     ] 3curry
 274     "Walker on " self name>> append spawn
 275     [ associate-thread ] keep ;
 276
 277 ! For convenience
 278 IN: syntax
 279
 280 : B ( -- ) break ;