basis/ui/gadgets/borders/borders.factor

   1 ! Copyright (C) 2005, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays ui.gadgets kernel math
   4 namespaces vectors sequences math.vectors math.geometry.rect ;
   5 IN: ui.gadgets.borders
   6
   7 TUPLE: border < gadget
   8 { size initial: { 0 0 } }
   9 { fill initial: { 0 0 } }
  10 { align initial: { 1/2 1/2 } } ;
  11
  12 : new-border ( child class -- border )
  13     new-gadget swap add-gadget ; inline
  14
  15 : <border> ( child gap -- border )
  16     swap border new-border
  17         swap dup 2array >>size ;
  18
  19 M: border pref-dim*
  20     [ size>> 2 v*n ] keep
  21     gadget-child pref-dim v+ ;
  22
  23 : border-major-dim ( border -- dim )
  24     [ dim>> ] [ size>> 2 v*n ] bi v- ;
  25
  26 : border-minor-dim ( border -- dim )
  27     gadget-child pref-dim ;
  28
  29 : scale ( a b s -- c )
  30     tuck { 1 1 } swap v- [ v* ] 2bi@ v+ ;
  31
  32 : border-dim ( border -- dim )
  33     [ border-major-dim ] [ border-minor-dim ] [ fill>> ] tri scale ;
  34
  35 : border-loc ( border dim -- loc )
  36     [ [ size>> ] [ align>> ] [ border-major-dim ] tri ] dip
  37     v- v* v+ [ >fixnum ] map ;
  38
  39 : border-child-rect ( border -- rect )
  40     dup border-dim [ border-loc ] keep <rect> ;
  41
  42 M: border layout*
  43     dup border-child-rect swap gadget-child
  44     over loc>> >>loc
  45     swap dim>> >>dim
  46     drop ;
  47
  48 M: border focusable-child*
  49     gadget-child ;