basis/ui/backend/windows/windows.factor

   1 ! Copyright (C) 2005, 2006 Doug Coleman.
   2 ! Portions copyright (C) 2007, 2009 Slava Pestov.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: alien alien.c-types alien.strings arrays assocs ui
   5 ui.private ui.gadgets ui.gadgets.private ui.backend
   6 ui.clipboards ui.gadgets.worlds ui.gestures ui.event-loop io
   7 kernel math math.vectors namespaces make sequences strings
   8 vectors words windows.dwmapi system-info.windows windows.kernel32
   9 windows.gdi32 windows.user32 windows.opengl32 windows.messages
  10 windows.types windows.offscreen windows.nt threads libc combinators
  11 fry combinators.short-circuit continuations command-line shuffle
  12 opengl ui.render math.bitwise locals accessors math.rectangles
  13 math.order calendar ascii sets io.encodings.utf16n
  14 windows.errors literals ui.pixel-formats
  15 ui.pixel-formats.private memoize classes
  16 specialized-arrays classes.struct alien.data ;
  17 SPECIALIZED-ARRAY: POINT
  18 IN: ui.backend.windows
  19
  20 SINGLETON: windows-ui-backend
  21
  22 TUPLE: win-base hDC hRC ;
  23 TUPLE: win < win-base hWnd world title ;
  24 TUPLE: win-offscreen < win-base hBitmap bits ;
  25 C: <win> win
  26 C: <win-offscreen> win-offscreen
  27
  28 <PRIVATE
  29
  30 PIXEL-FORMAT-ATTRIBUTE-TABLE: WGL_ARB { $ WGL_SUPPORT_OPENGL_ARB 1 } H{
  31     { double-buffered { $ WGL_DOUBLE_BUFFER_ARB 1 } }
  32     { stereo { $ WGL_STEREO_ARB 1 } }
  33     { offscreen { $ WGL_DRAW_TO_BITMAP_ARB 1 } }
  34     { fullscreen { $ WGL_DRAW_TO_WINDOW_ARB 1 } }
  35     { windowed { $ WGL_DRAW_TO_WINDOW_ARB 1 } }
  36     { accelerated { $ WGL_ACCELERATION_ARB $ WGL_FULL_ACCELERATION_ARB } }
  37     { software-rendered { $ WGL_ACCELERATION_ARB $ WGL_NO_ACCELERATION_ARB } }
  38     { backing-store { $ WGL_SWAP_METHOD_ARB $ WGL_SWAP_COPY_ARB } }
  39     { color-float { $ WGL_TYPE_RGBA_FLOAT_ARB 1 } }
  40     { color-bits { $ WGL_COLOR_BITS_ARB } }
  41     { red-bits { $ WGL_RED_BITS_ARB } }
  42     { green-bits { $ WGL_GREEN_BITS_ARB } }
  43     { blue-bits { $ WGL_BLUE_BITS_ARB } }
  44     { alpha-bits { $ WGL_ALPHA_BITS_ARB } }
  45     { accum-bits { $ WGL_ACCUM_BITS_ARB } }
  46     { accum-red-bits { $ WGL_ACCUM_RED_BITS_ARB } }
  47     { accum-green-bits { $ WGL_ACCUM_GREEN_BITS_ARB } }
  48     { accum-blue-bits { $ WGL_ACCUM_BLUE_BITS_ARB } }
  49     { accum-alpha-bits { $ WGL_ACCUM_ALPHA_BITS_ARB } }
  50     { depth-bits { $ WGL_DEPTH_BITS_ARB } }
  51     { stencil-bits { $ WGL_STENCIL_BITS_ARB } }
  52     { aux-buffers { $ WGL_AUX_BUFFERS_ARB } }
  53     { sample-buffers { $ WGL_SAMPLE_BUFFERS_ARB } }
  54     { samples { $ WGL_SAMPLES_ARB } }
  55 }
  56
  57 : has-wglChoosePixelFormatARB? ( world -- ? )
  58     drop f ;
  59
  60 : arb-make-pixel-format ( world attributes -- pf )
  61     [ handle>> hDC>> ] dip >WGL_ARB-int-array f 1 0 <int> 0 <int>
  62     [ wglChoosePixelFormatARB win32-error=0/f ] 2keep drop *int ;
  63
  64 : arb-pixel-format-attribute ( pixel-format attribute -- value )
  65     >WGL_ARB
  66     [ drop f ] [
  67         [ [ world>> handle>> hDC>> ] [ handle>> ] bi 0 1 ] dip
  68         first <int> 0 <int>
  69         [ wglGetPixelFormatAttribivARB win32-error=0/f ]
  70         keep *int
  71     ] if-empty ;
  72
  73 CONSTANT: pfd-flag-map H{
  74     { double-buffered $ PFD_DOUBLEBUFFER }
  75     { stereo $ PFD_STEREO }
  76     { offscreen $ PFD_DRAW_TO_BITMAP }
  77     { fullscreen $ PFD_DRAW_TO_WINDOW }
  78     { windowed $ PFD_DRAW_TO_WINDOW }
  79     { backing-store $ PFD_SWAP_COPY }
  80     { software-rendered $ PFD_GENERIC_FORMAT }
  81 }
  82
  83 : >pfd-flag ( attribute -- value )
  84     pfd-flag-map at [ ] [ 0 ] if* ;
  85
  86 : >pfd-flags ( attributes -- flags )
  87     [ >pfd-flag ] [ bitor ] map-reduce
  88     PFD_SUPPORT_OPENGL bitor ;
  89
  90 : attr-value ( attributes name -- value )
  91     [ instance? ] curry find nip
  92     [ value>> ] [ 0 ] if* ;
  93
  94 : >pfd ( attributes -- pfd )
  95     [ PIXELFORMATDESCRIPTOR <struct> ] dip
  96     {
  97         [ drop PIXELFORMATDESCRIPTOR heap-size >>nSize ]
  98         [ drop 1 >>nVersion ]
  99         [ >pfd-flags >>dwFlags ]
 100         [ drop PFD_TYPE_RGBA >>iPixelType ]
 101         [ color-bits attr-value >>cColorBits ]
 102         [ red-bits attr-value >>cRedBits ]
 103         [ green-bits attr-value >>cGreenBits ]
 104         [ blue-bits attr-value >>cBlueBits ]
 105         [ alpha-bits attr-value >>cAlphaBits ]
 106         [ accum-bits attr-value >>cAccumBits ]
 107         [ accum-red-bits attr-value >>cAccumRedBits ]
 108         [ accum-green-bits attr-value >>cAccumGreenBits ]
 109         [ accum-blue-bits attr-value >>cAccumBlueBits ]
 110         [ accum-alpha-bits attr-value >>cAccumAlphaBits ]
 111         [ depth-bits attr-value >>cDepthBits ]
 112         [ stencil-bits attr-value >>cStencilBits ]
 113         [ aux-buffers attr-value >>cAuxBuffers ]
 114         [ drop PFD_MAIN_PLANE >>dwLayerMask ]
 115     } cleave ;
 116
 117 : pfd-make-pixel-format ( world attributes -- pf )
 118     [ handle>> hDC>> ] [ >pfd ] bi*
 119     ChoosePixelFormat dup win32-error=0/f ;
 120
 121 : get-pfd ( pixel-format -- pfd )
 122     [ world>> handle>> hDC>> ] [ handle>> ] bi
 123     PIXELFORMATDESCRIPTOR heap-size
 124     PIXELFORMATDESCRIPTOR <struct>
 125     [ DescribePixelFormat win32-error=0/f ] keep ;
 126
 127 : pfd-flag? ( pfd flag -- ? )
 128     [ dwFlags>> ] dip bitand c-bool> ;
 129
 130 : (pfd-pixel-format-attribute) ( pfd attribute -- value )
 131     {
 132         { double-buffered [ PFD_DOUBLEBUFFER pfd-flag? ] }
 133         { stereo [ PFD_STEREO pfd-flag? ] }
 134         { offscreen [ PFD_DRAW_TO_BITMAP pfd-flag? ] }
 135         { fullscreen [ PFD_DRAW_TO_WINDOW pfd-flag? ] }
 136         { windowed [ PFD_DRAW_TO_WINDOW pfd-flag? ] }
 137         { software-rendered [ PFD_GENERIC_FORMAT pfd-flag? ] }
 138         { color-bits [ cColorBits>> ] }
 139         { red-bits [ cRedBits>> ] }
 140         { green-bits [ cGreenBits>> ] }
 141         { blue-bits [ cBlueBits>> ] }
 142         { alpha-bits [ cAlphaBits>> ] }
 143         { accum-bits [ cAccumBits>> ] }
 144         { accum-red-bits [ cAccumRedBits>> ] }
 145         { accum-green-bits [ cAccumGreenBits>> ] }
 146         { accum-blue-bits [ cAccumBlueBits>> ] }
 147         { accum-alpha-bits [ cAccumAlphaBits>> ] }
 148         { depth-bits [ cDepthBits>> ] }
 149         { stencil-bits [ cStencilBits>> ] }
 150         { aux-buffers [ cAuxBuffers>> ] }
 151         [ 2drop f ]
 152     } case ;
 153
 154 : pfd-pixel-format-attribute ( pixel-format attribute -- value )
 155     [ get-pfd ] dip (pfd-pixel-format-attribute) ;
 156
 157 M: windows-ui-backend (make-pixel-format)
 158     over has-wglChoosePixelFormatARB?
 159     [ arb-make-pixel-format ] [ pfd-make-pixel-format ] if ;
 160
 161 M: windows-ui-backend (free-pixel-format)
 162     drop ;
 163
 164 M: windows-ui-backend (pixel-format-attribute)
 165     over world>> has-wglChoosePixelFormatARB?
 166     [ arb-pixel-format-attribute ] [ pfd-pixel-format-attribute ] if ;
 167
 168 PRIVATE>
 169
 170 : lo-word ( wparam -- lo ) <short> *short ; inline
 171 : hi-word ( wparam -- hi ) -16 shift lo-word ; inline
 172 : >lo-hi ( WORD -- array ) [ lo-word ] [ hi-word ] bi 2array ;
 173
 174 : crlf>lf ( str -- str' )
 175     CHAR: \r swap remove ;
 176
 177 : lf>crlf ( str -- str' )
 178     [ [ dup CHAR: \n = [ CHAR: \r , ] when , ] each ] "" make ;
 179
 180 : enum-clipboard ( -- seq )
 181     0
 182     [ EnumClipboardFormats win32-error dup dup 0 > ]
 183     [ ]
 184     produce 2nip ;
 185
 186 : with-clipboard ( quot -- )
 187     f OpenClipboard win32-error=0/f
 188     call
 189     CloseClipboard win32-error=0/f ; inline
 190
 191 : paste ( -- str )
 192     [
 193         CF_UNICODETEXT IsClipboardFormatAvailable zero? [
 194             ! nothing to paste
 195             ""
 196         ] [
 197             CF_UNICODETEXT GetClipboardData dup win32-error=0/f
 198             dup GlobalLock dup win32-error=0/f
 199             GlobalUnlock win32-error=0/f
 200             utf16n alien>string
 201         ] if
 202     ] with-clipboard
 203     crlf>lf ;
 204
 205 : copy ( str -- )
 206     lf>crlf [
 207         utf16n string>alien
 208         EmptyClipboard win32-error=0/f
 209         GMEM_MOVEABLE over length 1 + GlobalAlloc
 210             dup win32-error=0/f
 211
 212         dup GlobalLock dup win32-error=0/f
 213         swapd byte-array>memory
 214         dup GlobalUnlock win32-error=0/f
 215         CF_UNICODETEXT swap SetClipboardData win32-error=0/f
 216     ] with-clipboard ;
 217
 218 TUPLE: pasteboard ;
 219 C: <pasteboard> pasteboard
 220
 221 M: pasteboard clipboard-contents drop paste ;
 222 M: pasteboard set-clipboard-contents drop copy ;
 223
 224 : init-clipboard ( -- )
 225     <pasteboard> clipboard set-global
 226     <clipboard> selection set-global ;
 227
 228 SYMBOLS: msg-obj class-name-ptr mouse-captured ;
 229
 230 CONSTANT: window-control>style
 231     H{
 232         { close-button 0 }
 233         { textured-background 0 }
 234         { minimize-button $ WS_MINIMIZEBOX }
 235         { maximize-button $ WS_MAXIMIZEBOX }
 236         { resize-handles $ WS_THICKFRAME }
 237         { small-title-bar $ WS_CAPTION }
 238         { normal-title-bar $ WS_CAPTION }
 239     }
 240
 241 CONSTANT: window-control>ex-style
 242     H{
 243         { close-button 0 }
 244         { textured-background 0 }
 245         { minimize-button 0 }
 246         { maximize-button 0 }
 247         { resize-handles $ WS_EX_WINDOWEDGE }
 248         { small-title-bar $ WS_EX_TOOLWINDOW }
 249         { normal-title-bar $ WS_EX_APPWINDOW }
 250     }
 251
 252 : needs-sysmenu? ( controls -- ? )
 253     { close-button minimize-button maximize-button } intersects? ;
 254
 255 : has-titlebar? ( controls -- ? )
 256     { small-title-bar normal-title-bar } intersects? ;
 257
 258 : world>style ( world -- n )
 259     window-controls>>
 260     [ window-control>style symbols>flags ]
 261     [ needs-sysmenu? [ WS_SYSMENU bitor ] when ]
 262     [ has-titlebar? [ WS_POPUP bitor ] unless ] tri ;
 263
 264 : world>ex-style ( world -- n )
 265     window-controls>> window-control>ex-style symbols>flags ;
 266
 267 : get-RECT-top-left ( RECT -- x y )
 268     [ left>> ] [ top>> ] bi ;
 269
 270 : get-RECT-width/height ( RECT -- width height )
 271     [ [ right>> ] [ left>> ] bi - ]
 272     [ [ bottom>> ] [ top>> ] bi - ] bi ;
 273
 274 : get-RECT-dimensions ( RECT -- x y width height )
 275     [ get-RECT-top-left ] [ get-RECT-width/height ] bi ;
 276
 277 : handle-wm-paint ( hWnd uMsg wParam lParam -- )
 278     #! wParam and lParam are unused
 279     #! only paint if width/height both > 0
 280     3drop window relayout-1 yield ;
 281
 282 : handle-wm-size ( hWnd uMsg wParam lParam -- )
 283     2nip
 284     [ lo-word ] keep hi-word 2array
 285     dup { 0 0 } = [ 2drop ] [ swap window [ (>>dim) ] [ drop ] if* ] if ;
 286
 287 : handle-wm-move ( hWnd uMsg wParam lParam -- )
 288     2nip
 289     [ lo-word ] keep hi-word 2array
 290     swap window [ (>>window-loc) ] [ drop ] if* ;
 291
 292 CONSTANT: wm-keydown-codes
 293     H{
 294         { 8 "BACKSPACE" }
 295         { 9 "TAB" }
 296         { 13 "RET" }
 297         { 27 "ESC" }
 298         { 33 "PAGE_UP" }
 299         { 34 "PAGE_DOWN" }
 300         { 35 "END" }
 301         { 36 "HOME" }
 302         { 37 "LEFT" }
 303         { 38 "UP" }
 304         { 39 "RIGHT" }
 305         { 40 "DOWN" }
 306         { 45 "INSERT" }
 307         { 46 "DELETE" }
 308         { 112 "F1" }
 309         { 113 "F2" }
 310         { 114 "F3" }
 311         { 115 "F4" }
 312         { 116 "F5" }
 313         { 117 "F6" }
 314         { 118 "F7" }
 315         { 119 "F8" }
 316         { 120 "F9" }
 317         { 121 "F10" }
 318         { 122 "F11" }
 319         { 123 "F12" }
 320     }
 321
 322 : key-state-down? ( key -- ? )
 323     GetKeyState 16 bit? ;
 324
 325 : left-shift? ( -- ? ) VK_LSHIFT key-state-down? ;
 326 : left-ctrl? ( -- ? ) VK_LCONTROL key-state-down? ;
 327 : left-alt? ( -- ? ) VK_LMENU key-state-down? ;
 328 : right-shift? ( -- ? ) VK_RSHIFT key-state-down? ;
 329 : right-ctrl? ( -- ? ) VK_RCONTROL key-state-down? ;
 330 : right-alt? ( -- ? ) VK_RMENU key-state-down? ;
 331 : shift? ( -- ? ) left-shift? right-shift? or ;
 332 : ctrl? ( -- ? ) left-ctrl? right-ctrl? or ;
 333 : alt? ( -- ? ) left-alt? right-alt? or ;
 334 : caps-lock? ( -- ? ) VK_CAPITAL GetKeyState zero? not ;
 335
 336 : key-modifiers ( -- seq )
 337     [
 338         shift? [ S+ , ] when
 339         ctrl? [ C+ , ] when
 340         alt? [ A+ , ] when
 341     ] { } make [ empty? not ] keep f ? ;
 342
 343 CONSTANT: exclude-keys-wm-keydown
 344     H{
 345         { 16 "SHIFT" }
 346         { 17 "CTRL" }
 347         { 18 "ALT" }
 348         { 20 "CAPS-LOCK" }
 349     }
 350
 351 ! Values are ignored
 352 CONSTANT: exclude-keys-wm-char
 353     H{
 354         { 8 "BACKSPACE" }
 355         { 9 "TAB" }
 356         { 13 "RET" }
 357         { 27 "ESC" }
 358     }
 359
 360 : exclude-key-wm-keydown? ( n -- ? )
 361     exclude-keys-wm-keydown key? ;
 362
 363 : exclude-key-wm-char? ( n -- ? )
 364     exclude-keys-wm-char key? ;
 365
 366 : keystroke>gesture ( n -- mods sym )
 367     wm-keydown-codes at* [ key-modifiers swap ] [ drop f f ] if ;
 368
 369 : send-key-gesture ( sym action? quot hWnd -- )
 370     [ [ key-modifiers ] 3dip call ] dip
 371     window propagate-key-gesture ; inline
 372
 373 : send-key-down ( sym action? hWnd -- )
 374     [ [ <key-down> ] ] dip send-key-gesture ;
 375
 376 : send-key-up ( sym action? hWnd -- )
 377     [ [ <key-up> ] ] dip send-key-gesture ;
 378
 379 : key-sym ( wParam -- string/f action? )
 380     {
 381         {
 382             [ dup LETTER? ]
 383             [ shift? caps-lock? xor [ CHAR: a + CHAR: A - ] unless 1string f ]
 384         }
 385         { [ dup digit? ] [ 1string f ] }
 386         [ wm-keydown-codes at t ]
 387     } cond ;
 388
 389 :: handle-wm-keydown ( hWnd uMsg wParam lParam -- )
 390     wParam exclude-key-wm-keydown? [
 391         wParam key-sym over [
 392             dup ctrl? alt? xor or [
 393                 hWnd send-key-down
 394             ] [ 2drop ] if
 395         ] [ 2drop ] if
 396     ] unless ;
 397
 398 :: handle-wm-char ( hWnd uMsg wParam lParam -- )
 399     wParam exclude-key-wm-char? [
 400         ctrl? alt? xor [
 401             wParam 1string
 402             [ f hWnd send-key-down ]
 403             [ hWnd window user-input ] bi
 404         ] unless
 405     ] unless ;
 406
 407 :: handle-wm-keyup ( hWnd uMsg wParam lParam -- )
 408     wParam exclude-key-wm-keydown? [
 409         wParam key-sym over [
 410             hWnd send-key-up
 411         ] [ 2drop ] if
 412     ] unless ;
 413
 414 :: set-window-active ( hwnd uMsg wParam lParam ? -- n )
 415     ? hwnd window (>>active?)
 416     hwnd uMsg wParam lParam DefWindowProc ;
 417
 418 : handle-wm-syscommand ( hWnd uMsg wParam lParam -- n )
 419     {
 420         { [ over SC_MINIMIZE = ] [ f set-window-active ] }
 421         { [ over SC_RESTORE = ] [ t set-window-active ] }
 422         { [ over SC_MAXIMIZE = ] [ t set-window-active ] }
 423         { [ dup alpha? ] [ 4drop 0 ] }
 424         { [ t ] [ DefWindowProc ] }
 425     } cond ;
 426
 427 : cleanup-window ( handle -- )
 428     dup title>> [ free ] when*
 429     dup hRC>> wglDeleteContext win32-error=0/f
 430     dup hWnd>> swap hDC>> ReleaseDC win32-error=0/f ;
 431
 432 M: windows-ui-backend (close-window)
 433     dup hWnd>> unregister-window
 434     dup cleanup-window
 435     hWnd>> DestroyWindow win32-error=0/f ;
 436
 437 : handle-wm-close ( hWnd uMsg wParam lParam -- )
 438     3drop window ungraft ;
 439
 440 : handle-wm-set-focus ( hWnd uMsg wParam lParam -- )
 441     3drop window [ focus-world ] when* ;
 442
 443 : handle-wm-kill-focus ( hWnd uMsg wParam lParam -- )
 444     3drop window [ unfocus-world ] when* ;
 445
 446 : message>button ( uMsg -- button down? )
 447     {
 448         { WM_LBUTTONDOWN   [ 1 t ] }
 449         { WM_LBUTTONUP     [ 1 f ] }
 450         { WM_MBUTTONDOWN   [ 2 t ] }
 451         { WM_MBUTTONUP     [ 2 f ] }
 452         { WM_RBUTTONDOWN   [ 3 t ] }
 453         { WM_RBUTTONUP     [ 3 f ] }
 454
 455         { WM_NCLBUTTONDOWN [ 1 t ] }
 456         { WM_NCLBUTTONUP   [ 1 f ] }
 457         { WM_NCMBUTTONDOWN [ 2 t ] }
 458         { WM_NCMBUTTONUP   [ 2 f ] }
 459         { WM_NCRBUTTONDOWN [ 3 t ] }
 460         { WM_NCRBUTTONUP   [ 3 f ] }
 461     } case ;
 462
 463 ! If the user clicks in the window border ("non-client area")
 464 ! Windows sends us an NC[LMR]BUTTONDOWN message; but if the
 465 ! mouse is subsequently released outside the NC area, we receive
 466 ! a [LMR]BUTTONUP message and Factor can get confused. So we
 467 ! ignore BUTTONUP's that are a result of an NC*BUTTONDOWN.
 468 SYMBOL: nc-buttons
 469
 470 : handle-wm-ncbutton ( hWnd uMsg wParam lParam -- )
 471     2drop nip
 472     message>button nc-buttons get
 473     swap [ push ] [ delete ] if ;
 474
 475 : mouse-wheel ( wParam -- array ) >lo-hi [ sgn neg ] map ;
 476
 477 : mouse-event>gesture ( uMsg -- button )
 478     key-modifiers swap message>button
 479     [ <button-down> ] [ <button-up> ] if ;
 480
 481 :: prepare-mouse ( hWnd uMsg wParam lParam -- button coordinate world )
 482     uMsg mouse-event>gesture
 483     lParam >lo-hi
 484     hWnd window ;
 485
 486 : set-capture ( hwnd -- )
 487     mouse-captured get [
 488         drop
 489     ] [
 490         [ SetCapture drop ] keep
 491         mouse-captured set
 492     ] if ;
 493
 494 : release-capture ( -- )
 495     ReleaseCapture win32-error=0/f
 496     mouse-captured off ;
 497
 498 : handle-wm-buttondown ( hWnd uMsg wParam lParam -- )
 499     [
 500         over set-capture
 501         dup message>button drop nc-buttons get delete
 502     ] 2dip prepare-mouse send-button-down ;
 503
 504 : handle-wm-buttonup ( hWnd uMsg wParam lParam -- )
 505     mouse-captured get [ release-capture ] when
 506     pick message>button drop dup nc-buttons get member? [
 507         nc-buttons get delete 4drop
 508     ] [
 509         drop prepare-mouse send-button-up
 510     ] if ;
 511
 512 : make-TRACKMOUSEEVENT ( hWnd -- alien )
 513     TRACKMOUSEEVENT <struct>
 514         swap >>hwndTrack
 515         TRACKMOUSEEVENT heap-size >>cbSize ;
 516
 517 : handle-wm-mousemove ( hWnd uMsg wParam lParam -- )
 518     2nip
 519     over make-TRACKMOUSEEVENT
 520         TME_LEAVE >>dwFlags
 521         0 >>dwHoverTime
 522     TrackMouseEvent drop
 523     >lo-hi swap window move-hand fire-motion ;
 524
 525 :: handle-wm-mousewheel ( hWnd uMsg wParam lParam -- )
 526     wParam mouse-wheel hand-loc get hWnd window send-wheel ;
 527
 528 : handle-wm-cancelmode ( hWnd uMsg wParam lParam -- )
 529     #! message sent if windows needs application to stop dragging
 530     4drop release-capture ;
 531
 532 : handle-wm-mouseleave ( hWnd uMsg wParam lParam -- )
 533     #! message sent if mouse leaves main application
 534     4drop forget-rollover ;
 535
 536 SYMBOL: wm-handlers
 537
 538 H{ } clone wm-handlers set-global
 539
 540 : add-wm-handler ( quot wm -- )
 541     dup array?
 542     [ [ execute( -- wm ) add-wm-handler ] with each ]
 543     [ wm-handlers get-global set-at ] if ;
 544
 545 [ handle-wm-close 0                  ] WM_CLOSE add-wm-handler
 546 [ 4dup handle-wm-paint DefWindowProc ] WM_PAINT add-wm-handler
 547
 548 [ handle-wm-size 0 ] WM_SIZE add-wm-handler
 549 [ handle-wm-move 0 ] WM_MOVE add-wm-handler
 550
 551 [ 4dup handle-wm-keydown DefWindowProc ] { WM_KEYDOWN WM_SYSKEYDOWN } add-wm-handler
 552 [ 4dup handle-wm-char DefWindowProc    ] { WM_CHAR WM_SYSCHAR }       add-wm-handler
 553 [ 4dup handle-wm-keyup DefWindowProc   ] { WM_KEYUP WM_SYSKEYUP }     add-wm-handler
 554
 555 [ handle-wm-syscommand   ] WM_SYSCOMMAND add-wm-handler
 556 [ handle-wm-set-focus 0  ] WM_SETFOCUS add-wm-handler
 557 [ handle-wm-kill-focus 0 ] WM_KILLFOCUS add-wm-handler
 558
 559 [ handle-wm-buttondown 0 ] WM_LBUTTONDOWN add-wm-handler
 560 [ handle-wm-buttondown 0 ] WM_MBUTTONDOWN add-wm-handler
 561 [ handle-wm-buttondown 0 ] WM_RBUTTONDOWN add-wm-handler
 562 [ handle-wm-buttonup 0   ] WM_LBUTTONUP   add-wm-handler
 563 [ handle-wm-buttonup 0   ] WM_MBUTTONUP   add-wm-handler
 564 [ handle-wm-buttonup 0   ] WM_RBUTTONUP   add-wm-handler
 565
 566 [ 4dup handle-wm-ncbutton DefWindowProc ]
 567 { WM_NCLBUTTONDOWN WM_NCMBUTTONDOWN WM_NCRBUTTONDOWN
 568 WM_NCLBUTTONUP WM_NCMBUTTONUP WM_NCRBUTTONUP }
 569 add-wm-handler
 570
 571 [ nc-buttons get-global delete-all DefWindowProc ]
 572 { WM_EXITSIZEMOVE WM_EXITMENULOOP } add-wm-handler
 573
 574 [ handle-wm-mousemove 0  ] WM_MOUSEMOVE  add-wm-handler
 575 [ handle-wm-mousewheel 0 ] WM_MOUSEWHEEL add-wm-handler
 576 [ handle-wm-cancelmode 0 ] WM_CANCELMODE add-wm-handler
 577 [ handle-wm-mouseleave 0 ] WM_MOUSELEAVE add-wm-handler
 578
 579 SYMBOL: trace-messages?
 580
 581 ! return 0 if you handle the message, else just let DefWindowProc return its val
 582 : ui-wndproc ( -- object )
 583     "uint" { "void*" "uint" "long" "long" } "stdcall" [
 584         pick
 585         trace-messages? get-global [ dup windows-message-name name>> print flush ] when
 586         wm-handlers get-global at* [ call ] [ drop DefWindowProc ] if
 587      ] alien-callback ;
 588
 589 : peek-message? ( msg -- ? ) f 0 0 PM_REMOVE PeekMessage zero? ;
 590
 591 M: windows-ui-backend do-events
 592     msg-obj get-global
 593     dup peek-message? [ drop ui-wait ] [
 594         [ TranslateMessage drop ]
 595         [ DispatchMessage drop ] bi
 596     ] if ;
 597
 598 :: register-window-class ( class-name-ptr -- )
 599     WNDCLASSEX <struct> f GetModuleHandle
 600     class-name-ptr pick GetClassInfoEx 0 = [
 601         WNDCLASSEX heap-size >>cbSize
 602         { CS_HREDRAW CS_VREDRAW CS_OWNDC } flags >>style
 603         ui-wndproc >>lpfnWndProc
 604         0 >>cbClsExtra
 605         0 >>cbWndExtra
 606         f GetModuleHandle >>hInstance
 607         f GetModuleHandle "fraptor" utf16n string>alien LoadIcon >>hIcon
 608         f IDC_ARROW LoadCursor >>hCursor
 609
 610         class-name-ptr >>lpszClassName
 611         RegisterClassEx win32-error=0/f
 612     ] [ drop ] if ;
 613
 614 : adjust-RECT ( RECT style ex-style -- )
 615     [ 0 ] dip AdjustWindowRectEx win32-error=0/f ;
 616
 617 : make-RECT ( world -- RECT )
 618     [ window-loc>> ] [ dim>> ] bi <RECT> ;
 619
 620 : default-position-RECT ( RECT -- RECT' )
 621     dup get-RECT-width/height
 622         [ CW_USEDEFAULT + >>right ] dip
 623         CW_USEDEFAULT + >>bottom
 624         CW_USEDEFAULT >>left
 625         CW_USEDEFAULT >>top ;
 626
 627 : make-adjusted-RECT ( rect style ex-style -- RECT )
 628     [
 629         make-RECT
 630         dup get-RECT-top-left [ zero? ] both? swap
 631         dup
 632     ] 2dip adjust-RECT
 633     swap [ default-position-RECT ] when ;
 634
 635 : get-window-class ( -- class-name )
 636     class-name-ptr [
 637         dup expired? [ drop "Factor-window" utf16n malloc-string ] when
 638         dup register-window-class
 639         dup
 640     ] change-global ;
 641
 642 :: create-window ( rect style ex-style -- hwnd )
 643     rect style ex-style make-adjusted-RECT
 644     [ get-window-class f ] dip
 645     [
 646         [ ex-style ] 2dip
 647         WS_CLIPSIBLINGS WS_CLIPCHILDREN bitor style bitor
 648     ] dip get-RECT-dimensions
 649     f f f GetModuleHandle f CreateWindowEx dup win32-error=0/f ;
 650
 651 : show-window ( hWnd -- )
 652     dup SW_SHOW ShowWindow drop ! always succeeds
 653     dup SetForegroundWindow drop
 654     SetFocus drop ;
 655
 656 : init-win32-ui ( -- )
 657     V{ } clone nc-buttons set-global
 658     MSG malloc-struct msg-obj set-global
 659     GetDoubleClickTime milliseconds double-click-timeout set-global ;
 660
 661 : cleanup-win32-ui ( -- )
 662     class-name-ptr [ [ [ f UnregisterClass drop ] [ free ] bi ] when* f ] change-global
 663     msg-obj [ [ free ] when* f ] change-global ;
 664
 665 : get-dc ( world -- )
 666     handle>> dup hWnd>> GetDC dup win32-error=0/f >>hDC drop ;
 667
 668 : get-rc ( world -- )
 669     handle>> dup hDC>> dup wglCreateContext dup win32-error=0/f
 670     [ wglMakeCurrent win32-error=0/f ] keep >>hRC drop ;
 671
 672 : set-pixel-format ( pixel-format hdc -- )
 673     swap handle>>
 674     PIXELFORMATDESCRIPTOR <struct> SetPixelFormat win32-error=0/f ;
 675
 676 : setup-gl ( world -- )
 677     [ get-dc ] keep
 678     [ swap [ handle>> hDC>> set-pixel-format ] [ get-rc ] bi ]
 679     with-world-pixel-format ;
 680
 681 : disable-close-button ( hwnd -- )
 682     0 GetSystemMenu
 683     SC_CLOSE MF_BYCOMMAND MF_GRAYED bitor EnableMenuItem drop ;
 684
 685 : ?make-glass ( world hwnd -- )
 686     swap { [ transparent?>> ] [ drop windows-major 6 >= ] } 1&&
 687     [ full-window-margins DwmExtendFrameIntoClientArea drop ]
 688     [ drop ] if ;
 689
 690 : ?disable-close-button ( world hwnd -- )
 691     swap window-controls>> close-button swap member? not
 692     [ disable-close-button ] [ drop ] if ;
 693
 694 M: windows-ui-backend (open-window) ( world -- )
 695     [
 696         dup
 697         [ ] [ world>style ] [ world>ex-style ] tri create-window
 698         [ ?make-glass ]
 699         [ ?disable-close-button ]
 700         [ [ f f ] dip f f <win> >>handle setup-gl ] 2tri
 701     ]
 702     [ dup handle>> hWnd>> register-window ]
 703     [ handle>> hWnd>> show-window ] tri ;
 704
 705 M: win-base select-gl-context ( handle -- )
 706     [ hDC>> ] [ hRC>> ] bi wglMakeCurrent win32-error=0/f
 707     GdiFlush drop ;
 708
 709 M: win-base flush-gl-context ( handle -- )
 710     hDC>> SwapBuffers win32-error=0/f ;
 711
 712 : setup-offscreen-gl ( world -- )
 713     dup [ handle>> ] [ dim>> ] bi make-offscreen-dc-and-bitmap
 714     [ >>hDC ] [ >>hBitmap ] [ >>bits ] tri* drop [
 715         swap [ handle>> hDC>> set-pixel-format ] [ get-rc ] bi
 716     ] with-world-pixel-format ;
 717
 718 M: windows-ui-backend (open-offscreen-buffer) ( world -- )
 719     win-offscreen new >>handle
 720     setup-offscreen-gl ;
 721
 722 M: windows-ui-backend (close-offscreen-buffer) ( handle -- )
 723     [ hDC>> DeleteDC drop ]
 724     [ hBitmap>> DeleteObject drop ] bi ;
 725
 726 ! Windows 32-bit bitmaps don't actually use the alpha byte of
 727 ! each pixel; it's left as zero
 728
 729 : (make-opaque) ( byte-array -- byte-array' )
 730     [ length 4 /i ]
 731     [ '[ 255 swap 4 * 3 + _ set-nth ] each ]
 732     [ ] tri ;
 733
 734 : (opaque-pixels) ( world -- pixels )
 735     [ handle>> bits>> ] [ dim>> ] bi bitmap>byte-array (make-opaque) ;
 736
 737 M: windows-ui-backend offscreen-pixels ( world -- alien w h )
 738     [ (opaque-pixels) ] [ dim>> first2 ] bi ;
 739
 740 M: windows-ui-backend raise-window* ( world -- )
 741     handle>> [ hWnd>> SetFocus drop ] when* ;
 742
 743 M: windows-ui-backend set-title ( string world -- )
 744     handle>>
 745     dup title>> [ free ] when*
 746     swap utf16n malloc-string
 747     [ >>title ]
 748     [ [ hWnd>> WM_SETTEXT 0 ] dip alien-address SendMessage drop ] bi ;
 749
 750 M: windows-ui-backend (with-ui)
 751     [
 752         [
 753             init-clipboard
 754             init-win32-ui
 755             start-ui
 756             event-loop
 757         ] [ cleanup-win32-ui ] [ ] cleanup
 758     ] ui-running ;
 759
 760 M: windows-ui-backend beep ( -- )
 761     0 MessageBeep drop ;
 762
 763 : fullscreen-RECT ( hwnd -- RECT )
 764     MONITOR_DEFAULTTONEAREST MonitorFromWindow
 765     MONITORINFOEX <struct>
 766         MONITORINFOEX heap-size >>cbSize
 767     [ GetMonitorInfo win32-error=0/f ] keep rcMonitor>> ;
 768
 769 : client-area>RECT ( hwnd -- RECT )
 770     RECT <struct>
 771     [ GetClientRect win32-error=0/f ]
 772     [ >c-ptr byte-array>POINT-array [ ClientToScreen drop ] with each ]
 773     [ nip ] 2tri ;
 774
 775 : hwnd>RECT ( hwnd -- RECT )
 776     RECT <struct> [ GetWindowRect win32-error=0/f ] keep ;
 777
 778 M: windows-ui-backend (grab-input) ( handle -- )
 779     0 ShowCursor drop
 780     hWnd>> client-area>RECT ClipCursor drop ;
 781
 782 M: windows-ui-backend (ungrab-input) ( handle -- )
 783     drop
 784     f ClipCursor drop
 785     1 ShowCursor drop ;
 786
 787 : fullscreen-flags ( -- n )
 788     { WS_CAPTION WS_BORDER WS_THICKFRAME } flags ; inline
 789
 790 : enter-fullscreen ( world -- )
 791     handle>> hWnd>>
 792     {
 793         [
 794             GWL_STYLE GetWindowLong
 795             fullscreen-flags unmask
 796         ]
 797         [ GWL_STYLE rot SetWindowLong win32-error=0/f ]
 798         [
 799             HWND_TOP
 800             over hwnd>RECT get-RECT-dimensions
 801             SWP_FRAMECHANGED
 802             SetWindowPos win32-error=0/f
 803         ]
 804         [ SW_MAXIMIZE ShowWindow win32-error=0/f ]
 805     } cleave ;
 806
 807 : exit-fullscreen ( world -- )
 808     dup handle>> hWnd>>
 809     {
 810         [ GWL_STYLE rot world>style SetWindowLong win32-error=0/f ]
 811         [
 812             f
 813             over hwnd>RECT get-RECT-dimensions
 814             { SWP_NOMOVE SWP_NOSIZE SWP_NOZORDER SWP_FRAMECHANGED } flags
 815             SetWindowPos win32-error=0/f
 816         ]
 817         [ SW_RESTORE ShowWindow win32-error=0/f ]
 818     } cleave ;
 819
 820 M: windows-ui-backend (set-fullscreen) ( ? world -- )
 821     [ enter-fullscreen ] [ exit-fullscreen ] if ;
 822
 823 M: windows-ui-backend (fullscreen?) ( world -- ? )
 824     [ handle>> hWnd>> hwnd>RECT ]
 825     [ handle>> hWnd>> fullscreen-RECT ] bi
 826     [ get-RECT-dimensions 2array 2nip ] bi@ = ;
 827
 828 windows-ui-backend ui-backend set-global
 829
 830 [ "ui.tools" ] main-vocab-hook set-global