basis/ui/backend/cocoa/cocoa.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.c-types arrays assocs classes cocoa
   4 cocoa.application cocoa.classes cocoa.messages cocoa.nibs
   5 cocoa.pasteboard cocoa.runtime cocoa.subclassing cocoa.types
   6 cocoa.views cocoa.windows combinators command-line
   7 core-foundation core-foundation.run-loop core-graphics
   8 core-graphics.types destructors fry generalizations io.thread
   9 kernel libc literals locals math math.bitwise math.rectangles memory
  10 namespaces sequences threads ui
  11 ui.backend ui.backend.cocoa.views ui.clipboards ui.gadgets
  12 ui.gadgets.worlds ui.pixel-formats ui.pixel-formats.private
  13 ui.private words.symbol ;
  14 IN: ui.backend.cocoa
  15
  16 TUPLE: handle ;
  17 TUPLE: window-handle < handle view window ;
  18 TUPLE: offscreen-handle < handle context buffer ;
  19
  20 C: <window-handle> window-handle
  21 C: <offscreen-handle> offscreen-handle
  22
  23 SINGLETON: cocoa-ui-backend
  24
  25 PIXEL-FORMAT-ATTRIBUTE-TABLE: NSOpenGLPFA { } H{
  26     { double-buffered { $ NSOpenGLPFADoubleBuffer } }
  27     { stereo { $ NSOpenGLPFAStereo } }
  28     { offscreen { $ NSOpenGLPFAOffScreen } }
  29     { fullscreen { $ NSOpenGLPFAFullScreen } }
  30     { windowed { $ NSOpenGLPFAWindow } }
  31     { accelerated { $ NSOpenGLPFAAccelerated } }
  32     { software-rendered { $ NSOpenGLPFARendererID $ kCGLRendererGenericFloatID } }
  33     { backing-store { $ NSOpenGLPFABackingStore } }
  34     { multisampled { $ NSOpenGLPFAMultisample } }
  35     { supersampled { $ NSOpenGLPFASupersample } }
  36     { sample-alpha { $ NSOpenGLPFASampleAlpha } }
  37     { color-float { $ NSOpenGLPFAColorFloat } }
  38     { color-bits { $ NSOpenGLPFAColorSize } }
  39     { alpha-bits { $ NSOpenGLPFAAlphaSize } }
  40     { accum-bits { $ NSOpenGLPFAAccumSize } }
  41     { depth-bits { $ NSOpenGLPFADepthSize } }
  42     { stencil-bits { $ NSOpenGLPFAStencilSize } }
  43     { aux-buffers { $ NSOpenGLPFAAuxBuffers } }
  44     { sample-buffers { $ NSOpenGLPFASampleBuffers } }
  45     { samples { $ NSOpenGLPFASamples } }
  46 }
  47
  48 M: cocoa-ui-backend (make-pixel-format)
  49     nip >NSOpenGLPFA-int-array
  50     NSOpenGLPixelFormat -> alloc swap -> initWithAttributes: ;
  51
  52 M: cocoa-ui-backend (free-pixel-format)
  53     handle>> -> release ;
  54
  55 M: cocoa-ui-backend (pixel-format-attribute)
  56     [ handle>> ] [ >NSOpenGLPFA ] bi*
  57     [ drop f ]
  58     [ first 0 <int> [ swap 0 -> getValues:forAttribute:forVirtualScreen: ] keep *int ]
  59     if-empty ;
  60
  61 TUPLE: pasteboard handle ;
  62
  63 C: <pasteboard> pasteboard
  64
  65 M: pasteboard clipboard-contents
  66     handle>> pasteboard-string ;
  67
  68 M: pasteboard set-clipboard-contents
  69     handle>> set-pasteboard-string ;
  70
  71 : init-clipboard ( -- )
  72     NSPasteboard -> generalPasteboard <pasteboard>
  73     clipboard set-global
  74     <clipboard> selection set-global ;
  75
  76 : world>NSRect ( world -- NSRect )
  77     [ 0 0 ] dip dim>> first2 <CGRect> ;
  78
  79 : auto-position ( window loc -- )
  80     #! Note: if this is the initial window, the length of the windows
  81     #! vector should be 1, since (open-window) calls auto-position
  82     #! after register-window.
  83     dup { 0 0 } = [
  84         drop
  85         windows get length 1 <= [ -> center ] [
  86             windows get last second window-loc>>
  87             dupd first2 <CGPoint> -> cascadeTopLeftFromPoint:
  88             -> setFrameTopLeftPoint:
  89         ] if
  90     ] [ first2 <CGPoint> -> setFrameTopLeftPoint: ] if ;
  91
  92 M: cocoa-ui-backend set-title ( string world -- )
  93     handle>> window>> swap <NSString> -> setTitle: ;
  94
  95 : enter-fullscreen ( world -- )
  96     handle>> view>>
  97     NSScreen -> mainScreen
  98     f -> enterFullScreenMode:withOptions:
  99     drop ;
 100
 101 : exit-fullscreen ( world -- )
 102     handle>>
 103     [ view>> f -> exitFullScreenModeWithOptions: ]
 104     [ [ window>> ] [ view>> ] bi -> makeFirstResponder: drop ] bi ;
 105
 106 M: cocoa-ui-backend (set-fullscreen) ( world ? -- )
 107     [ enter-fullscreen ] [ exit-fullscreen ] if ;
 108
 109 M: cocoa-ui-backend (fullscreen?) ( world -- ? )
 110     handle>> view>> -> isInFullScreenMode zero? not ;
 111
 112 CONSTANT: window-control>styleMask
 113     H{
 114         { close-button $ NSClosableWindowMask }
 115         { minimize-button $ NSMiniaturizableWindowMask }
 116         { maximize-button 0 }
 117         { resize-handles $ NSResizableWindowMask }
 118         { small-title-bar $[ NSTitledWindowMask NSUtilityWindowMask bitor ] }
 119         { normal-title-bar $ NSTitledWindowMask }
 120         { textured-background $ NSTexturedBackgroundWindowMask }
 121     }
 122
 123 : world>styleMask ( world -- n )
 124     window-controls>> window-control>styleMask symbols>flags ;
 125
 126 : make-context-transparent ( view -- )
 127     -> openGLContext
 128     0 <int> NSOpenGLCPSurfaceOpacity -> setValues:forParameter: ;
 129
 130 M:: cocoa-ui-backend (open-window) ( world -- )
 131     world [ [ dim>> ] dip <FactorView> ]
 132     with-world-pixel-format :> view
 133     world transparent?>> [ view make-context-transparent ] when
 134     view world [ world>NSRect ] [ world>styleMask ] bi <ViewWindow> :> window
 135     view -> release
 136     world view register-window
 137     window world window-loc>> auto-position
 138     world window save-position
 139     window install-window-delegate
 140     view window <window-handle> world (>>handle)
 141     window f -> makeKeyAndOrderFront: ;
 142
 143 M: cocoa-ui-backend (close-window) ( handle -- )
 144     [
 145         view>> dup -> isInFullScreenMode zero?
 146         [ drop ]
 147         [ f -> exitFullScreenModeWithOptions: ] if
 148     ] [ window>> -> release ] bi ;
 149
 150 M: cocoa-ui-backend (grab-input) ( handle -- )
 151     0 CGAssociateMouseAndMouseCursorPosition drop
 152     CGMainDisplayID CGDisplayHideCursor drop
 153     window>> -> frame CGRect>rect rect-center
 154     NSScreen -> screens 0 -> objectAtIndex: -> frame CGRect-h
 155     [ drop first ] [ swap second - ] 2bi <CGPoint>
 156     [ GetCurrentButtonState zero? not ] [ yield ] while
 157     CGWarpMouseCursorPosition drop ;
 158
 159 M: cocoa-ui-backend (ungrab-input) ( handle -- )
 160     drop
 161     CGMainDisplayID CGDisplayShowCursor drop
 162     1 CGAssociateMouseAndMouseCursorPosition drop ;
 163
 164 M: cocoa-ui-backend close-window ( gadget -- )
 165     find-world [
 166         handle>> [
 167             window>> -> close
 168         ] when*
 169     ] when* ;
 170
 171 M: cocoa-ui-backend raise-window* ( world -- )
 172     handle>> [
 173         window>> dup f -> orderFront: -> makeKeyWindow
 174         NSApp 1 -> activateIgnoringOtherApps:
 175     ] when* ;
 176
 177 : pixel-size ( pixel-format -- size )
 178     color-bits pixel-format-attribute -3 shift ;
 179
 180 : offscreen-buffer ( world pixel-format -- alien w h pitch )
 181     [ dim>> first2 ] [ pixel-size ] bi*
 182     { [ * * malloc ] [ 2drop ] [ drop nip ] [ nip * ] } 3cleave ;
 183
 184 :: gadget-offscreen-context ( world -- context buffer )
 185     world [
 186         nip :> pf
 187         NSOpenGLContext -> alloc pf handle>> f -> initWithFormat:shareContext:
 188         dup world pf offscreen-buffer
 189         4 npick [ -> setOffScreen:width:height:rowbytes: ] dip
 190     ] with-world-pixel-format ;
 191
 192 M: cocoa-ui-backend (open-offscreen-buffer) ( world -- )
 193     dup gadget-offscreen-context <offscreen-handle> >>handle drop ;
 194
 195 M: cocoa-ui-backend (close-offscreen-buffer) ( handle -- )
 196     [ context>> -> release ]
 197     [ buffer>> free ] bi ;
 198
 199 GENERIC: (gl-context) ( handle -- context )
 200 M: window-handle (gl-context) view>> -> openGLContext ;
 201 M: offscreen-handle (gl-context) context>> ;
 202
 203 M: handle select-gl-context ( handle -- )
 204     (gl-context) -> makeCurrentContext ;
 205
 206 M: handle flush-gl-context ( handle -- )
 207     (gl-context) -> flushBuffer ;
 208
 209 M: cocoa-ui-backend offscreen-pixels ( world -- alien w h )
 210     [ handle>> buffer>> ] [ dim>> first2 neg ] bi ;
 211
 212 M: cocoa-ui-backend beep ( -- )
 213     NSBeep ;
 214
 215 CLASS: {
 216     { +superclass+ "NSObject" }
 217     { +name+ "FactorApplicationDelegate" }
 218 }
 219
 220 { "applicationDidUpdate:" "void" { "id" "SEL" "id" }
 221     [ 3drop reset-run-loop ]
 222 } ;
 223
 224 : install-app-delegate ( -- )
 225     NSApp FactorApplicationDelegate install-delegate ;
 226
 227 SYMBOL: cocoa-init-hook
 228
 229 cocoa-init-hook [
 230     [ "MiniFactor.nib" load-nib install-app-delegate ]
 231 ] initialize
 232
 233 M: cocoa-ui-backend (with-ui)
 234     "UI" assert.app [
 235         [
 236             init-clipboard
 237             cocoa-init-hook get call( -- )
 238             start-ui
 239             f io-thread-running? set-global
 240             init-thread-timer
 241             reset-run-loop
 242             NSApp -> run
 243         ] ui-running
 244     ] with-cocoa ;
 245
 246 cocoa-ui-backend ui-backend set-global
 247
 248 [ running.app? "ui.tools" "listener" ? ] main-vocab-hook set-global