basis/ui/gadgets/buttons/buttons.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs classes colors colors.constants combinators
   4 combinators.short-circuit combinators.smart fry kernel locals
   5 math.vectors models namespaces sequences ui.commands ui.gadgets
   6 ui.gadgets.borders ui.gadgets.labels ui.gadgets.packs
   7 ui.gadgets.theme ui.gadgets.tracks ui.gadgets.worlds ui.gestures
   8 ui.pens ui.pens.image ui.pens.solid ui.pens.tile ;
   9 FROM: models => change-model ;
  10 IN: ui.gadgets.buttons
  11
  12 TUPLE: button < border pressed? selected? quot tooltip ;
  13
  14 <PRIVATE
  15
  16 : find-button ( gadget -- button )
  17     [ button? ] find-parent ;
  18
  19 : buttons-down? ( -- ? )
  20     hand-buttons get-global empty? not ;
  21
  22 : button-rollover? ( button -- ? )
  23     hand-gadget get-global child? ;
  24
  25 : mouse-clicked? ( gadget -- ? )
  26     hand-clicked get-global child? ;
  27
  28 : button-pressed? ( button -- ? )
  29     { [ mouse-clicked? ] [ button-rollover? ] } 1&&
  30     buttons-down? and ;
  31
  32 PRIVATE>
  33
  34 : button-update ( button -- )
  35     dup button-pressed? >>pressed? relayout-1 ;
  36
  37 : button-enter ( button -- )
  38     dup tooltip>> [ over show-status ] when* button-update ;
  39
  40 : button-leave ( button -- )
  41     [ hide-status ] [ button-update ] bi ;
  42
  43 : button-clicked ( button -- )
  44     [ ]
  45     [ button-update ]
  46     [ button-rollover? ] tri
  47     [ dup quot>> call( button -- ) ] [ drop ] if ;
  48
  49 button H{
  50     { T{ button-up } [ button-clicked ] }
  51     { T{ button-down } [ button-update ] }
  52     { mouse-leave [ button-leave ] }
  53     { mouse-enter [ button-enter ] }
  54 } set-gestures
  55
  56 : new-button ( label quot class -- button )
  57     [ swap >label ] dip new-border swap >>quot ; inline
  58
  59 : <button> ( label quot: ( button -- ) -- button )
  60     button new-button ;
  61
  62 TUPLE: button-pen
  63 plain rollover
  64 pressed selected pressed-selected ;
  65
  66 C: <button-pen> button-pen
  67
  68 : lookup-button-pen ( button pen -- button pen )
  69     over find-button {
  70         { [ dup { [ pressed?>> ] [ selected?>> ] } 1&& ] [
  71             drop pressed-selected>>
  72         ] }
  73         { [ dup pressed?>> ] [ drop pressed>> ] }
  74         { [ dup selected?>> ] [ drop selected>> ] }
  75         { [ dup button-rollover? ] [ drop rollover>> ] }
  76         [ drop plain>> ]
  77     } cond ;
  78
  79 M: button-pen draw-interior
  80     lookup-button-pen [ draw-interior ] [ drop ] if* ;
  81
  82 M: button-pen draw-boundary
  83     lookup-button-pen [ draw-boundary ] [ drop ] if* ;
  84
  85 M: button-pen pen-pref-dim
  86     [
  87         {
  88             [ plain>> pen-pref-dim ]
  89             [ rollover>> pen-pref-dim ]
  90             [ pressed>> pen-pref-dim ]
  91             [ selected>> pen-pref-dim ]
  92         } 2cleave
  93     ] [ vmax ] reduce-outputs ;
  94
  95 M: button-pen pen-background
  96     lookup-button-pen pen-background ;
  97
  98 M: button-pen pen-foreground
  99     lookup-button-pen pen-foreground ;
 100
 101 <PRIVATE
 102
 103 : align-left ( button -- button )
 104     { 0 1/2 } >>align ; inline
 105
 106 : roll-button-theme ( button -- button )
 107     f roll-button-rollover-border <solid> dup f f <button-pen> >>boundary
 108     f f roll-button-selected-background <solid> f f <button-pen> >>interior
 109     align-left ; inline
 110
 111 PRIVATE>
 112
 113 : <roll-button> ( label quot: ( button -- ) -- button )
 114     <button> roll-button-theme ;
 115
 116 <PRIVATE
 117
 118 : <border-button-state-pen> ( prefix background foreground -- pen )
 119     [
 120         "-left" "-middle" "-right"
 121         [ append theme-image ] tri-curry@ tri
 122     ] 2dip <tile-pen> ;
 123
 124 : <border-button-pen> ( -- pen )
 125     "button" transparent button-text-color
 126     <border-button-state-pen> dup
 127     "button-clicked" transparent button-clicked-text-color
 128     <border-button-state-pen> dup dup
 129     <button-pen> ;
 130
 131 : border-button-label-theme ( gadget -- )
 132     dup label? [ [ clone t >>bold? ] change-font ] when drop ;
 133
 134 : border-button-theme ( gadget -- gadget )
 135     dup gadget-child border-button-label-theme
 136     horizontal >>orientation
 137     <border-button-pen> >>interior
 138     dup dup interior>> pen-pref-dim >>min-dim
 139     { 10 0 } >>size ; inline
 140
 141 PRIVATE>
 142
 143 : <border-button> ( label quot: ( button -- ) -- button )
 144     <button> border-button-theme ;
 145
 146 TUPLE: repeat-button < button ;
 147
 148 repeat-button H{
 149     { T{ button-down } [ button-clicked ] }
 150     { T{ drag } [ button-clicked ] }
 151     { T{ button-up } [ button-update ] }
 152 } set-gestures
 153
 154 : <repeat-button> ( label quot: ( button -- ) -- button )
 155     ! Button that calls the quotation every 100ms as long as
 156     ! the mouse is held down.
 157     repeat-button new-button border-button-theme ;
 158
 159 <PRIVATE
 160
 161 : <checkmark-pen> ( -- pen )
 162     "checkbox" theme-image <image-pen>
 163     "checkbox" theme-image <image-pen>
 164     "checkbox-clicked" theme-image <image-pen>
 165     "checkbox-set" theme-image <image-pen>
 166     "checkbox-set-clicked" theme-image <image-pen>
 167     <button-pen> ;
 168
 169 : <checkmark> ( -- gadget )
 170     <gadget>
 171     <checkmark-pen> >>interior
 172     dup dup interior>> pen-pref-dim >>dim ;
 173
 174 : toggle-model ( model -- )
 175     [ not ] change-model ;
 176
 177 PRIVATE>
 178
 179 TUPLE: checkbox < button ;
 180
 181 : <checkbox> ( model label -- checkbox )
 182     <checkmark> label-on-right
 183     [ model>> toggle-model ]
 184     checkbox new-button
 185         swap >>model
 186         align-left ;
 187
 188 M: checkbox model-changed
 189     swap value>> >>selected? relayout-1 ;
 190
 191 <PRIVATE
 192
 193 : <radio-pen> ( -- pen )
 194     "radio" theme-image <image-pen>
 195     "radio" theme-image <image-pen>
 196     "radio-clicked" theme-image <image-pen>
 197     "radio-set" theme-image <image-pen>
 198     "radio-set-clicked" theme-image <image-pen>
 199     <button-pen> ;
 200
 201 : <radio-knob> ( -- gadget )
 202     <gadget>
 203     <radio-pen> >>interior
 204     dup dup interior>> pen-pref-dim >>dim ;
 205
 206 TUPLE: radio-control < button value ;
 207
 208 : <radio-control> ( value model label -- control )
 209     [ [ value>> ] keep set-control-value ]
 210     radio-control new-button
 211         swap >>model
 212         swap >>value
 213         align-left ; inline
 214
 215 M: radio-control model-changed
 216     2dup [ value>> ] same? >>selected? relayout-1 drop ;
 217
 218 :: <radio-controls> ( model assoc parent quot: ( value model label -- gadget ) -- parent )
 219     parent assoc [ model swap quot call add-gadget ] assoc-each ; inline
 220
 221 PRIVATE>
 222
 223 : <radio-button> ( value model label -- gadget )
 224     <radio-knob> label-on-right <radio-control> ;
 225
 226 : <radio-buttons> ( model assoc -- gadget )
 227     <filled-pile>
 228         [ <radio-button> ] <radio-controls>
 229         { 5 5 } >>gap ;
 230
 231 : command-button-quot ( target command -- quot )
 232     '[ _ _ invoke-command ] ;
 233
 234 : gesture>tooltip ( gesture -- str/f )
 235     gesture>string dup [ "Shortcut: " prepend ] when ;
 236
 237 :: <command-button> ( target gesture command -- button )
 238     command command-name
 239     target command command-button-quot
 240     '[ drop @ ] <border-button>
 241     gesture gesture>tooltip >>tooltip ; inline