basis/ui/backend/cocoa/cocoa.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.c-types arrays assocs classes cocoa
   4 cocoa.application cocoa.classes cocoa.messages cocoa.nibs
   5 cocoa.pasteboard cocoa.runtime cocoa.subclassing cocoa.types
   6 cocoa.views cocoa.windows combinators command-line
   7 core-foundation core-foundation.run-loop core-graphics
   8 core-graphics.types destructors fry generalizations io.thread
   9 kernel libc literals locals math math.bitwise math.rectangles memory
  10 namespaces sequences threads ui
  11 ui.backend ui.backend.cocoa.views ui.clipboards ui.gadgets
  12 ui.gadgets.worlds ui.pixel-formats ui.pixel-formats.private
  13 ui.private words.symbol ;
  14 IN: ui.backend.cocoa
  15
  16 TUPLE: handle ;
  17 TUPLE: window-handle < handle view window ;
  18 TUPLE: offscreen-handle < handle context buffer ;
  19
  20 C: <window-handle> window-handle
  21 C: <offscreen-handle> offscreen-handle
  22
  23 SINGLETON: cocoa-ui-backend
  24
  25 PIXEL-FORMAT-ATTRIBUTE-TABLE: NSOpenGLPFA { } H{
  26     { double-buffered { $ NSOpenGLPFADoubleBuffer } }
  27     { stereo { $ NSOpenGLPFAStereo } }
  28     { offscreen { $ NSOpenGLPFAOffScreen } }
  29     { fullscreen { $ NSOpenGLPFAFullScreen } }
  30     { windowed { $ NSOpenGLPFAWindow } }
  31     { accelerated { $ NSOpenGLPFAAccelerated } }
  32     { software-rendered { $ NSOpenGLPFARendererID $ kCGLRendererGenericFloatID } }
  33     { backing-store { $ NSOpenGLPFABackingStore } }
  34     { multisampled { $ NSOpenGLPFAMultisample } }
  35     { supersampled { $ NSOpenGLPFASupersample } }
  36     { sample-alpha { $ NSOpenGLPFASampleAlpha } }
  37     { color-float { $ NSOpenGLPFAColorFloat } }
  38     { color-bits { $ NSOpenGLPFAColorSize } }
  39     { alpha-bits { $ NSOpenGLPFAAlphaSize } }
  40     { accum-bits { $ NSOpenGLPFAAccumSize } }
  41     { depth-bits { $ NSOpenGLPFADepthSize } }
  42     { stencil-bits { $ NSOpenGLPFAStencilSize } }
  43     { aux-buffers { $ NSOpenGLPFAAuxBuffers } }
  44     { sample-buffers { $ NSOpenGLPFASampleBuffers } }
  45     { samples { $ NSOpenGLPFASamples } }
  46 }
  47
  48 M: cocoa-ui-backend (make-pixel-format)
  49     nip >NSOpenGLPFA-int-array
  50     NSOpenGLPixelFormat -> alloc swap -> initWithAttributes: ;
  51
  52 M: cocoa-ui-backend (free-pixel-format)
  53     handle>> -> release ;
  54
  55 M: cocoa-ui-backend (pixel-format-attribute)
  56     [ handle>> ] [ >NSOpenGLPFA ] bi*
  57     [ drop f ]
  58     [ first 0 <int> [ swap 0 -> getValues:forAttribute:forVirtualScreen: ] keep *int ]
  59     if-empty ;
  60
  61 M: cocoa-ui-backend system-background-color
  62     T{ rgba f 0.0 0.0 0.0 0.0 } ; inline
  63
  64 TUPLE: pasteboard handle ;
  65
  66 C: <pasteboard> pasteboard
  67
  68 M: pasteboard clipboard-contents
  69     handle>> pasteboard-string ;
  70
  71 M: pasteboard set-clipboard-contents
  72     handle>> set-pasteboard-string ;
  73
  74 : init-clipboard ( -- )
  75     NSPasteboard -> generalPasteboard <pasteboard>
  76     clipboard set-global
  77     <clipboard> selection set-global ;
  78
  79 : world>NSRect ( world -- NSRect )
  80     [ 0 0 ] dip dim>> first2 <CGRect> ;
  81
  82 : auto-position ( window loc -- )
  83     #! Note: if this is the initial window, the length of the windows
  84     #! vector should be 1, since (open-window) calls auto-position
  85     #! after register-window.
  86     dup { 0 0 } = [
  87         drop
  88         windows get length 1 <= [ -> center ] [
  89             windows get last second window-loc>>
  90             dupd first2 <CGPoint> -> cascadeTopLeftFromPoint:
  91             -> setFrameTopLeftPoint:
  92         ] if
  93     ] [ first2 <CGPoint> -> setFrameTopLeftPoint: ] if ;
  94
  95 M: cocoa-ui-backend set-title ( string world -- )
  96     handle>> window>> swap <NSString> -> setTitle: ;
  97
  98 : enter-fullscreen ( world -- )
  99     handle>> view>>
 100     NSScreen -> mainScreen
 101     f -> enterFullScreenMode:withOptions:
 102     drop ;
 103
 104 : exit-fullscreen ( world -- )
 105     handle>>
 106     [ view>> f -> exitFullScreenModeWithOptions: ]
 107     [ [ window>> ] [ view>> ] bi -> makeFirstResponder: drop ] bi ;
 108
 109 M: cocoa-ui-backend (set-fullscreen) ( world ? -- )
 110     [ enter-fullscreen ] [ exit-fullscreen ] if ;
 111
 112 M: cocoa-ui-backend (fullscreen?) ( world -- ? )
 113     handle>> view>> -> isInFullScreenMode zero? not ;
 114
 115 CONSTANT: window-control>styleMask
 116     H{
 117         { close-button $ NSClosableWindowMask }
 118         { minimize-button $ NSMiniaturizableWindowMask }
 119         { maximize-button 0 }
 120         { resize-handles $ NSResizableWindowMask }
 121         { small-title-bar $[ NSTitledWindowMask NSUtilityWindowMask bitor ] }
 122         { normal-title-bar $ NSTitledWindowMask }
 123         { textured-background $ NSTexturedBackgroundWindowMask }
 124     }
 125
 126 : world>styleMask ( world -- n )
 127     window-controls>> window-control>styleMask symbols>flags ;
 128
 129 : make-context-transparent ( view -- )
 130     -> openGLContext
 131     0 <int> NSOpenGLCPSurfaceOpacity -> setValues:forParameter: ;
 132
 133 M:: cocoa-ui-backend (open-window) ( world -- )
 134     world [ [ dim>> ] dip <FactorView> ]
 135     with-world-pixel-format :> view
 136     world transparent?>> [ view make-context-transparent ] when
 137     view world [ world>NSRect ] [ world>styleMask ] bi <ViewWindow> :> window
 138     view -> release
 139     world view register-window
 140     window world window-loc>> auto-position
 141     world window save-position
 142     window install-window-delegate
 143     view window <window-handle> world (>>handle)
 144     window f -> makeKeyAndOrderFront: ;
 145
 146 M: cocoa-ui-backend (close-window) ( handle -- )
 147     [
 148         view>> dup -> isInFullScreenMode zero?
 149         [ drop ]
 150         [ f -> exitFullScreenModeWithOptions: ] if
 151     ] [ window>> -> release ] bi ;
 152
 153 M: cocoa-ui-backend (grab-input) ( handle -- )
 154     0 CGAssociateMouseAndMouseCursorPosition drop
 155     CGMainDisplayID CGDisplayHideCursor drop
 156     window>> -> frame CGRect>rect rect-center
 157     NSScreen -> screens 0 -> objectAtIndex: -> frame CGRect-h
 158     [ drop first ] [ swap second - ] 2bi <CGPoint>
 159     [ GetCurrentButtonState zero? not ] [ yield ] while
 160     CGWarpMouseCursorPosition drop ;
 161
 162 M: cocoa-ui-backend (ungrab-input) ( handle -- )
 163     drop
 164     CGMainDisplayID CGDisplayShowCursor drop
 165     1 CGAssociateMouseAndMouseCursorPosition drop ;
 166
 167 M: cocoa-ui-backend close-window ( gadget -- )
 168     find-world [
 169         handle>> [
 170             window>> -> close
 171         ] when*
 172     ] when* ;
 173
 174 M: cocoa-ui-backend raise-window* ( world -- )
 175     handle>> [
 176         window>> dup f -> orderFront: -> makeKeyWindow
 177         NSApp 1 -> activateIgnoringOtherApps:
 178     ] when* ;
 179
 180 : pixel-size ( pixel-format -- size )
 181     color-bits pixel-format-attribute -3 shift ;
 182
 183 : offscreen-buffer ( world pixel-format -- alien w h pitch )
 184     [ dim>> first2 ] [ pixel-size ] bi*
 185     { [ * * malloc ] [ 2drop ] [ drop nip ] [ nip * ] } 3cleave ;
 186
 187 :: gadget-offscreen-context ( world -- context buffer )
 188     world [
 189         nip :> pf
 190         NSOpenGLContext -> alloc pf handle>> f -> initWithFormat:shareContext:
 191         dup world pf offscreen-buffer
 192         4 npick [ -> setOffScreen:width:height:rowbytes: ] dip
 193     ] with-world-pixel-format ;
 194
 195 M: cocoa-ui-backend (open-offscreen-buffer) ( world -- )
 196     dup gadget-offscreen-context <offscreen-handle> >>handle drop ;
 197
 198 M: cocoa-ui-backend (close-offscreen-buffer) ( handle -- )
 199     [ context>> -> release ]
 200     [ buffer>> free ] bi ;
 201
 202 GENERIC: (gl-context) ( handle -- context )
 203 M: window-handle (gl-context) view>> -> openGLContext ;
 204 M: offscreen-handle (gl-context) context>> ;
 205
 206 M: handle select-gl-context ( handle -- )
 207     (gl-context) -> makeCurrentContext ;
 208
 209 M: handle flush-gl-context ( handle -- )
 210     (gl-context) -> flushBuffer ;
 211
 212 M: cocoa-ui-backend offscreen-pixels ( world -- alien w h )
 213     [ handle>> buffer>> ] [ dim>> first2 neg ] bi ;
 214
 215 M: cocoa-ui-backend beep ( -- )
 216     NSBeep ;
 217
 218 CLASS: {
 219     { +superclass+ "NSObject" }
 220     { +name+ "FactorApplicationDelegate" }
 221 }
 222
 223 { "applicationDidUpdate:" "void" { "id" "SEL" "id" }
 224     [ 3drop reset-run-loop ]
 225 } ;
 226
 227 : install-app-delegate ( -- )
 228     NSApp FactorApplicationDelegate install-delegate ;
 229
 230 SYMBOL: cocoa-init-hook
 231
 232 cocoa-init-hook [
 233     [ "MiniFactor.nib" load-nib install-app-delegate ]
 234 ] initialize
 235
 236 M: cocoa-ui-backend (with-ui)
 237     "UI" assert.app [
 238         [
 239             init-clipboard
 240             cocoa-init-hook get call( -- )
 241             start-ui
 242             f io-thread-running? set-global
 243             init-thread-timer
 244             reset-run-loop
 245             NSApp -> run
 246         ] ui-running
 247     ] with-cocoa ;
 248
 249 cocoa-ui-backend ui-backend set-global
 250
 251 [ running.app? "ui.tools" "listener" ? ] main-vocab-hook set-global