basis/tuple-arrays/tuple-arrays.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays combinators.smart fry functors kernel
   4 kernel.private macros sequences combinators sequences.private
   5 stack-checker parser math classes.tuple.private ;
   6 FROM: inverse => undo ;
   7 IN: tuple-arrays
   8
   9 <PRIVATE
  10
  11 MACRO: boa-unsafe ( class -- quot ) tuple-layout '[ _ <tuple-boa> ] ;
  12
  13 MACRO: infer-in ( class -- quot ) infer in>> '[ _ ] ;
  14
  15 : tuple-arity ( class -- quot ) '[ _ boa ] infer-in ; inline
  16
  17 : smart-tuple>array ( tuple class -- array )
  18     '[ [ _ boa ] undo ] output>array ; inline
  19
  20 : tuple-prototype ( class -- array )
  21     [ new ] [ smart-tuple>array ] bi ; inline
  22
  23 : tuple-slice ( n seq -- slice )
  24     [ n>> [ * dup ] keep + ] [ seq>> ] bi slice boa ; inline
  25
  26 : read-tuple ( slice class -- tuple )
  27     '[ _ boa-unsafe ] input<sequence-unsafe ; inline
  28
  29 MACRO: write-tuple ( class -- quot )
  30     [ '[ [ _ boa ] undo ] ]
  31     [ tuple-arity <reversed> [ '[ [ _ ] dip set-nth-unsafe ] ] map '[ _ cleave ] ]
  32     bi '[ _ dip @ ] ;
  33
  34 PRIVATE>
  35
  36 FUNCTOR: define-tuple-array ( CLASS -- )
  37
  38 CLASS IS ${CLASS}
  39
  40 CLASS-array DEFINES-CLASS ${CLASS}-array
  41 CLASS-array? IS ${CLASS-array}?
  42
  43 <CLASS-array> DEFINES <${CLASS}-array>
  44 >CLASS-array DEFINES >${CLASS}-array
  45
  46 WHERE
  47
  48 TUPLE: CLASS-array
  49 { seq array read-only }
  50 { n array-capacity read-only }
  51 { length array-capacity read-only } ;
  52
  53 : <CLASS-array> ( length -- tuple-array )
  54     [ \ CLASS [ tuple-prototype <repetition> concat ] [ tuple-arity ] bi ] keep
  55     \ CLASS-array boa ; inline
  56
  57 M: CLASS-array length length>> ; inline
  58
  59 M: CLASS-array nth-unsafe tuple-slice \ CLASS read-tuple ; inline
  60
  61 M: CLASS-array set-nth-unsafe tuple-slice \ CLASS write-tuple ; inline
  62
  63 M: CLASS-array new-sequence drop <CLASS-array> ; inline
  64
  65 : >CLASS-array ( seq -- tuple-array ) 0 <CLASS-array> clone-like ;
  66
  67 M: CLASS-array like drop dup CLASS-array? [ >CLASS-array ] unless ; inline
  68
  69 INSTANCE: CLASS-array sequence
  70
  71 ;FUNCTOR
  72
  73 SYNTAX: TUPLE-ARRAY: scan-word define-tuple-array ;