basis/tuple-arrays/tuple-arrays.factor

   1 ! Copyright (C) 2009, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes.tuple classes.tuple.private
   4 combinators combinators.smart fry functors kernel macros math parser
   5 sequences sequences.private ;
   6 FROM: inverse => undo ;
   7 IN: tuple-arrays
   8
   9 ERROR: not-final class ;
  10
  11 <PRIVATE
  12
  13 MACRO: boa-unsafe ( class -- quot ) tuple-layout '[ _ <tuple-boa> ] ;
  14
  15 : tuple-arity ( class -- quot ) '[ _ boa ] inputs ; inline
  16
  17 : tuple-slice ( n seq -- slice )
  18     [ n>> [ * dup ] keep + ] [ seq>> ] bi <slice-unsafe> ; inline
  19
  20 : read-tuple ( slice class -- tuple )
  21     '[ _ boa-unsafe ] input<sequence-unsafe ; inline
  22
  23 MACRO: write-tuple ( class -- quot )
  24     [ '[ [ _ boa ] undo ] ]
  25     [ tuple-arity <iota> <reversed> [ '[ [ _ ] dip set-nth-unsafe ] ] map '[ _ cleave ] ]
  26     bi '[ _ dip @ ] ;
  27
  28 : check-final ( class -- )
  29     {
  30         { [ dup tuple-class? not ] [ not-a-tuple ] }
  31         { [ dup final-class? not ] [ not-final ] }
  32         [ drop ]
  33     } cond ;
  34
  35 PRIVATE>
  36
  37 FUNCTOR: define-tuple-array ( CLASS -- )
  38
  39 CLASS IS ${CLASS}
  40
  41 CLASS-array DEFINES-CLASS ${CLASS}-array
  42 CLASS-array? IS ${CLASS-array}?
  43
  44 <CLASS-array> DEFINES <${CLASS}-array>
  45 >CLASS-array DEFINES >${CLASS}-array
  46
  47 WHERE
  48
  49 CLASS check-final
  50
  51 TUPLE: CLASS-array
  52 { seq array read-only }
  53 { n array-capacity read-only }
  54 { length array-capacity read-only } ;
  55
  56 : <CLASS-array> ( length -- tuple-array )
  57     [ \ CLASS [ initial-values <repetition> concat ] [ tuple-arity ] bi ] keep
  58     \ CLASS-array boa ; inline
  59
  60 M: CLASS-array length length>> ; inline
  61
  62 M: CLASS-array nth-unsafe tuple-slice \ CLASS read-tuple ; inline
  63
  64 M: CLASS-array set-nth-unsafe tuple-slice \ CLASS write-tuple ; inline
  65
  66 M: CLASS-array new-sequence drop <CLASS-array> ; inline
  67
  68 : >CLASS-array ( seq -- tuple-array ) 0 <CLASS-array> clone-like ;
  69
  70 M: CLASS-array like drop dup CLASS-array? [ >CLASS-array ] unless ; inline
  71
  72 INSTANCE: CLASS-array sequence
  73
  74 ;FUNCTOR
  75
  76 SYNTAX: TUPLE-ARRAY: scan-word define-tuple-array ;