basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2011 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs calendar colors.constants combinators
   4 combinators.short-circuit documents documents.elements fonts fry
   5 grouping kernel locals make math math.functions math.order math.ranges
   6 math.rectangles math.vectors models models.arrow namespaces opengl
   7 sequences sorting splitting timers ui.baseline-alignment ui.clipboards
   8 ui.commands ui.gadgets ui.gadgets.borders ui.gadgets.line-support
   9 ui.gadgets.menus ui.gadgets.scrollers ui.gestures ui.pens.solid
  10 ui.render ui.text ui.theme unicode opengl.gl ;
  11 IN: ui.gadgets.editors
  12
  13 TUPLE: editor < line-gadget
  14     caret mark
  15     focused? blink blink-timer
  16     default-text
  17     preedit-start
  18     preedit-end
  19     preedit-selected-start
  20     preedit-selected-end
  21     preedit-selection-mode?
  22     preedit-underlines ;
  23
  24 M: editor preedit? preedit-start>> ;
  25
  26 <PRIVATE
  27
  28 : <loc> ( -- loc ) { 0 0 } <model> ;
  29
  30 : init-editor-locs ( editor -- editor )
  31     <loc> >>caret
  32     <loc> >>mark ; inline
  33
  34 : editor-theme ( editor -- editor )
  35     monospace-font >>font ; inline
  36
  37 PRIVATE>
  38
  39 : new-editor ( class -- editor )
  40     new-line-gadget
  41         <document> >>model
  42         init-editor-locs
  43         editor-theme ; inline
  44
  45 : <editor> ( -- editor )
  46     editor new-editor ;
  47
  48 <PRIVATE
  49
  50 : activate-editor-model ( editor model -- )
  51     [ add-connection ]
  52     [ nip activate-model ]
  53     [ swap model>> add-loc ] 2tri ;
  54
  55 : deactivate-editor-model ( editor model -- )
  56     [ remove-connection ]
  57     [ nip deactivate-model ]
  58     [ swap model>> remove-loc ] 2tri ;
  59
  60 : blink-caret ( editor -- )
  61     [ not ] change-blink relayout-1 ;
  62
  63 SYMBOL: blink-interval
  64
  65 750 milliseconds blink-interval set-global
  66
  67 : stop-blinking ( editor -- )
  68     blink-timer>> [ stop-timer ] when* ;
  69
  70 : start-blinking ( editor -- )
  71     t >>blink
  72     blink-timer>> [ restart-timer ] when* ;
  73
  74 : restart-blinking ( editor -- )
  75     dup focused?>> [
  76         [ start-blinking ]
  77         [ relayout-1 ]
  78         bi
  79     ] [ drop ] if ;
  80
  81 PRIVATE>
  82
  83 M: editor graft*
  84     [ dup caret>> activate-editor-model ]
  85     [ dup mark>> activate-editor-model ]
  86     [
  87         [
  88             '[ _ blink-caret ] blink-interval get dup <timer>
  89         ] keep blink-timer<<
  90     ] tri ;
  91
  92 M: editor ungraft*
  93     [ [ stop-blinking ] [ f >>blink-timer drop ] bi ]
  94     [ dup caret>> deactivate-editor-model ]
  95     [ dup mark>> deactivate-editor-model ] tri ;
  96
  97 : editor-caret ( editor -- loc ) caret>> value>> ;
  98
  99 : editor-mark ( editor -- loc ) mark>> value>> ;
 100
 101 : set-caret ( loc editor -- )
 102     [ model>> validate-loc ] [ caret>> ] bi set-model ;
 103
 104 : set-mark ( loc editor -- )
 105     [ model>> validate-loc ] [ mark>> ] bi set-model ;
 106
 107 : change-caret ( editor quot: ( loc document -- newloc ) -- )
 108     [ [ [ editor-caret ] [ model>> ] bi ] dip call ] [ drop ] 2bi
 109     set-caret ; inline
 110
 111 : mark>caret ( editor -- )
 112     [ editor-caret ] [ mark>> ] bi set-model ;
 113
 114 : change-caret&mark ( editor quot: ( loc document -- newloc ) -- )
 115     [ change-caret ] [ drop mark>caret ] 2bi ; inline
 116
 117 : editor-line ( n editor -- str ) control-value nth ;
 118
 119 :: point>loc ( point editor -- loc )
 120     point second editor y>line {
 121         { [ dup 0 < ] [ drop { 0 0 } ] }
 122         { [ dup editor model>> last-line# > ] [ drop editor model>> doc-end ] }
 123         [| n |
 124             n
 125             point first
 126             editor font>>
 127             n editor editor-line
 128             x>offset 2array
 129         ]
 130     } cond ;
 131
 132 : clicked-loc ( editor -- loc )
 133     [ hand-rel ] keep point>loc ;
 134
 135 : click-loc ( editor model -- )
 136     [ clicked-loc ] dip set-model ;
 137
 138 : focus-editor ( editor -- )
 139     [ start-blinking ] [ t >>focused? relayout-1 ] bi ;
 140
 141 : unfocus-editor ( editor -- )
 142     [ stop-blinking ] [ f >>focused? relayout-1 ] bi ;
 143
 144 : loc>x ( loc editor -- x )
 145     [ first2 swap ] dip [ editor-line ] [ font>> ] bi swap offset>x round ;
 146
 147 : loc>point ( loc editor -- loc )
 148     [ loc>x ] [ [ first ] dip line>y ceiling ] 2bi 2array ;
 149
 150 : caret-loc ( editor -- loc )
 151     [ editor-caret ] keep loc>point ;
 152
 153 : caret-dim ( editor -- dim )
 154     [ 0 ] dip line-height 2array ;
 155
 156 : scroll>caret ( editor -- )
 157     dup graft-state>> second [
 158         [
 159             [ caret-loc ] [ caret-dim { 2 1 } v+ ] bi <rect>
 160         ] keep scroll>rect
 161     ] [ drop ] if ;
 162
 163 <PRIVATE
 164
 165 : draw-caret? ( editor -- ? )
 166     { [ focused?>> ] [ blink>> ]
 167       [ [ preedit? not ] [ preedit-selection-mode?>> not ] bi or ] } 1&& ;
 168
 169 : draw-caret ( editor -- )
 170     dup draw-caret? [
 171         [ editor-caret-color gl-color ] dip
 172         [ caret-loc ] [ caret-dim ] bi
 173         over v+ gl-line
 174     ] [ drop ] if ;
 175
 176 :: draw-preedit-underlines ( editor -- )
 177     editor [ preedit? ] [ preedit-underlines>> ] bi and [
 178         editor [ caret-loc second ] [ caret-dim second ] bi + 2.0 - :> y
 179         editor editor-caret first :> row
 180         editor font>> foreground>> gl-color
 181         editor preedit-underlines>> [
 182             GL_LINE_BIT [
 183                 dup second glLineWidth
 184                 first editor preedit-start>> second dup 2array v+ first2
 185                 [ row swap 2array editor loc>x 1.0 + y 2array ]
 186                 [ row swap 2array editor loc>x 1.0 - y 2array ]
 187                 bi*
 188                 gl-line
 189             ] do-attribs
 190         ] each
 191     ] when ;
 192
 193 : selection-start/end ( editor -- start end )
 194     [ editor-mark ] [ editor-caret ] bi sort-pair ;
 195
 196 SYMBOL: selected-lines
 197
 198 TUPLE: selected-line start end first? last? ;
 199
 200 : compute-selection ( editor -- assoc )
 201     dup gadget-selection? [
 202         [ selection-start/end [ [ first ] bi@ [a,b] ] [ ] 2bi ]
 203         [ model>> ] bi
 204         '[ [ _ _ ] [ _ start/end-on-line ] bi 2array ] H{ } map>assoc
 205     ] [ drop f ] if ;
 206
 207 :: draw-selection ( line pair editor -- )
 208     pair [ editor font>> line offset>x ] map :> pair
 209     editor selection-color>> gl-color
 210     pair first 0 2array
 211     pair second pair first - round 1 max editor line-height 2array
 212     gl-fill-rect ;
 213
 214 : draw-unselected-line ( line editor -- )
 215     font>> swap draw-text ;
 216
 217 : draw-selected-line ( line pair editor -- )
 218     over all-equal? [
 219         [ nip draw-unselected-line ] [ draw-selection ] 3bi
 220     ] [
 221         [ draw-selection ]
 222         [
 223             [ [ first2 ] [ selection-color>> ] bi* <selection> ]
 224             [ draw-unselected-line ] bi
 225         ] 3bi
 226     ] if ;
 227
 228 : draw-default-text? ( editor -- ? )
 229     { [ default-text>> ] [ model>> doc-string empty? ] } 1&& ;
 230
 231 : draw-default-text ( editor -- )
 232     [ font>> clone line-color >>foreground ]
 233     [ default-text>> ] bi draw-text ;
 234
 235 PRIVATE>
 236
 237 M: editor draw-line
 238     [ selected-lines get at ] dip over
 239     [ draw-selected-line ] [ nip draw-unselected-line ] if ;
 240
 241 M: editor draw-gadget*
 242     dup draw-default-text? [
 243         [ draw-default-text ] [ draw-caret ] [ draw-preedit-underlines ] tri
 244     ] [
 245         dup compute-selection selected-lines [
 246             [ draw-lines ] [ draw-caret ] [ draw-preedit-underlines ] tri
 247         ] with-variable
 248     ] if ;
 249
 250 M: editor pref-dim*
 251     [ call-next-method ] keep ! at least as big as our min-rows/min-cols
 252     ! Add some space for the caret.
 253     [ font>> ] keep dup draw-default-text?
 254     [ default-text>> ] [ control-value ] if
 255     text-dim { 1 0 } v+ vmax ;
 256
 257 M: editor baseline font>> font-metrics ascent>> ;
 258
 259 M: editor cap-height font>> font-metrics cap-height>> ;
 260
 261 <PRIVATE
 262
 263 : contents-changed ( model editor -- )
 264     [ [ nip caret>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 265     [ [ nip mark>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 266     [ nip relayout ] 2tri ;
 267
 268 : caret/mark-changed ( editor -- )
 269     [ restart-blinking ] keep scroll>caret ;
 270
 271 PRIVATE>
 272
 273 M: editor model-changed
 274     {
 275         { [ 2dup model>> eq? ] [ contents-changed ] }
 276         { [ 2dup caret>> eq? ] [ nip caret/mark-changed ] }
 277         { [ 2dup mark>> eq? ] [ nip caret/mark-changed ] }
 278     } cond ;
 279
 280 M: editor gadget-selection?
 281     selection-start/end = not ;
 282
 283 M: editor gadget-selection
 284     [ selection-start/end ] [ model>> ] bi doc-range ;
 285
 286 : remove-selection ( editor -- )
 287     [ selection-start/end ] [ model>> ] bi remove-doc-range ;
 288
 289 M: editor user-input*
 290     [ selection-start/end ] [ model>> ] bi set-doc-range t ;
 291
 292 M: editor temp-im-input
 293     [ selection-start/end ] [ model>> ] bi set-doc-range* t ;
 294
 295 : editor-string ( editor -- string )
 296     model>> doc-string ;
 297
 298 : set-editor-string ( string editor -- )
 299     model>> set-doc-string ;
 300
 301 M: editor gadget-text* editor-string % ;
 302
 303 : extend-selection ( editor -- )
 304     [ request-focus ]
 305     [ restart-blinking ]
 306     [ dup caret>> click-loc ] tri ;
 307
 308 : remove-preedit-text ( editor -- )
 309     { [ preedit-start>> ] [ set-caret ]
 310       [ preedit-end>> ] [ set-mark ]
 311       [ remove-selection ]
 312     } cleave ;
 313
 314 : remove-preedit-info ( editor -- )
 315     f >>preedit-start
 316     f >>preedit-end
 317     f >>preedit-selected-start
 318     f >>preedit-selected-end
 319     f >>preedit-selection-mode?
 320     f >>preedit-underlines
 321     drop ;
 322
 323 : mouse-elt ( -- element )
 324     hand-click# get {
 325         { 1 one-char-elt }
 326         { 2 one-word-elt }
 327     } at one-line-elt or ;
 328
 329 : drag-direction? ( loc editor -- ? )
 330     editor-mark before? ;
 331
 332 : drag-selection-caret ( loc editor element -- loc )
 333     [
 334         [ drag-direction? ] [ model>> ] 2bi
 335     ] dip prev/next-elt ? ;
 336
 337 : drag-selection-mark ( loc editor element -- loc )
 338     [
 339         [ drag-direction? not ]
 340         [ editor-mark ]
 341         [ model>> ] tri
 342     ] dip prev/next-elt ? ;
 343
 344 : drag-caret&mark ( editor -- caret mark )
 345     [ clicked-loc ] [ mouse-elt ] bi
 346     [ drag-selection-caret ]
 347     [ drag-selection-mark ] 3bi ;
 348
 349 : drag-selection ( editor -- )
 350     [ drag-caret&mark ]
 351     [ mark>> set-model ]
 352     [ caret>> set-model ] tri ;
 353
 354 : editor-cut ( editor clipboard -- )
 355     [ gadget-copy ] [ drop remove-selection ] 2bi ;
 356
 357 : delete/backspace ( editor quot -- )
 358     over gadget-selection? [
 359         drop remove-selection
 360     ] [
 361         [ [ [ editor-caret ] [ model>> ] bi ] dip call ]
 362         [ drop model>> ]
 363         2bi remove-doc-range
 364     ] if ; inline
 365
 366 : editor-delete ( editor elt -- )
 367     '[ dupd _ next-elt ] delete/backspace ;
 368
 369 : editor-backspace ( editor elt -- )
 370     '[ over [ _ prev-elt ] dip ] delete/backspace ;
 371
 372 : editor-select-prev ( editor elt -- )
 373     '[ _ prev-elt ] change-caret ;
 374
 375 : editor-prev ( editor elt -- )
 376     [ editor-select-prev ] [ drop mark>caret ] 2bi ;
 377
 378 : editor-select-next ( editor elt -- )
 379     '[ _ next-elt ] change-caret ;
 380
 381 : editor-next ( editor elt -- )
 382     dupd editor-select-next mark>caret ;
 383
 384 : editor-select ( from to editor -- )
 385     [ mark>> set-model ] [ caret>> set-model ] bi-curry bi* ;
 386
 387 : select-elt ( editor elt -- )
 388     [ [ [ editor-caret ] [ model>> ] bi ] dip prev/next-elt ] [ drop ] 2bi
 389     editor-select ;
 390
 391 : start-of-document ( editor -- ) doc-elt editor-prev ;
 392
 393 : end-of-document ( editor -- ) doc-elt editor-next ;
 394
 395 : position-caret ( editor -- )
 396     mouse-elt dup one-char-elt =
 397     [ drop dup extend-selection dup mark>> click-loc ]
 398     [ select-elt ] if ;
 399
 400 : delete-previous-character ( editor -- )
 401     char-elt editor-backspace ;
 402
 403 : delete-next-character ( editor -- )
 404     char-elt editor-delete ;
 405
 406 : delete-previous-word ( editor -- )
 407     word-elt editor-backspace ;
 408
 409 : delete-next-word ( editor -- )
 410     word-elt editor-delete ;
 411
 412 : delete-to-start-of-line ( editor -- )
 413     one-line-elt editor-backspace ;
 414
 415 : delete-to-end-of-line ( editor -- )
 416     one-line-elt editor-delete ;
 417
 418 : delete-to-start-of-document ( editor -- )
 419     doc-elt editor-delete ;
 420
 421 : delete-to-end-of-document ( editor -- )
 422     doc-elt editor-delete ;
 423
 424 : com-undo ( editor -- ) model>> undo ;
 425
 426 : com-redo ( editor -- ) model>> redo ;
 427
 428 editor "editing" f {
 429     { undo-action com-undo }
 430     { redo-action com-redo }
 431     { T{ key-down f f "DELETE" } delete-next-character }
 432     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 433     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 434     { T{ key-down f { C+ } "DELETE" } delete-next-word }
 435     { T{ key-down f { C+ } "BACKSPACE" } delete-previous-word }
 436     { T{ key-down f { A+ } "DELETE" } delete-to-end-of-line }
 437     { T{ key-down f { A+ } "BACKSPACE" } delete-to-start-of-line }
 438 } define-command-map
 439
 440 : com-paste ( editor -- ) clipboard get paste-clipboard ;
 441
 442 : paste-selection ( editor -- ) ui.clipboards:selection get paste-clipboard ;
 443
 444 : com-cut ( editor -- ) clipboard get editor-cut ;
 445
 446 editor "clipboard" f {
 447     { cut-action com-cut }
 448     { copy-action com-copy }
 449     { paste-action com-paste }
 450     { T{ button-up } com-copy-selection }
 451     { T{ button-up f f 2 } paste-selection }
 452 } define-command-map
 453
 454 : previous-character ( editor -- )
 455     dup gadget-selection? [
 456         dup selection-start/end drop
 457         over set-caret mark>caret
 458     ] [
 459         char-elt editor-prev
 460     ] if ;
 461
 462 : next-character ( editor -- )
 463     dup gadget-selection? [
 464         dup selection-start/end nip
 465         over set-caret mark>caret
 466     ] [
 467         char-elt editor-next
 468     ] if ;
 469
 470 : previous-word ( editor -- ) word-elt editor-prev ;
 471
 472 : next-word ( editor -- ) word-elt editor-next ;
 473
 474 : start-of-line ( editor -- ) one-line-elt editor-prev ;
 475
 476 : end-of-line ( editor -- ) one-line-elt editor-next ;
 477
 478 editor "caret-motion" f {
 479     { T{ button-down } position-caret }
 480     { T{ key-down f f "LEFT" } previous-character }
 481     { T{ key-down f f "RIGHT" } next-character }
 482     { T{ key-down f { C+ } "LEFT" } previous-word }
 483     { T{ key-down f { C+ } "RIGHT" } next-word }
 484     { T{ key-down f f "HOME" } start-of-line }
 485     { T{ key-down f f "END" } end-of-line }
 486     { T{ key-down f { C+ } "HOME" } start-of-document }
 487     { T{ key-down f { C+ } "END" } end-of-document }
 488 } define-command-map
 489
 490 : clear-editor ( editor -- )
 491     model>> clear-doc ;
 492
 493 : select-all ( editor -- ) doc-elt select-elt ;
 494
 495 : select-line ( editor -- ) one-line-elt select-elt ;
 496
 497 : select-word ( editor -- ) one-word-elt select-elt ;
 498
 499 : selected-token ( editor -- string )
 500     dup gadget-selection?
 501     [ dup select-word ] unless
 502     gadget-selection ;
 503
 504 : select-previous-character ( editor -- )
 505     char-elt editor-select-prev ;
 506
 507 : select-next-character ( editor -- )
 508     char-elt editor-select-next ;
 509
 510 : select-previous-word ( editor -- )
 511     word-elt editor-select-prev ;
 512
 513 : select-next-word ( editor -- )
 514     word-elt editor-select-next ;
 515
 516 : select-start-of-line ( editor -- )
 517     one-line-elt editor-select-prev ;
 518
 519 : select-end-of-line ( editor -- )
 520     one-line-elt editor-select-next ;
 521
 522 : select-start-of-document ( editor -- )
 523     doc-elt editor-select-prev ;
 524
 525 : select-end-of-document ( editor -- )
 526     doc-elt editor-select-next ;
 527
 528 editor "selection" f {
 529     { T{ button-down f { S+ } 1 } extend-selection }
 530     { T{ button-up f { S+ } 1 } com-copy-selection }
 531     { T{ drag { # 1 } } drag-selection }
 532     { gain-focus focus-editor }
 533     { lose-focus unfocus-editor }
 534     { delete-action remove-selection }
 535     { select-all-action select-all }
 536     { T{ key-down f { C+ } "l" } select-line }
 537     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 538     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 539     { T{ key-down f { S+ C+ } "LEFT" } select-previous-word }
 540     { T{ key-down f { S+ C+ } "RIGHT" } select-next-word }
 541     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 542     { T{ key-down f { S+ } "END" } select-end-of-line }
 543     { T{ key-down f { S+ C+ } "HOME" } select-start-of-document }
 544     { T{ key-down f { S+ C+ } "END" } select-end-of-document }
 545 } define-command-map
 546
 547 : editor-menu ( editor -- )
 548     {
 549         com-undo
 550         com-redo
 551         ----
 552         com-cut
 553         com-copy
 554         com-paste
 555     } show-commands-menu ;
 556
 557 editor "misc" f {
 558     ! { T{ button-down f f 2 } paste-selection }
 559     { T{ button-down f f 3 } editor-menu }
 560 } define-command-map
 561
 562 ! Multi-line editors
 563 TUPLE: multiline-editor < editor ;
 564
 565 : <multiline-editor> ( -- editor )
 566     multiline-editor new-editor ;
 567
 568 : previous-line ( editor -- ) line-elt editor-prev ;
 569
 570 : next-line ( editor -- ) line-elt editor-next ;
 571
 572 <PRIVATE
 573
 574 : page-elt ( editor n -- editor element )
 575     over visible-lines 1 - min 1 max <page-elt> ;
 576
 577 : prev-page-elt ( editor -- editor element )
 578     dup editor-caret first page-elt ;
 579
 580 : next-page-elt ( editor -- editor element )
 581     dup [ control-value length 1 - ] [ editor-caret first ] bi - page-elt ;
 582
 583 PRIVATE>
 584
 585 : previous-page ( editor -- ) prev-page-elt editor-prev ;
 586
 587 : next-page ( editor -- ) next-page-elt editor-next ;
 588
 589 : select-previous-line ( editor -- ) line-elt editor-select-prev ;
 590
 591 : select-next-line ( editor -- ) line-elt editor-select-next ;
 592
 593 : select-previous-page ( editor -- ) prev-page-elt editor-select-prev ;
 594
 595 : select-next-page ( editor -- ) next-page-elt editor-select-next ;
 596
 597 : insert-newline ( editor -- )
 598     "\n" swap user-input* drop ;
 599
 600 : change-selection ( editor quot -- )
 601     '[ gadget-selection @ ] [ user-input* drop ] bi ; inline
 602
 603 <PRIVATE
 604
 605 : join-lines ( string -- string' )
 606     "\n" split
 607     [ rest-slice [ [ blank? ] trim-head-slice ] map! drop ]
 608     [ but-last-slice [ [ blank? ] trim-tail-slice ] map! drop ]
 609     [ " " join ]
 610     tri ;
 611
 612 : last-line? ( document line -- ? )
 613     [ last-line# ] dip = ;
 614
 615 : prev-line-and-this ( document line -- start end )
 616     swap [ drop 1 - 0 2array ] [ line-end ] 2bi ;
 617
 618 : join-with-prev ( document line -- )
 619     [ prev-line-and-this ] [ drop ] 2bi
 620     [ join-lines ] change-doc-range ;
 621
 622 : this-line-and-next ( document line -- start end )
 623     swap [ drop 0 2array ] [ [ 1 + ] dip line-end ] 2bi ;
 624
 625 : join-with-next ( document line -- )
 626     [ this-line-and-next ] [ drop ] 2bi
 627     [ join-lines ] change-doc-range ;
 628
 629 PRIVATE>
 630
 631 : com-join-lines ( editor -- )
 632     dup gadget-selection?
 633     [ [ join-lines ] change-selection ] [
 634         [ model>> ] [ editor-caret first ] bi {
 635             { [ over last-line# 0 = ] [ 2drop ] }
 636             { [ 2dup last-line? ] [ join-with-prev ] }
 637             [ join-with-next ]
 638         } cond
 639     ] if ;
 640
 641 multiline-editor "multiline" f {
 642     { T{ key-down f f "UP" } previous-line }
 643     { T{ key-down f f "DOWN" } next-line }
 644     { T{ key-down f { S+ } "UP" } select-previous-line }
 645     { T{ key-down f { S+ } "DOWN" } select-next-line }
 646     { T{ key-down f f "PAGE_UP" } previous-page }
 647     { T{ key-down f f "PAGE_DOWN" } next-page }
 648     { T{ key-down f { S+ } "PAGE_UP" } select-previous-page }
 649     { T{ key-down f { S+ } "PAGE_DOWN" } select-next-page }
 650     { T{ key-down f f "RET" } insert-newline }
 651     { T{ key-down f { S+ } "RET" } insert-newline }
 652     { T{ key-down f f "ENTER" } insert-newline }
 653     { T{ key-down f { C+ } "j" } com-join-lines }
 654 } define-command-map
 655
 656 TUPLE: source-editor < multiline-editor ;
 657
 658 : <source-editor> ( -- editor )
 659     source-editor new-editor ;
 660
 661 ! A useful model
 662 : <element-model> ( editor element -- model )
 663     [ [ caret>> ] [ model>> ] bi ] dip
 664     '[ _ _ elt-string ] <arrow> ;
 665
 666 ! Fields wrap an editor
 667 TUPLE: field < border editor min-cols max-cols ;
 668
 669 <PRIVATE
 670
 671 : field-theme ( gadget -- gadget )
 672     { 2 2 } >>size
 673     { 1 0 } >>fill
 674     field-border-color <solid> >>boundary ; inline
 675
 676 : <field-border> ( gadget -- border )
 677     border new-border field-theme ;
 678
 679 PRIVATE>
 680
 681 : new-field ( class -- gadget )
 682     [ <editor> ] dip new-border
 683         dup gadget-child >>editor
 684         field-theme ; inline
 685
 686 ! For line-gadget-width
 687 M: field font>> editor>> font>> ;
 688
 689 M: field pref-dim*
 690     [ ]
 691     [ editor>> pref-dim ]
 692     [ [ line-gadget-width ] [ drop second ] 2bi 2array ]
 693     tri border-pref-dim ;
 694
 695 M: field default-text>> editor>> default-text>> ;
 696
 697 M: field default-text<< editor>> default-text<< ;
 698
 699 TUPLE: model-field < field field-model ;
 700
 701 : <model-field> ( model -- gadget )
 702     model-field new-field
 703         swap >>field-model ;
 704
 705 M: model-field graft*
 706     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 707     [ dup editor>> model>> add-connection ]
 708     bi ;
 709
 710 M: model-field ungraft*
 711     dup editor>> model>> remove-connection ;
 712
 713 M: model-field model-changed
 714     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;
 715
 716 TUPLE: action-field < field quot ;
 717
 718 : <action-field> ( quot: ( string -- ) -- gadget )
 719     action-field [ <editor> ] dip new-border
 720         dup gadget-child >>editor
 721         field-theme
 722         swap >>quot ;
 723
 724 : invoke-action-field ( field -- )
 725     [ editor>> editor-string ]
 726     [ editor>> clear-editor ]
 727     [ quot>> ]
 728     tri call( string -- ) ;
 729
 730 action-field H{
 731     { T{ key-down f f "RET" } [ invoke-action-field ] }
 732 } set-gestures