basis/tuple-arrays/tuple-arrays.factor

   1 ! Copyright (C) 2009, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes classes.tuple
   4 classes.tuple.private combinators combinators.smart fry functors
   5 kernel macros math parser sequences sequences.private ;
   6 FROM: inverse => undo ;
   7 IN: tuple-arrays
   8
   9 ERROR: not-final class ;
  10
  11 <PRIVATE
  12
  13 MACRO: boa-unsafe ( class -- quot ) tuple-layout '[ _ <tuple-boa> ] ;
  14
  15 : tuple-arity ( class -- quot ) '[ _ boa ] inputs ; inline
  16
  17 : tuple-slice ( n seq -- slice )
  18     [ n>> [ * dup ] keep + ] [ seq>> ] bi <slice-unsafe> ; inline
  19
  20 : read-tuple ( slice class -- tuple )
  21     '[ _ boa-unsafe ] input<sequence-unsafe ; inline
  22
  23 MACRO: write-tuple ( class -- quot )
  24     [ '[ [ _ boa ] undo ] ]
  25     [ tuple-arity <iota> <reversed> [ '[ [ _ ] dip set-nth-unsafe ] ] map '[ _ cleave ] ]
  26     bi '[ _ dip @ ] ;
  27
  28 : check-final ( class -- )
  29     tuple-class check-instance
  30     dup final-class? [ drop ] [ not-final ] if ;
  31
  32 PRIVATE>
  33
  34 <FUNCTOR: define-tuple-array ( CLASS -- )
  35
  36 CLASS IS ${CLASS}
  37
  38 CLASS-array DEFINES-CLASS ${CLASS}-array
  39 CLASS-array? IS ${CLASS-array}?
  40
  41 <CLASS-array> DEFINES <${CLASS}-array>
  42 >CLASS-array DEFINES >${CLASS}-array
  43
  44 WHERE
  45
  46 CLASS check-final
  47
  48 TUPLE: CLASS-array
  49 { seq array read-only }
  50 { n array-capacity read-only }
  51 { length array-capacity read-only } ;
  52
  53 : <CLASS-array> ( length -- tuple-array )
  54     [ \ CLASS [ initial-values <repetition> concat ] [ tuple-arity ] bi ] keep
  55     \ CLASS-array boa ; inline
  56
  57 M: CLASS-array length length>> ; inline
  58
  59 M: CLASS-array nth-unsafe tuple-slice \ CLASS read-tuple ; inline
  60
  61 M: CLASS-array set-nth-unsafe tuple-slice \ CLASS write-tuple ; inline
  62
  63 M: CLASS-array new-sequence drop <CLASS-array> ; inline
  64
  65 : >CLASS-array ( seq -- tuple-array ) 0 <CLASS-array> clone-like ;
  66
  67 M: CLASS-array like drop dup CLASS-array? [ >CLASS-array ] unless ; inline
  68
  69 INSTANCE: CLASS-array sequence
  70
  71 ;FUNCTOR>
  72
  73 SYNTAX: TUPLE-ARRAY: scan-word define-tuple-array ;