basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2011 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs calendar colors.constants
   4 combinators combinators.short-circuit documents
   5 documents.elements fonts fry grouping kernel locals make math
   6 math.functions math.order math.ranges math.rectangles
   7 math.vectors models models.arrow namespaces opengl sequences
   8 sorting splitting system timers ui.baseline-alignment
   9 ui.clipboards ui.commands ui.gadgets ui.gadgets.borders
  10 ui.gadgets.line-support ui.gadgets.menus ui.gadgets.scrollers
  11 ui.gestures ui.pens.solid ui.render ui.text ui.theme unicode
  12 opengl.gl ;
  13 IN: ui.gadgets.editors
  14
  15 TUPLE: editor < line-gadget
  16     caret mark
  17     focused? blink blink-timer
  18     default-text
  19     preedit-start
  20     preedit-end
  21     preedit-selected-start
  22     preedit-selected-end
  23     preedit-selection-mode?
  24     preedit-underlines ;
  25
  26 M: editor preedit? preedit-start>> ;
  27
  28 <PRIVATE
  29
  30 : <loc> ( -- loc ) { 0 0 } <model> ;
  31
  32 : init-editor-locs ( editor -- editor )
  33     <loc> >>caret
  34     <loc> >>mark ; inline
  35
  36 : editor-theme ( editor -- editor )
  37     monospace-font >>font ; inline
  38
  39 PRIVATE>
  40
  41 : new-editor ( class -- editor )
  42     new-line-gadget
  43         <document> >>model
  44         init-editor-locs
  45         editor-theme ; inline
  46
  47 : <editor> ( -- editor )
  48     editor new-editor ;
  49
  50 <PRIVATE
  51
  52 : activate-editor-model ( editor model -- )
  53     [ add-connection ]
  54     [ nip activate-model ]
  55     [ swap model>> add-loc ] 2tri ;
  56
  57 : deactivate-editor-model ( editor model -- )
  58     [ remove-connection ]
  59     [ nip deactivate-model ]
  60     [ swap model>> remove-loc ] 2tri ;
  61
  62 : blink-caret ( editor -- )
  63     [ not ] change-blink relayout-1 ;
  64
  65 SYMBOL: blink-interval
  66
  67 750 milliseconds blink-interval set-global
  68
  69 : stop-blinking ( editor -- )
  70     blink-timer>> [ stop-timer ] when* ;
  71
  72 : start-blinking ( editor -- )
  73     t >>blink
  74     blink-timer>> [ restart-timer ] when* ;
  75
  76 : restart-blinking ( editor -- )
  77     dup focused?>> [
  78         [ start-blinking ]
  79         [ relayout-1 ]
  80         bi
  81     ] [ drop ] if ;
  82
  83 PRIVATE>
  84
  85 M: editor graft*
  86     [ dup caret>> activate-editor-model ]
  87     [ dup mark>> activate-editor-model ]
  88     [
  89         [
  90             '[ _ blink-caret ] blink-interval get dup <timer>
  91         ] keep blink-timer<<
  92     ] tri ;
  93
  94 M: editor ungraft*
  95     [ [ stop-blinking ] [ f >>blink-timer drop ] bi ]
  96     [ dup caret>> deactivate-editor-model ]
  97     [ dup mark>> deactivate-editor-model ] tri ;
  98
  99 : editor-caret ( editor -- loc ) caret>> value>> ;
 100
 101 : editor-mark ( editor -- loc ) mark>> value>> ;
 102
 103 : set-caret ( loc editor -- )
 104     [ model>> validate-loc ] [ caret>> ] bi set-model ;
 105
 106 : set-mark ( loc editor -- )
 107     [ model>> validate-loc ] [ mark>> ] bi set-model ;
 108
 109 : change-caret ( editor quot: ( loc document -- newloc ) -- )
 110     [ [ [ editor-caret ] [ model>> ] bi ] dip call ] [ drop ] 2bi
 111     set-caret ; inline
 112
 113 : mark>caret ( editor -- )
 114     [ editor-caret ] [ mark>> ] bi set-model ;
 115
 116 : change-caret&mark ( editor quot: ( loc document -- newloc ) -- )
 117     [ change-caret ] [ drop mark>caret ] 2bi ; inline
 118
 119 : editor-line ( n editor -- str ) control-value nth ;
 120
 121 :: point>loc ( point editor -- loc )
 122     point second editor y>line {
 123         { [ dup 0 < ] [ drop { 0 0 } ] }
 124         { [ dup editor model>> last-line# > ] [ drop editor model>> doc-end ] }
 125         [| n |
 126             n
 127             point first
 128             editor font>>
 129             n editor editor-line
 130             x>offset 2array
 131         ]
 132     } cond ;
 133
 134 : clicked-loc ( editor -- loc )
 135     [ hand-rel ] keep point>loc ;
 136
 137 : click-loc ( editor model -- )
 138     [ clicked-loc ] dip set-model ;
 139
 140 : focus-editor ( editor -- )
 141     [ start-blinking ] [ t >>focused? relayout-1 ] bi ;
 142
 143 : unfocus-editor ( editor -- )
 144     [ stop-blinking ] [ f >>focused? relayout-1 ] bi ;
 145
 146 : loc>x ( loc editor -- x )
 147     [ first2 swap ] dip [ editor-line ] [ font>> ] bi swap offset>x round ;
 148
 149 : loc>point ( loc editor -- loc )
 150     [ loc>x ] [ [ first ] dip line>y ceiling ] 2bi 2array ;
 151
 152 : caret-loc ( editor -- loc )
 153     [ editor-caret ] keep loc>point ;
 154
 155 : caret-dim ( editor -- dim )
 156     [ 0 ] dip line-height 2array ;
 157
 158 : scroll>caret ( editor -- )
 159     dup graft-state>> second [
 160         [
 161             [ caret-loc ] [ caret-dim { 2 1 } v+ ] bi <rect>
 162         ] keep scroll>rect
 163     ] [ drop ] if ;
 164
 165 <PRIVATE
 166
 167 : draw-caret? ( editor -- ? )
 168     { [ focused?>> ] [ blink>> ]
 169       [ [ preedit? not ] [ preedit-selection-mode?>> not ] bi or ] } 1&& ;
 170
 171 : draw-caret ( editor -- )
 172     dup draw-caret? [
 173         [ editor-caret-color gl-color ] dip
 174         [ caret-loc ] [ caret-dim ] bi
 175         over v+ gl-line
 176     ] [ drop ] if ;
 177
 178 :: draw-preedit-underlines ( editor -- )
 179     editor [ preedit? ] [ preedit-underlines>> ] bi and [
 180         editor [ caret-loc second ] [ caret-dim second ] bi + 2.0 - :> y
 181         editor editor-caret first :> row
 182         editor font>> foreground>> gl-color
 183         editor preedit-underlines>> [
 184             GL_LINE_BIT [
 185                 dup second glLineWidth
 186                 first editor preedit-start>> second dup 2array v+ first2
 187                 [ row swap 2array editor loc>x 1.0 + y 2array ]
 188                 [ row swap 2array editor loc>x 1.0 - y 2array ]
 189                 bi*
 190                 gl-line
 191             ] do-attribs
 192         ] each
 193     ] when ;
 194
 195 : selection-start/end ( editor -- start end )
 196     [ editor-mark ] [ editor-caret ] bi sort-pair ;
 197
 198 SYMBOL: selected-lines
 199
 200 TUPLE: selected-line start end first? last? ;
 201
 202 : compute-selection ( editor -- assoc )
 203     dup gadget-selection? [
 204         [ selection-start/end [ [ first ] bi@ [a,b] ] [ ] 2bi ]
 205         [ model>> ] bi
 206         '[ [ _ _ ] [ _ start/end-on-line ] bi 2array ] H{ } map>assoc
 207     ] [ drop f ] if ;
 208
 209 :: draw-selection ( line pair editor -- )
 210     pair [ editor font>> line offset>x ] map :> pair
 211     editor selection-color>> gl-color
 212     pair first 0 2array
 213     pair second pair first - round 1 max editor line-height 2array
 214     gl-fill-rect ;
 215
 216 : draw-unselected-line ( line editor -- )
 217     font>> swap draw-text ;
 218
 219 : draw-selected-line ( line pair editor -- )
 220     over all-equal? [
 221         [ nip draw-unselected-line ] [ draw-selection ] 3bi
 222     ] [
 223         [ draw-selection ]
 224         [
 225             [ [ first2 ] [ selection-color>> ] bi* <selection> ]
 226             [ draw-unselected-line ] bi
 227         ] 3bi
 228     ] if ;
 229
 230 : draw-default-text? ( editor -- ? )
 231     { [ default-text>> ] [ model>> doc-string empty? ] } 1&& ;
 232
 233 : draw-default-text ( editor -- )
 234     [ font>> clone line-color >>foreground ]
 235     [ default-text>> ] bi draw-text ;
 236
 237 PRIVATE>
 238
 239 M: editor draw-line
 240     [ selected-lines get at ] dip over
 241     [ draw-selected-line ] [ nip draw-unselected-line ] if ;
 242
 243 M: editor draw-gadget*
 244     dup draw-default-text? [
 245         [ draw-default-text ] [ draw-caret ] [ draw-preedit-underlines ] tri
 246     ] [
 247         dup compute-selection selected-lines [
 248             [ draw-lines ] [ draw-caret ] [ draw-preedit-underlines ] tri
 249         ] with-variable
 250     ] if ;
 251
 252 M: editor pref-dim*
 253     [ call-next-method ] keep ! at least as big as our min-rows/min-cols
 254     ! Add some space for the caret.
 255     [ font>> ] keep dup draw-default-text?
 256     [ default-text>> ] [ control-value ] if
 257     text-dim { 1 0 } v+ vmax ;
 258
 259 M: editor baseline font>> font-metrics ascent>> ;
 260
 261 M: editor cap-height font>> font-metrics cap-height>> ;
 262
 263 <PRIVATE
 264
 265 : contents-changed ( model editor -- )
 266     [ [ nip caret>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 267     [ [ nip mark>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 268     [ nip relayout ] 2tri ;
 269
 270 : caret/mark-changed ( editor -- )
 271     [ restart-blinking ] keep scroll>caret ;
 272
 273 PRIVATE>
 274
 275 M: editor model-changed
 276     {
 277         { [ 2dup model>> eq? ] [ contents-changed ] }
 278         { [ 2dup caret>> eq? ] [ nip caret/mark-changed ] }
 279         { [ 2dup mark>> eq? ] [ nip caret/mark-changed ] }
 280     } cond ;
 281
 282 M: editor gadget-selection?
 283     selection-start/end = not ;
 284
 285 M: editor gadget-selection
 286     [ selection-start/end ] [ model>> ] bi doc-range ;
 287
 288 : remove-selection ( editor -- )
 289     [ selection-start/end ] [ model>> ] bi remove-doc-range ;
 290
 291 M: editor user-input*
 292     [ selection-start/end ] [ model>> ] bi set-doc-range t ;
 293
 294 M: editor temp-im-input
 295     [ selection-start/end ] [ model>> ] bi set-doc-range* t ;
 296
 297 : editor-string ( editor -- string )
 298     model>> doc-string ;
 299
 300 : set-editor-string ( string editor -- )
 301     model>> set-doc-string ;
 302
 303 M: editor gadget-text* editor-string % ;
 304
 305 : extend-selection ( editor -- )
 306     [ request-focus ]
 307     [ restart-blinking ]
 308     [ dup caret>> click-loc ] tri ;
 309
 310 : remove-preedit-text ( editor -- )
 311     { [ preedit-start>> ] [ set-caret ]
 312       [ preedit-end>> ] [ set-mark ]
 313       [ remove-selection ]
 314     } cleave ;
 315
 316 : remove-preedit-info ( editor -- )
 317     f >>preedit-start
 318     f >>preedit-end
 319     f >>preedit-selected-start
 320     f >>preedit-selected-end
 321     f >>preedit-selection-mode?
 322     f >>preedit-underlines
 323     drop ;
 324
 325 : mouse-elt ( -- element )
 326     hand-click# get {
 327         { 1 one-char-elt }
 328         { 2 one-word-elt }
 329     } at one-line-elt or ;
 330
 331 : drag-direction? ( loc editor -- ? )
 332     editor-mark before? ;
 333
 334 : drag-selection-caret ( loc editor element -- loc )
 335     [
 336         [ drag-direction? ] [ model>> ] 2bi
 337     ] dip prev/next-elt ? ;
 338
 339 : drag-selection-mark ( loc editor element -- loc )
 340     [
 341         [ drag-direction? not ]
 342         [ editor-mark ]
 343         [ model>> ] tri
 344     ] dip prev/next-elt ? ;
 345
 346 : drag-caret&mark ( editor -- caret mark )
 347     [ clicked-loc ] [ mouse-elt ] bi
 348     [ drag-selection-caret ]
 349     [ drag-selection-mark ] 3bi ;
 350
 351 : drag-selection ( editor -- )
 352     [ drag-caret&mark ]
 353     [ mark>> set-model ]
 354     [ caret>> set-model ] tri ;
 355
 356 : editor-cut ( editor clipboard -- )
 357     [ gadget-copy ] [ drop remove-selection ] 2bi ;
 358
 359 : delete/backspace ( editor quot -- )
 360     over gadget-selection? [
 361         drop remove-selection
 362     ] [
 363         [ [ [ editor-caret ] [ model>> ] bi ] dip call ]
 364         [ drop model>> ]
 365         2bi remove-doc-range
 366     ] if ; inline
 367
 368 : editor-delete ( editor elt -- )
 369     '[ dupd _ next-elt ] delete/backspace ;
 370
 371 : editor-backspace ( editor elt -- )
 372     '[ over [ _ prev-elt ] dip ] delete/backspace ;
 373
 374 : editor-select-prev ( editor elt -- )
 375     '[ _ prev-elt ] change-caret ;
 376
 377 : editor-prev ( editor elt -- )
 378     [ editor-select-prev ] [ drop mark>caret ] 2bi ;
 379
 380 : editor-select-next ( editor elt -- )
 381     '[ _ next-elt ] change-caret ;
 382
 383 : editor-next ( editor elt -- )
 384     dupd editor-select-next mark>caret ;
 385
 386 : editor-select ( from to editor -- )
 387     [ mark>> set-model ] [ caret>> set-model ] bi-curry bi* ;
 388
 389 : select-elt ( editor elt -- )
 390     [ [ [ editor-caret ] [ model>> ] bi ] dip prev/next-elt ] [ drop ] 2bi
 391     editor-select ;
 392
 393 : start-of-document ( editor -- ) doc-elt editor-prev ;
 394
 395 : end-of-document ( editor -- ) doc-elt editor-next ;
 396
 397 : position-caret ( editor -- )
 398     mouse-elt dup one-char-elt =
 399     [ drop dup extend-selection dup mark>> click-loc ]
 400     [ select-elt ] if ;
 401
 402 : delete-previous-character ( editor -- )
 403     char-elt editor-backspace ;
 404
 405 : delete-next-character ( editor -- )
 406     char-elt editor-delete ;
 407
 408 : delete-previous-word ( editor -- )
 409     word-elt editor-backspace ;
 410
 411 : delete-next-word ( editor -- )
 412     word-elt editor-delete ;
 413
 414 : delete-to-start-of-line ( editor -- )
 415     one-line-elt editor-backspace ;
 416
 417 : delete-to-end-of-line ( editor -- )
 418     one-line-elt editor-delete ;
 419
 420 : delete-to-start-of-document ( editor -- )
 421     doc-elt editor-delete ;
 422
 423 : delete-to-end-of-document ( editor -- )
 424     doc-elt editor-delete ;
 425
 426 : com-undo ( editor -- ) model>> undo ;
 427
 428 : com-redo ( editor -- ) model>> redo ;
 429
 430 editor "editing" f {
 431     { undo-action com-undo }
 432     { redo-action com-redo }
 433     { T{ key-down f f "DELETE" } delete-next-character }
 434     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 435     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 436     { T{ key-down f { C+ } "DELETE" } delete-next-word }
 437     { T{ key-down f { C+ } "BACKSPACE" } delete-previous-word }
 438     { T{ key-down f { A+ } "DELETE" } delete-to-end-of-line }
 439     { T{ key-down f { A+ } "BACKSPACE" } delete-to-start-of-line }
 440 } os unix? [ {
 441     { T{ key-down f { C+ } "d" } delete-next-character }
 442     { T{ key-down f { C+ } "h" } delete-previous-character }
 443     { T{ key-down f { C+ } "u" } delete-to-start-of-line }
 444     { T{ key-down f { C+ } "k" } delete-to-end-of-line }
 445     { T{ key-down f { C+ } "w" } delete-previous-word }
 446 } append ] when define-command-map
 447
 448 : com-paste ( editor -- ) clipboard get paste-clipboard ;
 449
 450 : paste-selection ( editor -- ) ui.clipboards:selection get paste-clipboard ;
 451
 452 : com-cut ( editor -- ) clipboard get editor-cut ;
 453
 454 editor "clipboard" f {
 455     { cut-action com-cut }
 456     { copy-action com-copy }
 457     { paste-action com-paste }
 458     { T{ button-up } com-copy-selection }
 459     { T{ button-up f f 2 } paste-selection }
 460 } define-command-map
 461
 462 : previous-character ( editor -- )
 463     dup gadget-selection? [
 464         dup selection-start/end drop
 465         over set-caret mark>caret
 466     ] [
 467         char-elt editor-prev
 468     ] if ;
 469
 470 : next-character ( editor -- )
 471     dup gadget-selection? [
 472         dup selection-start/end nip
 473         over set-caret mark>caret
 474     ] [
 475         char-elt editor-next
 476     ] if ;
 477
 478 : previous-word ( editor -- ) word-elt editor-prev ;
 479
 480 : next-word ( editor -- ) word-elt editor-next ;
 481
 482 : start-of-line ( editor -- ) one-line-elt editor-prev ;
 483
 484 : end-of-line ( editor -- ) one-line-elt editor-next ;
 485
 486 editor "caret-motion" f {
 487     { T{ button-down } position-caret }
 488     { T{ key-down f f "LEFT" } previous-character }
 489     { T{ key-down f f "RIGHT" } next-character }
 490     { T{ key-down f { C+ } "LEFT" } previous-word }
 491     { T{ key-down f { C+ } "RIGHT" } next-word }
 492     { T{ key-down f f "HOME" } start-of-line }
 493     { T{ key-down f f "END" } end-of-line }
 494     { T{ key-down f { C+ } "HOME" } start-of-document }
 495     { T{ key-down f { C+ } "END" } end-of-document }
 496 } os unix? [ {
 497     { T{ key-down f { C+ } "b" } previous-character }
 498     { T{ key-down f { C+ } "f" } next-character }
 499     { T{ key-down f { C+ } "a" } start-of-line }
 500     { T{ key-down f { C+ } "e" } end-of-line }
 501 } append ] when define-command-map
 502
 503 : clear-editor ( editor -- )
 504     model>> clear-doc ;
 505
 506 : select-all ( editor -- ) doc-elt select-elt ;
 507
 508 : select-line ( editor -- ) one-line-elt select-elt ;
 509
 510 : select-word ( editor -- ) one-word-elt select-elt ;
 511
 512 : selected-token ( editor -- string )
 513     dup gadget-selection?
 514     [ dup select-word ] unless
 515     gadget-selection ;
 516
 517 : select-previous-character ( editor -- )
 518     char-elt editor-select-prev ;
 519
 520 : select-next-character ( editor -- )
 521     char-elt editor-select-next ;
 522
 523 : select-previous-word ( editor -- )
 524     word-elt editor-select-prev ;
 525
 526 : select-next-word ( editor -- )
 527     word-elt editor-select-next ;
 528
 529 : select-start-of-line ( editor -- )
 530     one-line-elt editor-select-prev ;
 531
 532 : select-end-of-line ( editor -- )
 533     one-line-elt editor-select-next ;
 534
 535 : select-start-of-document ( editor -- )
 536     doc-elt editor-select-prev ;
 537
 538 : select-end-of-document ( editor -- )
 539     doc-elt editor-select-next ;
 540
 541 editor "selection" f {
 542     { T{ button-down f { S+ } 1 } extend-selection }
 543     { T{ button-up f { S+ } 1 } com-copy-selection }
 544     { T{ drag { # 1 } } drag-selection }
 545     { gain-focus focus-editor }
 546     { lose-focus unfocus-editor }
 547     { delete-action remove-selection }
 548     { select-all-action select-all }
 549     { T{ key-down f { C+ } "l" } select-line }
 550     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 551     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 552     { T{ key-down f { S+ C+ } "LEFT" } select-previous-word }
 553     { T{ key-down f { S+ C+ } "RIGHT" } select-next-word }
 554     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 555     { T{ key-down f { S+ } "END" } select-end-of-line }
 556     { T{ key-down f { S+ C+ } "HOME" } select-start-of-document }
 557     { T{ key-down f { S+ C+ } "END" } select-end-of-document }
 558 } define-command-map
 559
 560 : editor-menu ( editor -- )
 561     {
 562         com-undo
 563         com-redo
 564         ----
 565         com-cut
 566         com-copy
 567         com-paste
 568     } show-commands-menu ;
 569
 570 editor "misc" f {
 571     ! { T{ button-down f f 2 } paste-selection }
 572     { T{ button-down f f 3 } editor-menu }
 573 } define-command-map
 574
 575 ! Multi-line editors
 576 TUPLE: multiline-editor < editor ;
 577
 578 : <multiline-editor> ( -- editor )
 579     multiline-editor new-editor ;
 580
 581 : previous-line ( editor -- ) line-elt editor-prev ;
 582
 583 : next-line ( editor -- ) line-elt editor-next ;
 584
 585 <PRIVATE
 586
 587 : page-elt ( editor n -- editor element )
 588     over visible-lines 1 - min 1 max <page-elt> ;
 589
 590 : prev-page-elt ( editor -- editor element )
 591     dup editor-caret first page-elt ;
 592
 593 : next-page-elt ( editor -- editor element )
 594     dup [ control-value length 1 - ] [ editor-caret first ] bi - page-elt ;
 595
 596 PRIVATE>
 597
 598 : previous-page ( editor -- ) prev-page-elt editor-prev ;
 599
 600 : next-page ( editor -- ) next-page-elt editor-next ;
 601
 602 : select-previous-line ( editor -- ) line-elt editor-select-prev ;
 603
 604 : select-next-line ( editor -- ) line-elt editor-select-next ;
 605
 606 : select-previous-page ( editor -- ) prev-page-elt editor-select-prev ;
 607
 608 : select-next-page ( editor -- ) next-page-elt editor-select-next ;
 609
 610 : insert-newline ( editor -- )
 611     "\n" swap user-input* drop ;
 612
 613 : change-selection ( editor quot -- )
 614     '[ gadget-selection @ ] [ user-input* drop ] bi ; inline
 615
 616 <PRIVATE
 617
 618 : join-lines ( string -- string' )
 619     "\n" split
 620     [ rest-slice [ [ blank? ] trim-head-slice ] map! drop ]
 621     [ but-last-slice [ [ blank? ] trim-tail-slice ] map! drop ]
 622     [ " " join ]
 623     tri ;
 624
 625 : last-line? ( document line -- ? )
 626     [ last-line# ] dip = ;
 627
 628 : prev-line-and-this ( document line -- start end )
 629     swap [ drop 1 - 0 2array ] [ line-end ] 2bi ;
 630
 631 : join-with-prev ( document line -- )
 632     [ prev-line-and-this ] [ drop ] 2bi
 633     [ join-lines ] change-doc-range ;
 634
 635 : this-line-and-next ( document line -- start end )
 636     swap [ drop 0 2array ] [ [ 1 + ] dip line-end ] 2bi ;
 637
 638 : join-with-next ( document line -- )
 639     [ this-line-and-next ] [ drop ] 2bi
 640     [ join-lines ] change-doc-range ;
 641
 642 PRIVATE>
 643
 644 : com-join-lines ( editor -- )
 645     dup gadget-selection?
 646     [ [ join-lines ] change-selection ] [
 647         [ model>> ] [ editor-caret first ] bi {
 648             { [ over last-line# 0 = ] [ 2drop ] }
 649             { [ 2dup last-line? ] [ join-with-prev ] }
 650             [ join-with-next ]
 651         } cond
 652     ] if ;
 653
 654 multiline-editor "multiline" f {
 655     { T{ key-down f f "UP" } previous-line }
 656     { T{ key-down f f "DOWN" } next-line }
 657     { T{ key-down f { S+ } "UP" } select-previous-line }
 658     { T{ key-down f { S+ } "DOWN" } select-next-line }
 659     { T{ key-down f f "PAGE_UP" } previous-page }
 660     { T{ key-down f f "PAGE_DOWN" } next-page }
 661     { T{ key-down f { S+ } "PAGE_UP" } select-previous-page }
 662     { T{ key-down f { S+ } "PAGE_DOWN" } select-next-page }
 663     { T{ key-down f f "RET" } insert-newline }
 664     { T{ key-down f { S+ } "RET" } insert-newline }
 665     { T{ key-down f f "ENTER" } insert-newline }
 666     { T{ key-down f { C+ } "j" } com-join-lines }
 667 } os unix? [ {
 668     { T{ key-down f { C+ } "p" } previous-line }
 669     { T{ key-down f { C+ } "n" } next-line }
 670 } append ] when define-command-map
 671
 672 TUPLE: source-editor < multiline-editor ;
 673
 674 : <source-editor> ( -- editor )
 675     source-editor new-editor ;
 676
 677 ! A useful model
 678 : <element-model> ( editor element -- model )
 679     [ [ caret>> ] [ model>> ] bi ] dip
 680     '[ _ _ elt-string ] <arrow> ;
 681
 682 ! Fields wrap an editor
 683 TUPLE: field < border editor min-cols max-cols ;
 684
 685 <PRIVATE
 686
 687 : field-theme ( gadget -- gadget )
 688     { 2 2 } >>size
 689     { 1 0 } >>fill
 690     field-border-color <solid> >>boundary ; inline
 691
 692 : <field-border> ( gadget -- border )
 693     border new-border field-theme ;
 694
 695 PRIVATE>
 696
 697 : new-field ( class -- gadget )
 698     [ <editor> ] dip new-border
 699         dup gadget-child >>editor
 700         field-theme ; inline
 701
 702 ! For line-gadget-width
 703 M: field font>> editor>> font>> ;
 704
 705 M: field pref-dim*
 706     [ ]
 707     [ editor>> pref-dim ]
 708     [ [ line-gadget-width ] [ drop second ] 2bi 2array ]
 709     tri border-pref-dim ;
 710
 711 M: field default-text>> editor>> default-text>> ;
 712
 713 M: field default-text<< editor>> default-text<< ;
 714
 715 TUPLE: model-field < field field-model ;
 716
 717 : <model-field> ( model -- gadget )
 718     model-field new-field
 719         swap >>field-model ;
 720
 721 M: model-field graft*
 722     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 723     [ dup editor>> model>> add-connection ]
 724     bi ;
 725
 726 M: model-field ungraft*
 727     dup editor>> model>> remove-connection ;
 728
 729 M: model-field model-changed
 730     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;
 731
 732 TUPLE: action-field < field quot ;
 733
 734 : <action-field> ( quot: ( string -- ) -- gadget )
 735     action-field [ <editor> ] dip new-border
 736         dup gadget-child >>editor
 737         field-theme
 738         swap >>quot ;
 739
 740 : invoke-action-field ( field -- )
 741     [ editor>> editor-string ]
 742     [ editor>> clear-editor ]
 743     [ quot>> ]
 744     tri call( string -- ) ;
 745
 746 action-field H{
 747     { T{ key-down f f "RET" } [ invoke-action-field ] }
 748 } set-gestures