basis/ui/gadgets/buttons/buttons.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs colors combinators combinators.short-circuit
   4 combinators.smart fry kernel locals math.vectors memoize models
   5 namespaces sequences ui.commands ui.gadgets ui.gadgets.borders
   6 ui.gadgets.labels ui.gadgets.packs ui.theme ui.gadgets.worlds
   7 ui.gestures ui.pens ui.pens.image ui.pens.solid ui.pens.tile
   8 ui.theme.images ;
   9 FROM: models => change-model ;
  10 IN: ui.gadgets.buttons
  11
  12 TUPLE: button < border pressed? selected? quot tooltip ;
  13
  14 <PRIVATE
  15
  16 : find-button ( gadget -- button )
  17     [ button? ] find-parent ;
  18
  19 : buttons-down? ( -- ? )
  20     hand-buttons get-global empty? not ;
  21
  22 : button-rollover? ( button -- ? )
  23     hand-gadget get-global child? ;
  24
  25 : mouse-clicked? ( gadget -- ? )
  26     hand-clicked get-global child? ;
  27
  28 : button-pressed? ( button -- ? )
  29     { [ mouse-clicked? ] [ button-rollover? ] } 1&&
  30     buttons-down? and ;
  31
  32 PRIVATE>
  33
  34 : button-update ( button -- )
  35     dup button-pressed? >>pressed? relayout-1 ;
  36
  37 : button-enter ( button -- )
  38     dup tooltip>> [ over show-status ] when* button-update ;
  39
  40 : button-leave ( button -- )
  41     [ hide-status ] [ button-update ] bi ;
  42
  43 : button-clicked ( button -- )
  44     [ ]
  45     [ button-update ]
  46     [ button-rollover? ] tri
  47     [ dup quot>> call( button -- ) ] [ drop ] if ;
  48
  49 button H{
  50     { T{ button-up } [ button-clicked ] }
  51     { T{ button-down } [ button-update ] }
  52     { mouse-leave [ button-leave ] }
  53     { mouse-enter [ button-enter ] }
  54 } set-gestures
  55
  56 : new-button ( label quot class -- button )
  57     [ swap >label ] dip new-border swap >>quot ; inline
  58
  59 : <button> ( label quot: ( button -- ) -- button )
  60     button new-button ;
  61
  62 TUPLE: button-pen
  63     plain rollover
  64     pressed selected pressed-selected ;
  65
  66 C: <button-pen> button-pen
  67
  68 : lookup-button-pen ( button pen -- button pen )
  69     over find-button {
  70         { [ dup { [ pressed?>> ] [ selected?>> ] } 1&& ] [
  71             drop pressed-selected>>
  72         ] }
  73         { [ dup pressed?>> ] [ drop pressed>> ] }
  74         { [ dup selected?>> ] [ drop selected>> ] }
  75         { [ dup button-rollover? ] [ drop rollover>> ] }
  76         [ drop plain>> ]
  77     } cond ;
  78
  79 M: button-pen draw-interior
  80     lookup-button-pen [ draw-interior ] [ drop ] if* ;
  81
  82 M: button-pen draw-boundary
  83     lookup-button-pen [ draw-boundary ] [ drop ] if* ;
  84
  85 M: button-pen pen-pref-dim
  86     [
  87         {
  88             [ plain>> pen-pref-dim ]
  89             [ rollover>> pen-pref-dim ]
  90             [ pressed>> pen-pref-dim ]
  91             [ selected>> pen-pref-dim ]
  92         } 2cleave
  93     ] [ vmax ] reduce-outputs ;
  94
  95 M: button-pen pen-background
  96     lookup-button-pen pen-background ;
  97
  98 M: button-pen pen-foreground
  99     lookup-button-pen pen-foreground ;
 100
 101 <PRIVATE
 102
 103 : align-left ( button -- button )
 104     { 0 1/2 } >>align ; inline
 105
 106 MEMO: button-pen-boundary ( -- button-pen )
 107     f roll-button-rollover-border <solid> dup f f <button-pen> ;
 108
 109 MEMO: button-pen-interior ( -- button-pen )
 110     f f roll-button-selected-background <solid> f f <button-pen> ;
 111
 112 : roll-button-theme ( button -- button )
 113     button-pen-boundary >>boundary
 114     button-pen-interior >>interior
 115     align-left ; inline
 116
 117 PRIVATE>
 118
 119 : <roll-button> ( label quot: ( button -- ) -- button )
 120     <button> roll-button-theme ;
 121
 122 <PRIVATE
 123
 124 : <border-button-state-pen> ( prefix background foreground -- pen )
 125     [
 126         "-left" "-middle" "-right"
 127         [ append theme-image ] tri-curry@ tri
 128     ] 2dip <tile-pen> ;
 129
 130 : <border-button-pen> ( -- pen )
 131     "button" transparent button-text-color
 132     <border-button-state-pen> dup
 133     "button-clicked" transparent button-clicked-text-color
 134     <border-button-state-pen> dup dup
 135     <button-pen> ;
 136
 137 : border-button-label-theme ( gadget -- )
 138     dup label? [ [ clone t >>bold? ] change-font ] when drop ;
 139
 140 : border-button-theme ( gadget -- gadget )
 141     dup gadget-child border-button-label-theme
 142     horizontal >>orientation
 143     <border-button-pen> >>interior
 144     dup dup interior>> pen-pref-dim >>min-dim
 145     { 10 0 } >>size ; inline
 146
 147 PRIVATE>
 148
 149 : <border-button> ( label quot: ( button -- ) -- button )
 150     <button> border-button-theme ;
 151
 152 TUPLE: repeat-button < button ;
 153
 154 repeat-button H{
 155     { T{ button-down } [ button-clicked ] }
 156     { T{ drag } [ button-clicked ] }
 157     { T{ button-up } [ button-update ] }
 158 } set-gestures
 159
 160 : <repeat-button> ( label quot: ( button -- ) -- button )
 161     ! Button that calls the quotation every 100ms as long as
 162     ! the mouse is held down.
 163     repeat-button new-button border-button-theme ;
 164
 165 <PRIVATE
 166
 167 : <checkmark-pen> ( -- pen )
 168     "checkbox" theme-image <image-pen>
 169     "checkbox" theme-image <image-pen>
 170     "checkbox-clicked" theme-image <image-pen>
 171     "checkbox-set" theme-image <image-pen>
 172     "checkbox-set-clicked" theme-image <image-pen>
 173     <button-pen> ;
 174
 175 : <checkmark> ( -- gadget )
 176     <gadget>
 177     <checkmark-pen> >>interior
 178     dup dup interior>> pen-pref-dim >>dim ;
 179
 180 : toggle-model ( model -- )
 181     [ not ] change-model ;
 182
 183 PRIVATE>
 184
 185 TUPLE: checkbox < button ;
 186
 187 : <checkbox> ( model label -- checkbox )
 188     <checkmark> label-on-right
 189     [ model>> toggle-model ]
 190     checkbox new-button
 191         swap >>model
 192         align-left ;
 193
 194 M: checkbox model-changed
 195     swap value>> >>selected? relayout-1 ;
 196
 197 <PRIVATE
 198
 199 : <radio-pen> ( -- pen )
 200     "radio" theme-image <image-pen>
 201     "radio" theme-image <image-pen>
 202     "radio-clicked" theme-image <image-pen>
 203     "radio-set" theme-image <image-pen>
 204     "radio-set-clicked" theme-image <image-pen>
 205     <button-pen> ;
 206
 207 : <radio-knob> ( -- gadget )
 208     <gadget>
 209     <radio-pen> >>interior
 210     dup dup interior>> pen-pref-dim >>dim ;
 211
 212 TUPLE: radio-control < button value ;
 213
 214 : <radio-control> ( value model label -- control )
 215     [ [ value>> ] keep set-control-value ]
 216     radio-control new-button
 217         swap >>model
 218         swap >>value
 219         align-left ; inline
 220
 221 M: radio-control model-changed
 222     2dup [ value>> ] same? >>selected? relayout-1 drop ;
 223
 224 :: <radio-controls> ( model assoc parent quot: ( value model label -- gadget ) -- parent )
 225     parent assoc [ model swap quot call add-gadget ] assoc-each ; inline
 226
 227 PRIVATE>
 228
 229 : <radio-button> ( value model label -- gadget )
 230     <radio-knob> label-on-right <radio-control> ;
 231
 232 : <radio-buttons> ( model assoc -- gadget )
 233     <filled-pile>
 234         [ <radio-button> ] <radio-controls>
 235         { 5 5 } >>gap ;
 236
 237 : command-button-quot ( target command -- quot )
 238     '[ _ _ invoke-command ] ;
 239
 240 : gesture>tooltip ( gesture -- str/f )
 241     gesture>string dup [ "Shortcut: " prepend ] when ;
 242
 243 :: <command-button> ( target gesture command -- button )
 244     command command-name
 245     target command command-button-quot
 246     '[ drop @ ] <border-button>
 247     gesture gesture>tooltip >>tooltip ; inline