basis/ui/backend/cocoa/tools/tools.factor

   1 ! Copyright (C) 2006, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien.syntax cocoa cocoa.nibs cocoa.application
   4 cocoa.classes cocoa.dialogs cocoa.pasteboard cocoa.runtime
   5 cocoa.subclassing core-foundation core-foundation.strings
   6 help.topics kernel memory namespaces parser system ui
   7 ui.tools.browser ui.tools.listener ui.backend.cocoa eval
   8 locals listener vocabs.refresh ;
   9 FROM: alien.c-types => int void ;
  10 IN: ui.backend.cocoa.tools
  11
  12 : finder-run-files ( alien -- )
  13     CF>string-array listener-run-files
  14     NSApp NSApplicationDelegateReplySuccess
  15     -> replyToOpenOrPrint: ;
  16
  17 : menu-run-files ( -- )
  18     open-panel [ listener-run-files ] when* ;
  19
  20 : menu-save-image ( -- )
  21     image-path save-panel [ save-image ] when* ;
  22
  23 ! Handle Open events from the Finder
  24 CLASS: FactorWorkspaceApplicationDelegate < FactorApplicationDelegate
  25
  26     METHOD: void application: id app openFiles: id files [ files finder-run-files ] ;
  27
  28     METHOD: int applicationShouldHandleReopen: id app hasVisibleWindows: int flag [ flag 0 = [ show-listener ] when 1 ] ;
  29
  30     METHOD: id factorListener: id app [ show-listener f ] ;
  31
  32     METHOD: id factorBrowser: id app [ show-browser f ] ;
  33
  34     METHOD: id newFactorListener: id app [ listener-window f ] ;
  35
  36     METHOD: id newFactorBrowser: id app [ browser-window f ] ;
  37
  38     METHOD: id runFactorFile: id app [ menu-run-files f ] ;
  39
  40     METHOD: id saveFactorImage: id app [ save f ] ;
  41
  42     METHOD: id saveFactorImageAs: id app [ menu-save-image f ] ;
  43
  44     METHOD: id refreshAll: id app [ [ refresh-all ] \ refresh-all call-listener f ] ;
  45 ;
  46
  47 : install-app-delegate ( -- )
  48     NSApp FactorWorkspaceApplicationDelegate install-delegate ;
  49
  50 ! Service support; evaluate Factor code from other apps
  51 :: do-service ( pboard error quot -- )
  52     pboard error ?pasteboard-string
  53     dup [ quot call( string -- result/f ) ] when
  54     [ pboard set-pasteboard-string ] when* ;
  55
  56 CLASS: FactorServiceProvider < NSObject
  57
  58     METHOD: void evalInListener: id pboard userData: id userData error: id error
  59     [ pboard error [ eval-listener f ] do-service ] ;
  60
  61     METHOD: void evalToString: id pboard userData: id userData error: id error
  62     [
  63         pboard error
  64         [ [ (eval>string) ] with-interactive-vocabs ] do-service
  65     ] ;
  66 ;
  67
  68 : register-services ( -- )
  69     NSApp
  70     FactorServiceProvider -> alloc -> init
  71     -> setServicesProvider: ;
  72
  73 FUNCTION: void NSUpdateDynamicServices ( )
  74
  75 [
  76     install-app-delegate
  77     "Factor.nib" load-nib
  78     register-services
  79 ] cocoa-startup-hook set-global