basis/ui/backend/cocoa/views/views.factor

   1 ! Copyright (C) 2006, 2010 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.data alien.strings
   4 arrays assocs cocoa cocoa.application cocoa.classes
   5 cocoa.pasteboard cocoa.runtime cocoa.subclassing cocoa.touchbar
   6 cocoa.types cocoa.views combinators core-foundation.strings
   7 core-graphics core-graphics.types core-text io.encodings.utf8
   8 kernel literals locals math math.rectangles namespaces opengl
   9 sequences threads ui.gadgets ui.gadgets.private
  10 ui.gadgets.worlds ui.gestures ui.private ui.tools.listener
  11 vocabs.refresh ;
  12 IN: ui.backend.cocoa.views
  13
  14 : send-mouse-moved ( view event -- )
  15     [ mouse-location ] [ drop window ] 2bi
  16     [ move-hand fire-motion yield ] [ drop ] if* ;
  17
  18 ! Issue #1453
  19 : button ( event -- n )
  20     ! Cocoa -> Factor UI button mapping
  21     -> buttonNumber {
  22         { 0 [ 1 ] }
  23         { 1 [ 3 ] }
  24         { 2 [ 2 ] }
  25         [ ]
  26     } case ;
  27
  28 CONSTANT: NSAlphaShiftKeyMask 0x10000
  29 CONSTANT: NSShiftKeyMask      0x20000
  30 CONSTANT: NSControlKeyMask    0x40000
  31 CONSTANT: NSAlternateKeyMask  0x80000
  32 CONSTANT: NSCommandKeyMask    0x100000
  33 CONSTANT: NSNumericPadKeyMask 0x200000
  34 CONSTANT: NSHelpKeyMask       0x400000
  35 CONSTANT: NSFunctionKeyMask   0x800000
  36
  37 CONSTANT: modifiers {
  38         { S+ $ NSShiftKeyMask }
  39         { C+ $ NSControlKeyMask }
  40         { A+ $ NSCommandKeyMask }
  41         { M+ $ NSAlternateKeyMask }
  42     }
  43
  44 CONSTANT: key-codes
  45     H{
  46         { 71 "CLEAR" }
  47         { 36 "RET" }
  48         { 76 "ENTER" }
  49         { 53 "ESC" }
  50         { 48 "TAB" }
  51         { 51 "BACKSPACE" }
  52         { 115 "HOME" }
  53         { 117 "DELETE" }
  54         { 119 "END" }
  55         { 122 "F1" }
  56         { 120 "F2" }
  57         { 99 "F3" }
  58         { 118 "F4" }
  59         { 96 "F5" }
  60         { 97 "F6" }
  61         { 98 "F7" }
  62         { 100 "F8" }
  63         { 123 "LEFT" }
  64         { 124 "RIGHT" }
  65         { 125 "DOWN" }
  66         { 126 "UP" }
  67         { 116 "PAGE_UP" }
  68         { 121 "PAGE_DOWN" }
  69     }
  70
  71 : key-code ( event -- string ? )
  72     dup -> keyCode key-codes at
  73     [ t ] [ -> charactersIgnoringModifiers CF>string f ] ?if ;
  74
  75 : event-modifiers ( event -- modifiers )
  76     -> modifierFlags modifiers modifier ;
  77
  78 : key-event>gesture ( event -- modifiers keycode action? )
  79     [ event-modifiers ] [ key-code ] bi ;
  80
  81 : send-key-event ( view gesture -- )
  82     swap window [ propagate-key-gesture ] [ drop ] if* ;
  83
  84 : interpret-key-event ( view event -- )
  85     NSArray swap -> arrayWithObject: -> interpretKeyEvents: ;
  86
  87 : send-key-down-event ( view event -- )
  88     [ key-event>gesture <key-down> send-key-event ]
  89     [ interpret-key-event ]
  90     2bi ;
  91
  92 : send-key-up-event ( view event -- )
  93     key-event>gesture <key-up> send-key-event ;
  94
  95 : mouse-event>gesture ( event -- modifiers button )
  96     [ event-modifiers ] [ button ] bi ;
  97
  98 : send-button-down$ ( view event -- )
  99     [ nip mouse-event>gesture <button-down> ]
 100     [ mouse-location ]
 101     [ drop window ]
 102     2tri
 103     [ send-button-down ] [ 2drop ] if* ;
 104
 105 : send-button-up$ ( view event -- )
 106     [ nip mouse-event>gesture <button-up> ]
 107     [ mouse-location ]
 108     [ drop window ]
 109     2tri
 110     [ send-button-up ] [ 2drop ] if* ;
 111
 112 : send-scroll$ ( view event -- )
 113     [ nip [ -> deltaX ] [ -> deltaY ] bi [ neg ] bi@ 2array ]
 114     [ mouse-location ]
 115     [ drop window ]
 116     2tri
 117     [ send-scroll ] [ 2drop ] if* ;
 118
 119 : send-action$ ( view event gesture -- )
 120     [ drop window ] dip over [ send-action ] [ 2drop ] if ;
 121
 122 : add-resize-observer ( observer object -- )
 123     [
 124         "updateFactorGadgetSize:"
 125         "NSViewFrameDidChangeNotification" <NSString>
 126     ] dip add-observer ;
 127
 128 : string-or-nil? ( NSString -- ? )
 129     [ CF>string NSStringPboardType = ] [ t ] if* ;
 130
 131 : valid-service? ( gadget send-type return-type -- ? )
 132     2dup [ string-or-nil? ] [ string-or-nil? ] bi* and
 133     [ drop [ gadget-selection? ] [ drop t ] if ] [ 3drop f ] if ;
 134
 135 : NSRect>rect ( NSRect world -- rect )
 136     [ [ [ CGRect-x ] [ CGRect-y ] bi ] [ dim>> second ] bi* swap - 2array ]
 137     [ drop [ CGRect-w ] [ CGRect-h ] bi 2array ]
 138     2bi <rect> ;
 139
 140 : rect>NSRect ( rect world -- NSRect )
 141     [ [ loc>> first2 ] [ dim>> second ] bi* swap - ]
 142     [ drop dim>> first2 ]
 143     2bi <CGRect> ;
 144
 145 CONSTANT: selector>action H{
 146     { "undo:" undo-action }
 147     { "redo:" redo-action }
 148     { "cut:" cut-action }
 149     { "copy:" copy-action }
 150     { "paste:" paste-action }
 151     { "delete:" delete-action }
 152     { "selectAll:" select-all-action }
 153     { "newDocument:" new-action }
 154     { "openDocument:" open-action }
 155     { "saveDocument:" save-action }
 156     { "saveDocumentAs:" save-as-action }
 157     { "revertDocumentToSaved:" revert-action }
 158 }
 159
 160 : validate-action ( world selector -- ? validated? )
 161     selector>action at
 162     [ swap world-focus parents-handle-gesture? t ] [ drop f f ] if* ;
 163
 164 CLASS: FactorView < NSOpenGLView
 165     COCOA-PROTOCOL: NSTextInput
 166
 167     METHOD: void prepareOpenGL [
 168         self SUPER-> prepareOpenGL
 169
 170         self SEL: setWantsBestResolutionOpenGLSurface:
 171         -> respondsToSelector: c-bool> [
 172
 173             self SEL: setWantsBestResolutionOpenGLSurface: 1
 174             void f "objc_msgSend" { id SEL char } f alien-invoke
 175
 176             self SEL: backingScaleFactor
 177             double f "objc_msgSend" { id SEL } f alien-invoke
 178
 179             dup 1.0 > [
 180                 gl-scale-factor set-global t retina? set-global
 181                 cached-lines get-global clear-assoc
 182             ] [ drop ] if
 183
 184         ] when
 185     ] ;
 186
 187     METHOD: void refreshAllAction [
 188         [ refresh-all ] \ refresh-all call-listener
 189     ] ;
 190
 191     METHOD: void autoUseAction [
 192         [ com-auto-use ] \ com-auto-use call-listener
 193     ] ;
 194
 195     METHOD: Class makeTouchBar [ default-touchbar self make-touchbar ] ;
 196
 197     METHOD: Class touchBar: Class touchbar makeItemForIdentifier: Class string [
 198         string CF>string
 199         {
 200             { "refresh-all-action" [
 201                 self "refresh-all-action" "refresh-all" "refreshAllAction" make-NSTouchBar-button
 202             ] }
 203             { "auto-use-action" [
 204                 self "auto-use-action" "auto-use" "autoUseAction" make-NSTouchBar-button
 205             ] }
 206             [ drop f ]
 207         } case
 208     ] ;
 209
 210     ! Rendering
 211     METHOD: void drawRect: NSRect rect [ self window [ draw-world ] when* ] ;
 212
 213     ! Events
 214     METHOD: char acceptsFirstMouse: id event [ 0 ] ;
 215
 216     METHOD: void mouseEntered: id event [ self event send-mouse-moved ] ;
 217
 218     METHOD: void mouseExited: id event [ forget-rollover ] ;
 219
 220     METHOD: void mouseMoved: id event [ self event send-mouse-moved ] ;
 221
 222     METHOD: void mouseDragged: id event [ self event send-mouse-moved ] ;
 223
 224     METHOD: void rightMouseDragged: id event [ self event send-mouse-moved ] ;
 225
 226     METHOD: void otherMouseDragged: id event [ self event send-mouse-moved ] ;
 227
 228     METHOD: void mouseDown: id event [ self event send-button-down$ ] ;
 229
 230     METHOD: void mouseUp: id event [ self event send-button-up$ ] ;
 231
 232     METHOD: void rightMouseDown: id event [ self event send-button-down$ ] ;
 233
 234     METHOD: void rightMouseUp: id event [ self event send-button-up$ ] ;
 235
 236     METHOD: void otherMouseDown: id event [ self event send-button-down$ ] ;
 237
 238     METHOD: void otherMouseUp: id event [ self event send-button-up$ ] ;
 239
 240     METHOD: void scrollWheel: id event [ self event send-scroll$ ] ;
 241
 242     METHOD: void keyDown: id event [ self event send-key-down-event ] ;
 243
 244     METHOD: void keyUp: id event [ self event send-key-up-event ] ;
 245
 246     METHOD: char validateUserInterfaceItem: id event
 247     [
 248         self window [
 249             event -> action utf8 alien>string validate-action
 250             [ >c-bool ] [ drop self event SUPER-> validateUserInterfaceItem: ] if
 251         ] [ 0 ] if*
 252     ] ;
 253
 254     METHOD: id undo: id event [ self event undo-action send-action$ f ] ;
 255
 256     METHOD: id redo: id event [ self event redo-action send-action$ f ] ;
 257
 258     METHOD: id cut: id event [ self event cut-action send-action$ f ] ;
 259
 260     METHOD: id copy: id event [ self event copy-action send-action$ f ] ;
 261
 262     METHOD: id paste: id event [ self event paste-action send-action$ f ] ;
 263
 264     METHOD: id delete: id event [ self event delete-action send-action$ f ] ;
 265
 266     METHOD: id selectAll: id event [ self event select-all-action send-action$ f ] ;
 267
 268     METHOD: id newDocument: id event [ self event new-action send-action$ f ] ;
 269
 270     METHOD: id openDocument: id event [ self event open-action send-action$ f ] ;
 271
 272     METHOD: id saveDocument: id event [ self event save-action send-action$ f ] ;
 273
 274     METHOD: id saveDocumentAs: id event [ self event save-as-action send-action$ f ] ;
 275
 276     METHOD: id revertDocumentToSaved: id event [ self event revert-action send-action$ f ] ;
 277
 278     ! Multi-touch gestures
 279     METHOD: void magnifyWithEvent: id event
 280     [
 281         self event
 282         dup -> deltaZ sgn {
 283             {  1 [ zoom-in-action send-action$ ] }
 284             { -1 [ zoom-out-action send-action$ ] }
 285             {  0 [ 2drop ] }
 286         } case
 287     ] ;
 288
 289     METHOD: void swipeWithEvent: id event
 290     [
 291         self event
 292         dup -> deltaX sgn {
 293             {  1 [ left-action send-action$ ] }
 294             { -1 [ right-action send-action$ ] }
 295             {  0
 296                 [
 297                     dup -> deltaY sgn {
 298                         {  1 [ up-action send-action$ ] }
 299                         { -1 [ down-action send-action$ ] }
 300                         {  0 [ 2drop ] }
 301                     } case
 302                 ]
 303             }
 304         } case
 305     ] ;
 306
 307     METHOD: char acceptsFirstResponder [ 1 ] ;
 308
 309     ! Services
 310     METHOD: id validRequestorForSendType: id sendType returnType: id returnType
 311     [
 312         ! We return either self or nil
 313         self window [
 314             world-focus sendType returnType
 315             valid-service? [ self ] [ f ] if
 316         ] [ f ] if*
 317     ] ;
 318
 319     METHOD: char writeSelectionToPasteboard: id pboard types: id types
 320     [
 321         NSStringPboardType types CF>string-array member? [
 322             self window [
 323                 world-focus gadget-selection
 324                 [ pboard set-pasteboard-string 1 ] [ 0 ] if*
 325             ] [ 0 ] if*
 326         ] [ 0 ] if
 327     ] ;
 328
 329     METHOD: char readSelectionFromPasteboard: id pboard
 330     [
 331         self window :> window
 332         window [
 333             pboard pasteboard-string
 334             [ window user-input 1 ] [ 0 ] if*
 335         ] [ 0 ] if
 336     ] ;
 337
 338     ! Text input
 339     METHOD: void insertText: id text
 340     [
 341         self window :> window
 342         window [
 343             text CF>string window user-input
 344         ] when
 345     ] ;
 346
 347     METHOD: char hasMarkedText [ 0 ] ;
 348
 349     METHOD: NSRange markedRange [ 0 0 <NSRange> ] ;
 350
 351     METHOD: NSRange selectedRange [ 0 0 <NSRange> ] ;
 352
 353     METHOD: void setMarkedText: id text selectedRange: NSRange range [ ] ;
 354
 355     METHOD: void unmarkText [ ] ;
 356
 357     METHOD: id validAttributesForMarkedText [ NSArray -> array ] ;
 358
 359     METHOD: id attributedSubstringFromRange: NSRange range [ f ] ;
 360
 361     METHOD: NSUInteger characterIndexForPoint: NSPoint point [ 0 ] ;
 362
 363     METHOD: NSRect firstRectForCharacterRange: NSRange range [ 0 0 0 0 <CGRect> ] ;
 364
 365     METHOD: NSInteger conversationIdentifier [ self alien-address ] ;
 366
 367     ! Initialization
 368     METHOD: void updateFactorGadgetSize: id notification
 369     [
 370         self window :> window
 371         window [
 372             self view-dim window dim<< yield
 373         ] when
 374     ] ;
 375
 376     METHOD: void doCommandBySelector: SEL selector [ ] ;
 377
 378     METHOD: id initWithFrame: NSRect frame pixelFormat: id pixelFormat
 379     [
 380         self frame pixelFormat SUPER-> initWithFrame:pixelFormat:
 381         dup dup add-resize-observer
 382     ] ;
 383
 384     METHOD: char isOpaque [ 0 ] ;
 385
 386     METHOD: void dealloc
 387     [
 388         self remove-observer
 389         self SUPER-> dealloc
 390     ] ;
 391 ;
 392
 393 : sync-refresh-to-screen ( GLView -- )
 394     -> openGLContext -> CGLContextObj NSOpenGLCPSwapInterval 1 int <ref>
 395     CGLSetParameter drop ;
 396
 397 : <FactorView> ( dim pixel-format -- view )
 398     [ FactorView ] 2dip <GLView> [ sync-refresh-to-screen ] keep ;
 399
 400 : save-position ( world window -- )
 401     -> frame CGRect-top-left 2array >>window-loc drop ;
 402
 403 CLASS: FactorWindowDelegate < NSObject
 404
 405     METHOD: void windowDidMove: id notification
 406     [
 407         notification -> object -> contentView window
 408         [ notification -> object save-position ] when*
 409     ] ;
 410
 411     METHOD: void windowDidBecomeKey: id notification
 412     [
 413         notification -> object -> contentView window
 414         [ focus-world ] when*
 415     ] ;
 416
 417     METHOD: void windowDidResignKey: id notification
 418     [
 419         forget-rollover
 420         notification -> object -> contentView :> view
 421         view window :> window
 422         window [
 423             view -> isInFullScreenMode 0 =
 424             [ window unfocus-world ] when
 425         ] when
 426     ] ;
 427
 428     METHOD: char windowShouldClose: id notification [ 1 ] ;
 429
 430     METHOD: void windowWillClose: id notification
 431     [
 432         notification -> object -> contentView
 433         [ window ungraft ] [ unregister-window ] bi
 434     ] ;
 435
 436     METHOD: void windowDidChangeBackingProperties: id notification
 437     [
 438
 439         notification -> object dup SEL: backingScaleFactor
 440         -> respondsToSelector: c-bool> [
 441             { double { id SEL } } ?-> backingScaleFactor
 442
 443             [ [ 1.0 > ] keep f ? gl-scale-factor set-global ]
 444             [ 1.0 > retina? set-global ] bi
 445         ] [ drop ] if
 446     ] ;
 447 ;
 448
 449 : install-window-delegate ( window -- )
 450     FactorWindowDelegate install-delegate ;