basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays documents documents.elements kernel math
   4 math.ranges models models.filter namespaces locals fry make opengl
   5 opengl.gl sequences strings math.vectors math.functions sorting colors
   6 colors.constants combinators assocs math.order fry calendar alarms
   7 continuations ui.clipboards ui.commands ui.gadgets ui.gadgets.borders
   8 ui.gadgets.buttons ui.gadgets.labels ui.gadgets.scrollers
   9 ui.gadgets.menus ui.gadgets.wrappers ui.render
  10 ui.pens.solid ui.gadgets.line-support ui.text ui.gestures
  11 math.rectangles splitting unicode.categories fonts grouping ;
  12 IN: ui.gadgets.editors
  13
  14 TUPLE: editor < line-gadget
  15 caret-color
  16 caret mark
  17 focused? blink blink-alarm ;
  18
  19 : <loc> ( -- loc ) { 0 0 } <model> ;
  20
  21 : init-editor-locs ( editor -- editor )
  22     <loc> >>caret
  23     <loc> >>mark ; inline
  24
  25 : editor-theme ( editor -- editor )
  26     COLOR: red >>caret-color
  27     monospace-font >>font ; inline
  28
  29 : new-editor ( class -- editor )
  30     new-line-gadget
  31         <document> >>model
  32         init-editor-locs
  33         editor-theme ; inline
  34
  35 : <editor> ( -- editor )
  36     editor new-editor ;
  37
  38 : activate-editor-model ( editor model -- )
  39     2dup add-connection
  40     dup activate-model
  41     swap model>> add-loc ;
  42
  43 : deactivate-editor-model ( editor model -- )
  44     2dup remove-connection
  45     dup deactivate-model
  46     swap model>> remove-loc ;
  47
  48 : blink-caret ( editor -- )
  49     [ not ] change-blink relayout-1 ;
  50
  51 SYMBOL: blink-interval
  52
  53 750 milliseconds blink-interval set-global
  54
  55 : stop-blinking ( editor -- )
  56     [ [ cancel-alarm ] when* f ] change-blink-alarm drop ;
  57
  58 : start-blinking ( editor -- )
  59     [ stop-blinking ] [
  60         t >>blink
  61         dup '[ _ blink-caret ] blink-interval get every
  62         >>blink-alarm drop
  63     ] bi ;
  64
  65 : restart-blinking ( editor -- )
  66     dup focused?>> [
  67         [ start-blinking ]
  68         [ relayout-1 ]
  69         bi
  70     ] [ drop ] if ;
  71
  72 M: editor graft*
  73     dup
  74     dup caret>> activate-editor-model
  75     dup mark>> activate-editor-model ;
  76
  77 M: editor ungraft*
  78     dup
  79     dup stop-blinking
  80     dup caret>> deactivate-editor-model
  81     dup mark>> deactivate-editor-model ;
  82
  83 : editor-caret ( editor -- loc ) caret>> value>> ;
  84
  85 : editor-mark ( editor -- loc ) mark>> value>> ;
  86
  87 : set-caret ( loc editor -- )
  88     [ model>> validate-loc ] keep
  89     caret>> set-model ;
  90
  91 : change-caret ( editor quot -- )
  92     [ [ [ editor-caret ] [ model>> ] bi ] dip call ] [ drop ] 2bi
  93     set-caret ; inline
  94
  95 : mark>caret ( editor -- )
  96     [ editor-caret ] [ mark>> ] bi set-model ;
  97
  98 : change-caret&mark ( editor quot -- )
  99     [ change-caret ] [ drop mark>caret ] 2bi ; inline
 100
 101 : editor-line ( n editor -- str ) control-value nth ;
 102
 103 :: point>loc ( point editor -- loc )
 104     point second editor y>line {
 105         { [ dup 0 < ] [ drop { 0 0 } ] }
 106         { [ dup editor model>> last-line# > ] [ drop editor model>> doc-end ] }
 107         [| n |
 108             n
 109             point first
 110             editor font>>
 111             n editor editor-line
 112             x>offset 2array
 113         ]
 114     } cond ;
 115
 116 : clicked-loc ( editor -- loc )
 117     [ hand-rel ] keep point>loc ;
 118
 119 : click-loc ( editor model -- )
 120     [ clicked-loc ] dip set-model ;
 121
 122 : focus-editor ( editor -- )
 123     [ start-blinking ] [ t >>focused? relayout-1 ] bi ;
 124
 125 : unfocus-editor ( editor -- )
 126     [ stop-blinking ] [ f >>focused? relayout-1 ] bi ;
 127
 128 : loc>x ( loc editor -- x )
 129     [ first2 swap ] dip [ editor-line ] [ font>> ] bi swap offset>x round ;
 130
 131 : loc>point ( loc editor -- loc )
 132     [ loc>x ] [ [ first ] dip line>y ceiling ] 2bi 2array ;
 133
 134 : caret-loc ( editor -- loc )
 135     [ editor-caret ] keep loc>point ;
 136
 137 : caret-dim ( editor -- dim )
 138     line-height 0 swap 2array ;
 139
 140 : scroll>caret ( editor -- )
 141     dup graft-state>> second [
 142         [
 143             [ caret-loc ] [ caret-dim { 1 0 } v+ ] bi <rect>
 144         ] keep scroll>rect
 145     ] [ drop ] if ;
 146
 147 : draw-caret? ( editor -- ? )
 148     [ focused?>> ] [ blink>> ] bi and ;
 149
 150 : draw-caret ( editor -- )
 151     dup draw-caret? [
 152         [ caret-color>> gl-color ]
 153         [
 154             [ caret-loc ] [ caret-dim ] bi
 155             over v+ gl-line
 156         ] bi
 157     ] [ drop ] if ;
 158
 159 : selection-start/end ( editor -- start end )
 160     [ editor-mark ] [ editor-caret ] bi sort-pair ;
 161
 162 SYMBOL: selected-lines
 163
 164 TUPLE: selected-line start end first? last? ;
 165
 166 : compute-selection ( editor -- assoc )
 167     dup gadget-selection? [
 168         [ selection-start/end [ [ first ] bi@ [a,b] ] 2keep ] keep model>>
 169         '[ [ _ _ ] keep _ start/end-on-line 2array ] H{ } map>assoc
 170     ] [ drop f ] if ;
 171
 172 :: draw-empty-selection ( line pair editor -- )
 173     editor font>> :> font
 174     pair first font line offset>x 0 2array [
 175         editor selection-color>> gl-color
 176         1 font font-metrics height>> 2array gl-fill-rect
 177     ] with-translation ;
 178
 179 : draw-unselected-line ( line editor -- )
 180     font>> swap draw-text ;
 181
 182 : draw-selected-line ( line pair editor -- )
 183     over all-equal? [
 184         [ nip draw-unselected-line ] [ draw-empty-selection ] 3bi
 185     ] [
 186         [ [ first2 ] [ selection-color>> ] bi* <selection> ] keep
 187         draw-unselected-line
 188     ] if ;
 189
 190 M: editor draw-line ( line index editor -- )
 191     [ selected-lines get at ] dip over
 192     [ draw-selected-line ] [ nip draw-unselected-line ] if ;
 193
 194 M: editor draw-gadget*
 195     dup compute-selection selected-lines [
 196         [ draw-lines ] [ draw-caret ] bi
 197     ] with-variable ;
 198
 199 M: editor pref-dim*
 200     [ font>> ] [ control-value ] bi text-dim ;
 201
 202 M: editor baseline
 203     font>> font-metrics ascent>> ;
 204
 205 : contents-changed ( model editor -- )
 206     swap
 207     over caret>> [ over validate-loc ] (change-model)
 208     over mark>> [ over validate-loc ] (change-model)
 209     drop relayout ;
 210
 211 : caret/mark-changed ( model editor -- )
 212     nip [ restart-blinking ] [ scroll>caret ] bi ;
 213
 214 M: editor model-changed
 215     {
 216         { [ 2dup model>> eq? ] [ contents-changed ] }
 217         { [ 2dup caret>> eq? ] [ caret/mark-changed ] }
 218         { [ 2dup mark>> eq? ] [ caret/mark-changed ] }
 219     } cond ;
 220
 221 M: editor gadget-selection?
 222     selection-start/end = not ;
 223
 224 M: editor gadget-selection
 225     [ selection-start/end ] keep model>> doc-range ;
 226
 227 : remove-selection ( editor -- )
 228     [ selection-start/end ] keep model>> remove-doc-range ;
 229
 230 M: editor user-input*
 231     [ selection-start/end ] keep model>> set-doc-range t ;
 232
 233 : editor-string ( editor -- string )
 234     model>> doc-string ;
 235
 236 : set-editor-string ( string editor -- )
 237     model>> set-doc-string ;
 238
 239 M: editor gadget-text* editor-string % ;
 240
 241 : extend-selection ( editor -- )
 242     dup request-focus
 243     dup restart-blinking
 244     dup caret>> click-loc ;
 245
 246 : mouse-elt ( -- element )
 247     hand-click# get {
 248         { 1 one-char-elt }
 249         { 2 one-word-elt }
 250     } at one-line-elt or ;
 251
 252 : drag-direction? ( loc editor -- ? )
 253     editor-mark before? ;
 254
 255 : drag-selection-caret ( loc editor element -- loc )
 256     [
 257         [ drag-direction? ] 2keep model>>
 258     ] dip prev/next-elt ? ;
 259
 260 : drag-selection-mark ( loc editor element -- loc )
 261     [
 262         [ drag-direction? not ] keep
 263         [ editor-mark ] [ model>> ] bi
 264     ] dip prev/next-elt ? ;
 265
 266 : drag-caret&mark ( editor -- caret mark )
 267     dup clicked-loc swap mouse-elt
 268     [ drag-selection-caret ] 3keep
 269     drag-selection-mark ;
 270
 271 : drag-selection ( editor -- )
 272     dup drag-caret&mark
 273     pick mark>> set-model
 274     swap caret>> set-model ;
 275
 276 : editor-cut ( editor clipboard -- )
 277     [ gadget-copy ] [ drop remove-selection ] 2bi ;
 278
 279 : delete/backspace ( editor quot -- )
 280     over gadget-selection? [
 281         drop remove-selection
 282     ] [
 283         [ [ [ editor-caret ] [ model>> ] bi ] dip call ]
 284         [ drop model>> ]
 285         2bi remove-doc-range
 286     ] if ; inline
 287
 288 : editor-delete ( editor elt -- )
 289     '[ dupd _ next-elt ] delete/backspace ;
 290
 291 : editor-backspace ( editor elt -- )
 292     '[ over [ _ prev-elt ] dip ] delete/backspace ;
 293
 294 : editor-select-prev ( editor elt -- )
 295     '[ _ prev-elt ] change-caret ;
 296
 297 : editor-prev ( editor elt -- )
 298     [ editor-select-prev ] [ drop mark>caret ] 2bi ;
 299
 300 : editor-select-next ( editor elt -- )
 301     '[ _ next-elt ] change-caret ;
 302
 303 : editor-next ( editor elt -- )
 304     dupd editor-select-next mark>caret ;
 305
 306 : editor-select ( from to editor -- )
 307     [ mark>> set-model ] [ caret>> set-model ] bi-curry bi* ;
 308
 309 : select-elt ( editor elt -- )
 310     [ [ [ editor-caret ] [ model>> ] bi ] dip prev/next-elt ] [ drop ] 2bi
 311     editor-select ;
 312
 313 : start-of-document ( editor -- ) doc-elt editor-prev ;
 314
 315 : end-of-document ( editor -- ) doc-elt editor-next ;
 316
 317 : position-caret ( editor -- )
 318     mouse-elt dup one-char-elt =
 319     [ drop dup extend-selection dup mark>> click-loc ]
 320     [ select-elt ] if ;
 321
 322 : delete-next-character ( editor -- )
 323     char-elt editor-delete ;
 324
 325 : delete-previous-character ( editor -- )
 326     char-elt editor-backspace ;
 327
 328 : delete-previous-word ( editor -- )
 329     word-elt editor-delete ;
 330
 331 : delete-next-word ( editor -- )
 332     word-elt editor-backspace ;
 333
 334 : delete-to-start-of-line ( editor -- )
 335     one-line-elt editor-delete ;
 336
 337 : delete-to-end-of-line ( editor -- )
 338     one-line-elt editor-backspace ;
 339
 340 : com-undo ( editor -- )
 341     model>> undo ;
 342
 343 : com-redo ( editor -- )
 344     model>> redo ;
 345
 346 editor "editing" f {
 347     { undo-action com-undo }
 348     { redo-action com-redo }
 349     { T{ key-down f f "DELETE" } delete-next-character }
 350     { T{ key-down f { S+ } "DELETE" } delete-next-character }
 351     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 352     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 353     { T{ key-down f { C+ } "DELETE" } delete-previous-word }
 354     { T{ key-down f { C+ } "BACKSPACE" } delete-next-word }
 355     { T{ key-down f { A+ } "DELETE" } delete-to-start-of-line }
 356     { T{ key-down f { A+ } "BACKSPACE" } delete-to-end-of-line }
 357 } define-command-map
 358
 359 : paste ( editor -- ) clipboard get paste-clipboard ;
 360
 361 : paste-selection ( editor -- ) selection get paste-clipboard ;
 362
 363 : cut ( editor -- ) clipboard get editor-cut ;
 364
 365 editor "clipboard" f {
 366     { paste-action paste }
 367     { copy-action com-copy }
 368     { cut-action cut }
 369     { T{ button-up f f 2 } paste-selection }
 370     { T{ button-up } com-copy-selection }
 371 } define-command-map
 372
 373 : previous-character ( editor -- )
 374     dup gadget-selection? [
 375         dup selection-start/end drop
 376         over set-caret mark>caret
 377     ] [
 378         char-elt editor-prev
 379     ] if ;
 380
 381 : next-character ( editor -- )
 382     dup gadget-selection? [
 383         dup selection-start/end nip
 384         over set-caret mark>caret
 385     ] [
 386         char-elt editor-next
 387     ] if ;
 388
 389 : previous-word ( editor -- ) word-elt editor-prev ;
 390
 391 : next-word ( editor -- ) word-elt editor-next ;
 392
 393 : start-of-line ( editor -- ) one-line-elt editor-prev ;
 394
 395 : end-of-line ( editor -- ) one-line-elt editor-next ;
 396
 397 editor "caret-motion" f {
 398     { T{ button-down } position-caret }
 399     { T{ key-down f f "LEFT" } previous-character }
 400     { T{ key-down f f "RIGHT" } next-character }
 401     { T{ key-down f { C+ } "LEFT" } previous-word }
 402     { T{ key-down f { C+ } "RIGHT" } next-word }
 403     { T{ key-down f f "HOME" } start-of-line }
 404     { T{ key-down f f "END" } end-of-line }
 405     { T{ key-down f { C+ } "HOME" } start-of-document }
 406     { T{ key-down f { C+ } "END" } end-of-document }
 407 } define-command-map
 408
 409 : clear-editor ( editor -- )
 410     #! The with-datastack is a kludge to make it infer. Stupid.
 411     model>> 1array [ clear-doc ] with-datastack drop ;
 412
 413 : select-all ( editor -- ) doc-elt select-elt ;
 414
 415 : select-line ( editor -- ) one-line-elt select-elt ;
 416
 417 : select-word ( editor -- ) one-word-elt select-elt ;
 418
 419 : selected-token ( editor -- string )
 420     dup gadget-selection?
 421     [ dup select-word ] unless
 422     gadget-selection ;
 423
 424 : select-previous-character ( editor -- )
 425     char-elt editor-select-prev ;
 426
 427 : select-next-character ( editor -- )
 428     char-elt editor-select-next ;
 429
 430 : select-previous-word ( editor -- )
 431     word-elt editor-select-prev ;
 432
 433 : select-next-word ( editor -- )
 434     word-elt editor-select-next ;
 435
 436 : select-start-of-line ( editor -- )
 437     one-line-elt editor-select-prev ;
 438
 439 : select-end-of-line ( editor -- )
 440     one-line-elt editor-select-next ;
 441
 442 : select-start-of-document ( editor -- )
 443     doc-elt editor-select-prev ;
 444
 445 : select-end-of-document ( editor -- )
 446     doc-elt editor-select-next ;
 447
 448 editor "selection" f {
 449     { T{ button-down f { S+ } 1 } extend-selection }
 450     { T{ drag } drag-selection }
 451     { gain-focus focus-editor }
 452     { lose-focus unfocus-editor }
 453     { delete-action remove-selection }
 454     { select-all-action select-all }
 455     { T{ key-down f { C+ } "l" } select-line }
 456     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 457     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 458     { T{ key-down f { S+ C+ } "LEFT" } select-previous-word }
 459     { T{ key-down f { S+ C+ } "RIGHT" } select-next-word }
 460     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 461     { T{ key-down f { S+ } "END" } select-end-of-line }
 462     { T{ key-down f { S+ C+ } "HOME" } select-start-of-document }
 463     { T{ key-down f { S+ C+ } "END" } select-end-of-document }
 464 } define-command-map
 465
 466 : editor-menu ( editor -- )
 467     { com-undo com-redo cut com-copy paste } show-commands-menu ;
 468
 469 editor "misc" f {
 470     { T{ button-down f f 3 } editor-menu }
 471 } define-command-map
 472
 473 ! Multi-line editors
 474 TUPLE: multiline-editor < editor ;
 475
 476 : <multiline-editor> ( -- editor )
 477     multiline-editor new-editor ;
 478
 479 : previous-line ( editor -- ) line-elt editor-prev ;
 480
 481 : next-line ( editor -- ) line-elt editor-next ;
 482
 483 : select-previous-line ( editor -- )
 484     line-elt editor-select-prev ;
 485
 486 : select-next-line ( editor -- )
 487     line-elt editor-select-next ;
 488
 489 : insert-newline ( editor -- )
 490     "\n" swap user-input* drop ;
 491
 492 : change-selection ( editor quot -- )
 493     '[ gadget-selection @ ] keep user-input* drop ; inline
 494
 495 : join-lines ( string -- string' )
 496     "\n" split
 497     [ rest-slice [ [ blank? ] trim-head-slice ] change-each ]
 498     [ but-last-slice [ [ blank? ] trim-tail-slice ] change-each ]
 499     [ " " join ]
 500     tri ;
 501
 502 : this-line-and-next ( document line -- start end )
 503     [ nip 0 swap 2array ]
 504     [ [ nip 1+ ] [ 1+ swap doc-line length ] 2bi 2array ]
 505     2bi ;
 506
 507 : last-line? ( document line -- ? )
 508     [ last-line# ] dip = ;
 509
 510 : com-join-lines ( editor -- )
 511     dup gadget-selection?
 512     [ [ join-lines ] change-selection ] [
 513         [ model>> ] [ editor-caret first ] bi
 514         2dup last-line? [ 2drop ] [
 515             [ this-line-and-next ] [ drop ] 2bi
 516             [ join-lines ] change-doc-range
 517         ] if
 518     ] if ;
 519
 520 multiline-editor "multiline" f {
 521     { T{ key-down f f "UP" } previous-line }
 522     { T{ key-down f f "DOWN" } next-line }
 523     { T{ key-down f { S+ } "UP" } select-previous-line }
 524     { T{ key-down f { S+ } "DOWN" } select-next-line }
 525     { T{ key-down f f "RET" } insert-newline }
 526     { T{ key-down f { S+ } "RET" } insert-newline }
 527     { T{ key-down f f "ENTER" } insert-newline }
 528     { T{ key-down f { C+ } "j" } com-join-lines }
 529 } define-command-map
 530
 531 TUPLE: source-editor < multiline-editor ;
 532
 533 : <source-editor> ( -- editor )
 534     source-editor new-editor ;
 535
 536 ! A useful model
 537 : <element-model> ( editor element -- model )
 538     [ [ caret>> ] [ model>> ] bi ] dip
 539     '[ _ _ elt-string ] <filter> ;
 540
 541 ! Fields wrap an editor
 542 TUPLE: field < wrapper editor min-width max-width ;
 543
 544 : field-theme ( gadget -- gadget )
 545     COLOR: gray <solid> >>boundary ; inline
 546
 547 : <field-border> ( gadget -- border )
 548     { 2 2 } <border>
 549         { 1 0 } >>fill
 550         field-theme ;
 551
 552 : new-field ( class -- gadget )
 553     [ <editor> dup <field-border> ] dip new-wrapper swap >>editor ; inline
 554
 555 : column-width ( editor n -- width )
 556     [ editor>> font>> ] [ CHAR: \s <string> ] bi* text-width ;
 557
 558 M: field pref-dim*
 559     [ call-next-method ]
 560     [ dup min-width>> dup [ column-width 0 2array vmax ] [ 2drop ] if ]
 561     [ dup max-width>> dup [ column-width 1/0. 2array vmin ] [ 2drop ] if ]
 562     tri ;
 563
 564 TUPLE: model-field < field field-model ;
 565
 566 : <model-field> ( model -- gadget )
 567     model-field new-field swap >>field-model ;
 568
 569 M: model-field graft*
 570     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 571     [ dup editor>> model>> add-connection ]
 572     bi ;
 573
 574 M: model-field ungraft*
 575     dup editor>> model>> remove-connection ;
 576
 577 M: model-field model-changed
 578     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;
 579
 580 TUPLE: action-field < field quot ;
 581
 582 : <action-field> ( quot -- gadget )
 583     action-field new-field swap >>quot ;
 584
 585 : invoke-action-field ( field -- )
 586     [ editor>> editor-string ]
 587     [ editor>> clear-editor ]
 588     [ quot>> ]
 589     tri call ;
 590
 591 action-field H{
 592     { T{ key-down f f "RET" } [ invoke-action-field ] }
 593 } set-gestures