basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2008 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays documents io kernel math models
   4 namespaces make opengl opengl.gl sequences strings io.styles
   5 math.vectors sorting colors combinators assocs math.order
   6 ui.clipboards ui.commands ui.gadgets ui.gadgets.borders
   7 ui.gadgets.buttons ui.gadgets.labels ui.gadgets.scrollers
   8 ui.gadgets.theme ui.gadgets.wrappers ui.render ui.gestures
   9 math.geometry.rect ;
  10 IN: ui.gadgets.editors
  11
  12 TUPLE: editor < gadget
  13 font color caret-color selection-color
  14 caret mark
  15 focused? ;
  16
  17 : <loc> ( -- loc ) { 0 0 } <model> ;
  18
  19 : init-editor-locs ( editor -- editor )
  20     <loc> >>caret
  21     <loc> >>mark ; inline
  22
  23 : editor-theme ( editor -- editor )
  24     black >>color
  25     red >>caret-color
  26     selection-color >>selection-color
  27     monospace-font >>font ; inline
  28
  29 : new-editor ( class -- editor )
  30     new-gadget
  31         <document> >>model
  32         init-editor-locs
  33         editor-theme ; inline
  34
  35 : <editor> ( -- editor )
  36     editor new-editor ;
  37
  38 : activate-editor-model ( editor model -- )
  39     2dup add-connection
  40     dup activate-model
  41     swap model>> add-loc ;
  42
  43 : deactivate-editor-model ( editor model -- )
  44     2dup remove-connection
  45     dup deactivate-model
  46     swap model>> remove-loc ;
  47
  48 M: editor graft*
  49     dup
  50     dup caret>> activate-editor-model
  51     dup mark>> activate-editor-model ;
  52
  53 M: editor ungraft*
  54     dup
  55     dup caret>> deactivate-editor-model
  56     dup mark>> deactivate-editor-model ;
  57
  58 : editor-caret* ( editor -- loc ) caret>> value>> ;
  59
  60 : editor-mark* ( editor -- loc ) mark>> value>> ;
  61
  62 : set-caret ( loc editor -- )
  63     [ model>> validate-loc ] keep
  64     caret>> set-model ;
  65
  66 : change-caret ( editor quot -- )
  67     over >r >r dup editor-caret* swap model>> r> call r>
  68     set-caret ; inline
  69
  70 : mark>caret ( editor -- )
  71     dup editor-caret* swap mark>> set-model ;
  72
  73 : change-caret&mark ( editor quot -- )
  74     over >r change-caret r> mark>caret ; inline
  75
  76 : editor-line ( n editor -- str ) control-value nth ;
  77
  78 : editor-font* ( editor -- font ) font>> open-font ;
  79
  80 : line-height ( editor -- n )
  81     editor-font* "" string-height ;
  82
  83 : y>line ( y editor -- line# )
  84     [ line-height / >fixnum ] keep model>> validate-line ;
  85
  86 : point>loc ( point editor -- loc )
  87     [
  88         >r first2 r> tuck y>line dup ,
  89         >r dup editor-font* r>
  90         rot editor-line x>offset ,
  91     ] { } make ;
  92
  93 : clicked-loc ( editor -- loc )
  94     [ hand-rel ] keep point>loc ;
  95
  96 : click-loc ( editor model -- )
  97     >r clicked-loc r> set-model ;
  98
  99 : focus-editor ( editor -- ) t >>focused? relayout-1 ;
 100
 101 : unfocus-editor ( editor -- ) f >>focused? relayout-1 ;
 102
 103 : (offset>x) ( font col# str -- x )
 104     swap head-slice string-width ;
 105
 106 : offset>x ( col# line# editor -- x )
 107     [ editor-line ] keep editor-font* -rot (offset>x) ;
 108
 109 : loc>x ( loc editor -- x ) >r first2 swap r> offset>x ;
 110
 111 : line>y ( lines# editor -- y )
 112     line-height * ;
 113
 114 : caret-loc ( editor -- loc )
 115     [ editor-caret* ] keep 2dup loc>x
 116     rot first rot line>y 2array ;
 117
 118 : caret-dim ( editor -- dim )
 119     line-height 0 swap 2array ;
 120
 121 : scroll>caret ( editor -- )
 122     dup graft-state>> second [
 123         dup caret-loc over caret-dim { 1 0 } v+ <rect>
 124         over scroll>rect
 125     ] when drop ;
 126
 127 : draw-caret ( -- )
 128     editor get focused?>> [
 129         editor get
 130         dup caret-color>> set-color
 131         dup caret-loc origin get v+
 132         swap caret-dim over v+
 133         [ { 0.5 -0.5 } v+ ] bi@ gl-line
 134     ] when ;
 135
 136 : line-translation ( n -- loc )
 137     editor get line-height * 0.0 swap 2array ;
 138
 139 : translate-lines ( n -- )
 140     line-translation gl-translate ;
 141
 142 : draw-line ( editor str -- )
 143     >r font>> r> { 0 0 } draw-string ;
 144
 145 : first-visible-line ( editor -- n )
 146     clip get rect-loc second origin get second -
 147     swap y>line ;
 148
 149 : last-visible-line ( editor -- n )
 150     clip get rect-extent nip second origin get second -
 151     swap y>line 1+ ;
 152
 153 : with-editor ( editor quot -- )
 154     [
 155         swap
 156         dup first-visible-line \ first-visible-line set
 157         dup last-visible-line \ last-visible-line set
 158         dup model>> document set
 159         editor set
 160         call
 161     ] with-scope ; inline
 162
 163 : visible-lines ( editor -- seq )
 164     \ first-visible-line get
 165     \ last-visible-line get
 166     rot control-value <slice> ;
 167
 168 : with-editor-translation ( n quot -- )
 169     >r line-translation origin get v+ r> with-translation ;
 170     inline
 171
 172 : draw-lines ( -- )
 173     \ first-visible-line get [
 174         editor get dup color>> set-color
 175         dup visible-lines
 176         [ draw-line 1 translate-lines ] with each
 177     ] with-editor-translation ;
 178
 179 : selection-start/end ( editor -- start end )
 180     dup editor-mark* swap editor-caret* sort-pair ;
 181
 182 : (draw-selection) ( x1 x2 -- )
 183     2dup = [ 2 + ] when
 184     0.0 swap editor get line-height glRectd ;
 185
 186 : draw-selected-line ( start end n -- )
 187     [ start/end-on-line ] keep tuck
 188     >r >r editor get offset>x r> r>
 189     editor get offset>x
 190     (draw-selection) ;
 191
 192 : draw-selection ( -- )
 193     editor get selection-color>> set-color
 194     editor get selection-start/end
 195     over first [
 196         2dup [
 197             >r 2dup r> draw-selected-line
 198             1 translate-lines
 199         ] each-line 2drop
 200     ] with-editor-translation ;
 201
 202 M: editor draw-gadget*
 203     [ draw-selection draw-lines draw-caret ] with-editor ;
 204
 205 M: editor pref-dim*
 206     dup editor-font* swap control-value text-dim ;
 207
 208 : contents-changed ( model editor -- )
 209     swap
 210     over caret>> [ over validate-loc ] (change-model)
 211     over mark>> [ over validate-loc ] (change-model)
 212     drop relayout ;
 213
 214 : caret/mark-changed ( model editor -- )
 215     nip [ relayout-1 ] [ scroll>caret ] bi ;
 216
 217 M: editor model-changed
 218     {
 219         { [ 2dup model>> eq? ] [ contents-changed ] }
 220         { [ 2dup caret>> eq? ] [ caret/mark-changed ] }
 221         { [ 2dup mark>> eq? ] [ caret/mark-changed ] }
 222     } cond ;
 223
 224 M: editor gadget-selection?
 225     selection-start/end = not ;
 226
 227 M: editor gadget-selection
 228     [ selection-start/end ] keep model>> doc-range ;
 229
 230 : remove-selection ( editor -- )
 231     [ selection-start/end ] keep model>> remove-doc-range ;
 232
 233 M: editor user-input*
 234     [ selection-start/end ] keep model>> set-doc-range t ;
 235
 236 : editor-string ( editor -- string )
 237     model>> doc-string ;
 238
 239 : set-editor-string ( string editor -- )
 240     model>> set-doc-string ;
 241
 242 M: editor gadget-text* editor-string % ;
 243
 244 : extend-selection ( editor -- )
 245     dup request-focus dup caret>> click-loc ;
 246
 247 : mouse-elt ( -- element )
 248     hand-click# get {
 249         { 1 T{ one-char-elt } }
 250         { 2 T{ one-word-elt } }
 251     } at T{ one-line-elt } or ;
 252
 253 : drag-direction? ( loc editor -- ? )
 254     editor-mark* before? ;
 255
 256 : drag-selection-caret ( loc editor element -- loc )
 257     >r [ drag-direction? ] 2keep
 258     model>>
 259     r> prev/next-elt ? ;
 260
 261 : drag-selection-mark ( loc editor element -- loc )
 262     >r [ drag-direction? not ] 2keep
 263     nip dup editor-mark* swap model>>
 264     r> prev/next-elt ? ;
 265
 266 : drag-caret&mark ( editor -- caret mark )
 267     dup clicked-loc swap mouse-elt
 268     [ drag-selection-caret ] 3keep
 269     drag-selection-mark ;
 270
 271 : drag-selection ( editor -- )
 272     dup drag-caret&mark
 273     pick mark>> set-model
 274     swap caret>> set-model ;
 275
 276 : editor-cut ( editor clipboard -- )
 277     dupd gadget-copy remove-selection ;
 278
 279 : delete/backspace ( elt editor quot -- )
 280     over gadget-selection? [
 281         drop nip remove-selection
 282     ] [
 283         over >r >r dup editor-caret* swap model>>
 284         r> call r> model>> remove-doc-range
 285     ] if ; inline
 286
 287 : editor-delete ( editor elt -- )
 288     swap [ over >r rot next-elt r> swap ] delete/backspace ;
 289
 290 : editor-backspace ( editor elt -- )
 291     swap [ over >r rot prev-elt r> ] delete/backspace ;
 292
 293 : editor-select-prev ( editor elt -- )
 294     swap [ rot prev-elt ] change-caret ;
 295
 296 : editor-prev ( editor elt -- )
 297     dupd editor-select-prev mark>caret ;
 298
 299 : editor-select-next ( editor elt -- )
 300     swap [ rot next-elt ] change-caret ;
 301
 302 : editor-next ( editor elt -- )
 303     dupd editor-select-next mark>caret ;
 304
 305 : editor-select ( from to editor -- )
 306     tuck caret>> set-model mark>> set-model ;
 307
 308 : select-elt ( editor elt -- )
 309     over >r
 310     >r dup editor-caret* swap model>> r> prev/next-elt
 311     r> editor-select ;
 312
 313 : start-of-document ( editor -- ) T{ doc-elt } editor-prev ;
 314
 315 : end-of-document ( editor -- ) T{ doc-elt } editor-next ;
 316
 317 : position-caret ( editor -- )
 318     mouse-elt dup T{ one-char-elt } =
 319     [ drop dup extend-selection dup mark>> click-loc ]
 320     [ select-elt ] if ;
 321
 322 : insert-newline ( editor -- ) "\n" swap user-input ;
 323
 324 : delete-next-character ( editor -- )
 325     T{ char-elt } editor-delete ;
 326
 327 : delete-previous-character ( editor -- )
 328     T{ char-elt } editor-backspace ;
 329
 330 : delete-previous-word ( editor -- )
 331     T{ word-elt } editor-delete ;
 332
 333 : delete-next-word ( editor -- )
 334     T{ word-elt } editor-backspace ;
 335
 336 : delete-to-start-of-line ( editor -- )
 337     T{ one-line-elt } editor-delete ;
 338
 339 : delete-to-end-of-line ( editor -- )
 340     T{ one-line-elt } editor-backspace ;
 341
 342 editor "general" f {
 343     { T{ key-down f f "DELETE" } delete-next-character }
 344     { T{ key-down f { S+ } "DELETE" } delete-next-character }
 345     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 346     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 347     { T{ key-down f { C+ } "DELETE" } delete-previous-word }
 348     { T{ key-down f { C+ } "BACKSPACE" } delete-next-word }
 349     { T{ key-down f { A+ } "DELETE" } delete-to-start-of-line }
 350     { T{ key-down f { A+ } "BACKSPACE" } delete-to-end-of-line }
 351 } define-command-map
 352
 353 : paste ( editor -- ) clipboard get paste-clipboard ;
 354
 355 : paste-selection ( editor -- ) selection get paste-clipboard ;
 356
 357 : cut ( editor -- ) clipboard get editor-cut ;
 358
 359 editor "clipboard" f {
 360     { T{ paste-action } paste }
 361     { T{ button-up f f 2 } paste-selection }
 362     { T{ copy-action } com-copy }
 363     { T{ button-up } com-copy-selection }
 364     { T{ cut-action } cut }
 365 } define-command-map
 366
 367 : previous-character ( editor -- )
 368     dup gadget-selection? [
 369         dup selection-start/end drop
 370         over set-caret mark>caret
 371     ] [
 372         T{ char-elt } editor-prev
 373     ] if ;
 374
 375 : next-character ( editor -- )
 376     dup gadget-selection? [
 377         dup selection-start/end nip
 378         over set-caret mark>caret
 379     ] [
 380         T{ char-elt } editor-next
 381     ] if ;
 382
 383 : previous-line ( editor -- ) T{ line-elt } editor-prev ;
 384
 385 : next-line ( editor -- ) T{ line-elt } editor-next ;
 386
 387 : previous-word ( editor -- ) T{ word-elt } editor-prev ;
 388
 389 : next-word ( editor -- ) T{ word-elt } editor-next ;
 390
 391 : start-of-line ( editor -- ) T{ one-line-elt } editor-prev ;
 392
 393 : end-of-line ( editor -- ) T{ one-line-elt } editor-next ;
 394
 395 editor "caret-motion" f {
 396     { T{ button-down } position-caret }
 397     { T{ key-down f f "LEFT" } previous-character }
 398     { T{ key-down f f "RIGHT" } next-character }
 399     { T{ key-down f f "UP" } previous-line }
 400     { T{ key-down f f "DOWN" } next-line }
 401     { T{ key-down f { C+ } "LEFT" } previous-word }
 402     { T{ key-down f { C+ } "RIGHT" } next-word }
 403     { T{ key-down f f "HOME" } start-of-line }
 404     { T{ key-down f f "END" } end-of-line }
 405     { T{ key-down f { C+ } "HOME" } start-of-document }
 406     { T{ key-down f { C+ } "END" } end-of-document }
 407 } define-command-map
 408
 409 : select-all ( editor -- ) T{ doc-elt } select-elt ;
 410
 411 : select-line ( editor -- ) T{ one-line-elt } select-elt ;
 412
 413 : select-word ( editor -- ) T{ one-word-elt } select-elt ;
 414
 415 : selected-word ( editor -- string )
 416     dup gadget-selection?
 417     [ dup select-word ] unless
 418     gadget-selection ;
 419
 420 : select-previous-character ( editor -- )
 421     T{ char-elt } editor-select-prev ;
 422
 423 : select-next-character ( editor -- )
 424     T{ char-elt } editor-select-next ;
 425
 426 : select-previous-line ( editor -- )
 427     T{ line-elt } editor-select-prev ;
 428
 429 : select-next-line ( editor -- )
 430     T{ line-elt } editor-select-next ;
 431
 432 : select-previous-word ( editor -- )
 433     T{ word-elt } editor-select-prev ;
 434
 435 : select-next-word ( editor -- )
 436     T{ word-elt } editor-select-next ;
 437
 438 : select-start-of-line ( editor -- )
 439     T{ one-line-elt } editor-select-prev ;
 440
 441 : select-end-of-line ( editor -- )
 442     T{ one-line-elt } editor-select-next ;
 443
 444 : select-start-of-document ( editor -- )
 445     T{ doc-elt } editor-select-prev ;
 446
 447 : select-end-of-document ( editor -- )
 448     T{ doc-elt } editor-select-next ;
 449
 450 editor "selection" f {
 451     { T{ button-down f { S+ } } extend-selection }
 452     { T{ drag } drag-selection }
 453     { T{ gain-focus } focus-editor }
 454     { T{ lose-focus } unfocus-editor }
 455     { T{ delete-action } remove-selection }
 456     { T{ select-all-action } select-all }
 457     { T{ key-down f { C+ } "l" } select-line }
 458     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 459     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 460     { T{ key-down f { S+ } "UP" } select-previous-line }
 461     { T{ key-down f { S+ } "DOWN" } select-next-line }
 462     { T{ key-down f { S+ C+ } "LEFT" } select-previous-word }
 463     { T{ key-down f { S+ C+ } "RIGHT" } select-next-word }
 464     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 465     { T{ key-down f { S+ } "END" } select-end-of-line }
 466     { T{ key-down f { S+ C+ } "HOME" } select-start-of-document }
 467     { T{ key-down f { S+ C+ } "END" } select-end-of-document }
 468 } define-command-map
 469
 470 ! Multi-line editors
 471 TUPLE: multiline-editor < editor ;
 472
 473 : <multiline-editor> ( -- editor )
 474     multiline-editor new-editor ;
 475
 476 multiline-editor "general" f {
 477     { T{ key-down f f "RET" } insert-newline }
 478     { T{ key-down f { S+ } "RET" } insert-newline }
 479     { T{ key-down f f "ENTER" } insert-newline }
 480 } define-command-map
 481
 482 TUPLE: source-editor < multiline-editor ;
 483
 484 : <source-editor> ( -- editor )
 485     source-editor new-editor ;
 486
 487 ! Fields wrap an editor and edit an external model
 488 TUPLE: field < wrapper field-model editor ;
 489
 490 : field-theme ( gadget -- gadget )
 491     gray <solid> >>boundary ; inline
 492
 493 : <field-border> ( gadget -- border )
 494     2 <border>
 495         { 1 0 } >>fill
 496         field-theme ;
 497
 498 : <field> ( model -- gadget )
 499     <editor> dup <field-border> field new-wrapper
 500         swap >>editor
 501         swap >>field-model ;
 502
 503 M: field graft*
 504     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 505     [ dup editor>> model>> add-connection ]
 506     bi ;
 507
 508 M: field ungraft*
 509     dup editor>> model>> remove-connection ;
 510
 511 M: field model-changed
 512     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;