basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2011 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs calendar colors.constants combinators
   4 combinators.short-circuit documents documents.elements fonts fry
   5 grouping kernel locals make math math.functions math.order math.ranges
   6 math.rectangles math.vectors models models.arrow namespaces opengl
   7 sequences sorting splitting timers ui.baseline-alignment ui.clipboards
   8 ui.commands ui.gadgets ui.gadgets.borders ui.gadgets.line-support
   9 ui.gadgets.menus ui.gadgets.scrollers ui.gestures ui.pens.solid
  10 ui.render ui.text ui.theme unicode ;
  11 IN: ui.gadgets.editors
  12
  13 TUPLE: editor < line-gadget
  14     caret mark
  15     focused? blink blink-timer
  16     default-text ;
  17
  18 <PRIVATE
  19
  20 : <loc> ( -- loc ) { 0 0 } <model> ;
  21
  22 : init-editor-locs ( editor -- editor )
  23     <loc> >>caret
  24     <loc> >>mark ; inline
  25
  26 : editor-theme ( editor -- editor )
  27     monospace-font >>font ; inline
  28
  29 PRIVATE>
  30
  31 : new-editor ( class -- editor )
  32     new-line-gadget
  33         <document> >>model
  34         init-editor-locs
  35         editor-theme ; inline
  36
  37 : <editor> ( -- editor )
  38     editor new-editor ;
  39
  40 <PRIVATE
  41
  42 : activate-editor-model ( editor model -- )
  43     [ add-connection ]
  44     [ nip activate-model ]
  45     [ swap model>> add-loc ] 2tri ;
  46
  47 : deactivate-editor-model ( editor model -- )
  48     [ remove-connection ]
  49     [ nip deactivate-model ]
  50     [ swap model>> remove-loc ] 2tri ;
  51
  52 : blink-caret ( editor -- )
  53     [ not ] change-blink relayout-1 ;
  54
  55 SYMBOL: blink-interval
  56
  57 750 milliseconds blink-interval set-global
  58
  59 : stop-blinking ( editor -- )
  60     blink-timer>> [ stop-timer ] when* ;
  61
  62 : start-blinking ( editor -- )
  63     t >>blink
  64     blink-timer>> [ restart-timer ] when* ;
  65
  66 : restart-blinking ( editor -- )
  67     dup focused?>> [
  68         [ start-blinking ]
  69         [ relayout-1 ]
  70         bi
  71     ] [ drop ] if ;
  72
  73 PRIVATE>
  74
  75 M: editor graft*
  76     [ dup caret>> activate-editor-model ]
  77     [ dup mark>> activate-editor-model ]
  78     [
  79         [
  80             '[ _ blink-caret ] blink-interval get dup <timer>
  81         ] keep blink-timer<<
  82     ] tri ;
  83
  84 M: editor ungraft*
  85     [ [ stop-blinking ] [ f >>blink-timer drop ] bi ]
  86     [ dup caret>> deactivate-editor-model ]
  87     [ dup mark>> deactivate-editor-model ] tri ;
  88
  89 : editor-caret ( editor -- loc ) caret>> value>> ;
  90
  91 : editor-mark ( editor -- loc ) mark>> value>> ;
  92
  93 : set-caret ( loc editor -- )
  94     [ model>> validate-loc ] [ caret>> ] bi set-model ;
  95
  96 : change-caret ( editor quot: ( loc document -- newloc ) -- )
  97     [ [ [ editor-caret ] [ model>> ] bi ] dip call ] [ drop ] 2bi
  98     set-caret ; inline
  99
 100 : mark>caret ( editor -- )
 101     [ editor-caret ] [ mark>> ] bi set-model ;
 102
 103 : change-caret&mark ( editor quot: ( loc document -- newloc ) -- )
 104     [ change-caret ] [ drop mark>caret ] 2bi ; inline
 105
 106 : editor-line ( n editor -- str ) control-value nth ;
 107
 108 :: point>loc ( point editor -- loc )
 109     point second editor y>line {
 110         { [ dup 0 < ] [ drop { 0 0 } ] }
 111         { [ dup editor model>> last-line# > ] [ drop editor model>> doc-end ] }
 112         [| n |
 113             n
 114             point first
 115             editor font>>
 116             n editor editor-line
 117             x>offset 2array
 118         ]
 119     } cond ;
 120
 121 : clicked-loc ( editor -- loc )
 122     [ hand-rel ] keep point>loc ;
 123
 124 : click-loc ( editor model -- )
 125     [ clicked-loc ] dip set-model ;
 126
 127 : focus-editor ( editor -- )
 128     [ start-blinking ] [ t >>focused? relayout-1 ] bi ;
 129
 130 : unfocus-editor ( editor -- )
 131     [ stop-blinking ] [ f >>focused? relayout-1 ] bi ;
 132
 133 : loc>x ( loc editor -- x )
 134     [ first2 swap ] dip [ editor-line ] [ font>> ] bi swap offset>x round ;
 135
 136 : loc>point ( loc editor -- loc )
 137     [ loc>x ] [ [ first ] dip line>y ceiling ] 2bi 2array ;
 138
 139 : caret-loc ( editor -- loc )
 140     [ editor-caret ] keep loc>point ;
 141
 142 : caret-dim ( editor -- dim )
 143     [ 0 ] dip line-height 2array ;
 144
 145 : scroll>caret ( editor -- )
 146     dup graft-state>> second [
 147         [
 148             [ caret-loc ] [ caret-dim { 2 1 } v+ ] bi <rect>
 149         ] keep scroll>rect
 150     ] [ drop ] if ;
 151
 152 <PRIVATE
 153
 154 : draw-caret? ( editor -- ? )
 155     { [ focused?>> ] [ blink>> ] } 1&& ;
 156
 157 : draw-caret ( editor -- )
 158     dup draw-caret? [
 159         [ editor-caret-color gl-color ] dip
 160         [ caret-loc ] [ caret-dim ] bi
 161         over v+ gl-line
 162     ] [ drop ] if ;
 163
 164 : selection-start/end ( editor -- start end )
 165     [ editor-mark ] [ editor-caret ] bi sort-pair ;
 166
 167 SYMBOL: selected-lines
 168
 169 TUPLE: selected-line start end first? last? ;
 170
 171 : compute-selection ( editor -- assoc )
 172     dup gadget-selection? [
 173         [ selection-start/end [ [ first ] bi@ [a,b] ] [ ] 2bi ]
 174         [ model>> ] bi
 175         '[ [ _ _ ] [ _ start/end-on-line ] bi 2array ] H{ } map>assoc
 176     ] [ drop f ] if ;
 177
 178 :: draw-selection ( line pair editor -- )
 179     pair [ editor font>> line offset>x ] map :> pair
 180     editor selection-color>> gl-color
 181     pair first 0 2array
 182     pair second pair first - round 1 max editor line-height 2array
 183     gl-fill-rect ;
 184
 185 : draw-unselected-line ( line editor -- )
 186     font>> swap draw-text ;
 187
 188 : draw-selected-line ( line pair editor -- )
 189     over all-equal? [
 190         [ nip draw-unselected-line ] [ draw-selection ] 3bi
 191     ] [
 192         [ draw-selection ]
 193         [
 194             [ [ first2 ] [ selection-color>> ] bi* <selection> ]
 195             [ draw-unselected-line ] bi
 196         ] 3bi
 197     ] if ;
 198
 199 : draw-default-text? ( editor -- ? )
 200     { [ default-text>> ] [ model>> doc-string empty? ] } 1&& ;
 201
 202 : draw-default-text ( editor -- )
 203     [ font>> clone line-color >>foreground ]
 204     [ default-text>> ] bi draw-text ;
 205
 206 PRIVATE>
 207
 208 M: editor draw-line ( line index editor -- )
 209     [ selected-lines get at ] dip over
 210     [ draw-selected-line ] [ nip draw-unselected-line ] if ;
 211
 212 M: editor draw-gadget*
 213     dup draw-default-text? [
 214         [ draw-default-text ] [ draw-caret ] bi
 215     ] [
 216         dup compute-selection selected-lines [
 217             [ draw-lines ] [ draw-caret ] bi
 218         ] with-variable
 219     ] if ;
 220
 221 M: editor pref-dim*
 222     ! Add some space for the caret.
 223     [ font>> ] keep dup draw-default-text?
 224     [ default-text>> ] [ control-value ] if
 225     text-dim { 1 0 } v+ ;
 226
 227 M: editor baseline font>> font-metrics ascent>> ;
 228
 229 M: editor cap-height font>> font-metrics cap-height>> ;
 230
 231 <PRIVATE
 232
 233 : contents-changed ( model editor -- )
 234     [ [ nip caret>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 235     [ [ nip mark>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 236     [ nip relayout ] 2tri ;
 237
 238 : caret/mark-changed ( editor -- )
 239     [ restart-blinking ] keep scroll>caret ;
 240
 241 PRIVATE>
 242
 243 M: editor model-changed
 244     {
 245         { [ 2dup model>> eq? ] [ contents-changed ] }
 246         { [ 2dup caret>> eq? ] [ nip caret/mark-changed ] }
 247         { [ 2dup mark>> eq? ] [ nip caret/mark-changed ] }
 248     } cond ;
 249
 250 M: editor gadget-selection?
 251     selection-start/end = not ;
 252
 253 M: editor gadget-selection
 254     [ selection-start/end ] [ model>> ] bi doc-range ;
 255
 256 : remove-selection ( editor -- )
 257     [ selection-start/end ] [ model>> ] bi remove-doc-range ;
 258
 259 M: editor user-input*
 260     [ selection-start/end ] [ model>> ] bi set-doc-range t ;
 261
 262 : editor-string ( editor -- string )
 263     model>> doc-string ;
 264
 265 : set-editor-string ( string editor -- )
 266     model>> set-doc-string ;
 267
 268 M: editor gadget-text* editor-string % ;
 269
 270 : extend-selection ( editor -- )
 271     [ request-focus ]
 272     [ restart-blinking ]
 273     [ dup caret>> click-loc ] tri ;
 274
 275 : mouse-elt ( -- element )
 276     hand-click# get {
 277         { 1 one-char-elt }
 278         { 2 one-word-elt }
 279     } at one-line-elt or ;
 280
 281 : drag-direction? ( loc editor -- ? )
 282     editor-mark before? ;
 283
 284 : drag-selection-caret ( loc editor element -- loc )
 285     [
 286         [ drag-direction? ] [ model>> ] 2bi
 287     ] dip prev/next-elt ? ;
 288
 289 : drag-selection-mark ( loc editor element -- loc )
 290     [
 291         [ drag-direction? not ]
 292         [ editor-mark ]
 293         [ model>> ] tri
 294     ] dip prev/next-elt ? ;
 295
 296 : drag-caret&mark ( editor -- caret mark )
 297     [ clicked-loc ] [ mouse-elt ] bi
 298     [ drag-selection-caret ]
 299     [ drag-selection-mark ] 3bi ;
 300
 301 : drag-selection ( editor -- )
 302     [ drag-caret&mark ]
 303     [ mark>> set-model ]
 304     [ caret>> set-model ] tri ;
 305
 306 : editor-cut ( editor clipboard -- )
 307     [ gadget-copy ] [ drop remove-selection ] 2bi ;
 308
 309 : delete/backspace ( editor quot -- )
 310     over gadget-selection? [
 311         drop remove-selection
 312     ] [
 313         [ [ [ editor-caret ] [ model>> ] bi ] dip call ]
 314         [ drop model>> ]
 315         2bi remove-doc-range
 316     ] if ; inline
 317
 318 : editor-delete ( editor elt -- )
 319     '[ dupd _ next-elt ] delete/backspace ;
 320
 321 : editor-backspace ( editor elt -- )
 322     '[ over [ _ prev-elt ] dip ] delete/backspace ;
 323
 324 : editor-select-prev ( editor elt -- )
 325     '[ _ prev-elt ] change-caret ;
 326
 327 : editor-prev ( editor elt -- )
 328     [ editor-select-prev ] [ drop mark>caret ] 2bi ;
 329
 330 : editor-select-next ( editor elt -- )
 331     '[ _ next-elt ] change-caret ;
 332
 333 : editor-next ( editor elt -- )
 334     dupd editor-select-next mark>caret ;
 335
 336 : editor-select ( from to editor -- )
 337     [ mark>> set-model ] [ caret>> set-model ] bi-curry bi* ;
 338
 339 : select-elt ( editor elt -- )
 340     [ [ [ editor-caret ] [ model>> ] bi ] dip prev/next-elt ] [ drop ] 2bi
 341     editor-select ;
 342
 343 : start-of-document ( editor -- ) doc-elt editor-prev ;
 344
 345 : end-of-document ( editor -- ) doc-elt editor-next ;
 346
 347 : position-caret ( editor -- )
 348     mouse-elt dup one-char-elt =
 349     [ drop dup extend-selection dup mark>> click-loc ]
 350     [ select-elt ] if ;
 351
 352 : delete-previous-character ( editor -- )
 353     char-elt editor-backspace ;
 354
 355 : delete-next-character ( editor -- )
 356     char-elt editor-delete ;
 357
 358 : delete-previous-word ( editor -- )
 359     word-elt editor-backspace ;
 360
 361 : delete-next-word ( editor -- )
 362     word-elt editor-delete ;
 363
 364 : delete-to-start-of-line ( editor -- )
 365     one-line-elt editor-backspace ;
 366
 367 : delete-to-end-of-line ( editor -- )
 368     one-line-elt editor-delete ;
 369
 370 : delete-to-start-of-document ( editor -- )
 371     doc-elt editor-delete ;
 372
 373 : delete-to-end-of-document ( editor -- )
 374     doc-elt editor-delete ;
 375
 376 : com-undo ( editor -- ) model>> undo ;
 377
 378 : com-redo ( editor -- ) model>> redo ;
 379
 380 editor "editing" f {
 381     { undo-action com-undo }
 382     { redo-action com-redo }
 383     { T{ key-down f f "DELETE" } delete-next-character }
 384     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 385     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 386     { T{ key-down f { C+ } "DELETE" } delete-next-word }
 387     { T{ key-down f { C+ } "BACKSPACE" } delete-previous-word }
 388     { T{ key-down f { A+ } "DELETE" } delete-to-end-of-line }
 389     { T{ key-down f { A+ } "BACKSPACE" } delete-to-start-of-line }
 390 } define-command-map
 391
 392 : com-paste ( editor -- ) clipboard get paste-clipboard ;
 393
 394 : paste-selection ( editor -- ) ui.clipboards:selection get paste-clipboard ;
 395
 396 : com-cut ( editor -- ) clipboard get editor-cut ;
 397
 398 editor "clipboard" f {
 399     { cut-action com-cut }
 400     { copy-action com-copy }
 401     { paste-action com-paste }
 402     { T{ button-up } com-copy-selection }
 403     { T{ button-up f f 2 } paste-selection }
 404 } define-command-map
 405
 406 : previous-character ( editor -- )
 407     dup gadget-selection? [
 408         dup selection-start/end drop
 409         over set-caret mark>caret
 410     ] [
 411         char-elt editor-prev
 412     ] if ;
 413
 414 : next-character ( editor -- )
 415     dup gadget-selection? [
 416         dup selection-start/end nip
 417         over set-caret mark>caret
 418     ] [
 419         char-elt editor-next
 420     ] if ;
 421
 422 : previous-word ( editor -- ) word-elt editor-prev ;
 423
 424 : next-word ( editor -- ) word-elt editor-next ;
 425
 426 : start-of-line ( editor -- ) one-line-elt editor-prev ;
 427
 428 : end-of-line ( editor -- ) one-line-elt editor-next ;
 429
 430 editor "caret-motion" f {
 431     { T{ button-down } position-caret }
 432     { T{ key-down f f "LEFT" } previous-character }
 433     { T{ key-down f f "RIGHT" } next-character }
 434     { T{ key-down f { C+ } "LEFT" } previous-word }
 435     { T{ key-down f { C+ } "RIGHT" } next-word }
 436     { T{ key-down f f "HOME" } start-of-line }
 437     { T{ key-down f f "END" } end-of-line }
 438     { T{ key-down f { C+ } "HOME" } start-of-document }
 439     { T{ key-down f { C+ } "END" } end-of-document }
 440 } define-command-map
 441
 442 : clear-editor ( editor -- )
 443     model>> clear-doc ;
 444
 445 : select-all ( editor -- ) doc-elt select-elt ;
 446
 447 : select-line ( editor -- ) one-line-elt select-elt ;
 448
 449 : select-word ( editor -- ) one-word-elt select-elt ;
 450
 451 : selected-token ( editor -- string )
 452     dup gadget-selection?
 453     [ dup select-word ] unless
 454     gadget-selection ;
 455
 456 : select-previous-character ( editor -- )
 457     char-elt editor-select-prev ;
 458
 459 : select-next-character ( editor -- )
 460     char-elt editor-select-next ;
 461
 462 : select-previous-word ( editor -- )
 463     word-elt editor-select-prev ;
 464
 465 : select-next-word ( editor -- )
 466     word-elt editor-select-next ;
 467
 468 : select-start-of-line ( editor -- )
 469     one-line-elt editor-select-prev ;
 470
 471 : select-end-of-line ( editor -- )
 472     one-line-elt editor-select-next ;
 473
 474 : select-start-of-document ( editor -- )
 475     doc-elt editor-select-prev ;
 476
 477 : select-end-of-document ( editor -- )
 478     doc-elt editor-select-next ;
 479
 480 editor "selection" f {
 481     { T{ button-down f { S+ } 1 } extend-selection }
 482     { T{ button-up f { S+ } 1 } com-copy-selection }
 483     { T{ drag { # 1 } } drag-selection }
 484     { gain-focus focus-editor }
 485     { lose-focus unfocus-editor }
 486     { delete-action remove-selection }
 487     { select-all-action select-all }
 488     { T{ key-down f { C+ } "l" } select-line }
 489     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 490     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 491     { T{ key-down f { S+ C+ } "LEFT" } select-previous-word }
 492     { T{ key-down f { S+ C+ } "RIGHT" } select-next-word }
 493     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 494     { T{ key-down f { S+ } "END" } select-end-of-line }
 495     { T{ key-down f { S+ C+ } "HOME" } select-start-of-document }
 496     { T{ key-down f { S+ C+ } "END" } select-end-of-document }
 497 } define-command-map
 498
 499 : editor-menu ( editor -- )
 500     {
 501         com-undo
 502         com-redo
 503         ----
 504         com-cut
 505         com-copy
 506         com-paste
 507     } show-commands-menu ;
 508
 509 editor "misc" f {
 510     ! { T{ button-down f f 2 } paste-selection }
 511     { T{ button-down f f 3 } editor-menu }
 512 } define-command-map
 513
 514 ! Multi-line editors
 515 TUPLE: multiline-editor < editor ;
 516
 517 : <multiline-editor> ( -- editor )
 518     multiline-editor new-editor ;
 519
 520 : previous-line ( editor -- ) line-elt editor-prev ;
 521
 522 : next-line ( editor -- ) line-elt editor-next ;
 523
 524 <PRIVATE
 525
 526 : page-elt ( editor -- editor element ) dup visible-lines 1 - <page-elt> ;
 527
 528 PRIVATE>
 529
 530 : previous-page ( editor -- ) page-elt editor-prev ;
 531
 532 : next-page ( editor -- ) page-elt editor-next ;
 533
 534 : select-previous-line ( editor -- ) line-elt editor-select-prev ;
 535
 536 : select-next-line ( editor -- ) line-elt editor-select-next ;
 537
 538 : select-previous-page ( editor -- ) page-elt editor-select-prev ;
 539
 540 : select-next-page ( editor -- ) page-elt editor-select-next ;
 541
 542 : insert-newline ( editor -- )
 543     "\n" swap user-input* drop ;
 544
 545 : change-selection ( editor quot -- )
 546     '[ gadget-selection @ ] [ user-input* drop ] bi ; inline
 547
 548 <PRIVATE
 549
 550 : join-lines ( string -- string' )
 551     "\n" split
 552     [ rest-slice [ [ blank? ] trim-head-slice ] map! drop ]
 553     [ but-last-slice [ [ blank? ] trim-tail-slice ] map! drop ]
 554     [ " " join ]
 555     tri ;
 556
 557 : last-line? ( document line -- ? )
 558     [ last-line# ] dip = ;
 559
 560 : prev-line-and-this ( document line -- start end )
 561     swap [ drop 1 - 0 2array ] [ line-end ] 2bi ;
 562
 563 : join-with-prev ( document line -- )
 564     [ prev-line-and-this ] [ drop ] 2bi
 565     [ join-lines ] change-doc-range ;
 566
 567 : this-line-and-next ( document line -- start end )
 568     swap [ drop 0 2array ] [ [ 1 + ] dip line-end ] 2bi ;
 569
 570 : join-with-next ( document line -- )
 571     [ this-line-and-next ] [ drop ] 2bi
 572     [ join-lines ] change-doc-range ;
 573
 574 PRIVATE>
 575
 576 : com-join-lines ( editor -- )
 577     dup gadget-selection?
 578     [ [ join-lines ] change-selection ] [
 579         [ model>> ] [ editor-caret first ] bi {
 580             { [ over last-line# 0 = ] [ 2drop ] }
 581             { [ 2dup last-line? ] [ join-with-prev ] }
 582             [ join-with-next ]
 583         } cond
 584     ] if ;
 585
 586 multiline-editor "multiline" f {
 587     { T{ key-down f f "UP" } previous-line }
 588     { T{ key-down f f "DOWN" } next-line }
 589     { T{ key-down f { S+ } "UP" } select-previous-line }
 590     { T{ key-down f { S+ } "DOWN" } select-next-line }
 591     { T{ key-down f f "PAGE_UP" } previous-page }
 592     { T{ key-down f f "PAGE_DOWN" } next-page }
 593     { T{ key-down f { S+ } "PAGE_UP" } select-previous-page }
 594     { T{ key-down f { S+ } "PAGE_DOWN" } select-next-page }
 595     { T{ key-down f f "RET" } insert-newline }
 596     { T{ key-down f { S+ } "RET" } insert-newline }
 597     { T{ key-down f f "ENTER" } insert-newline }
 598     { T{ key-down f { C+ } "j" } com-join-lines }
 599 } define-command-map
 600
 601 TUPLE: source-editor < multiline-editor ;
 602
 603 : <source-editor> ( -- editor )
 604     source-editor new-editor ;
 605
 606 ! A useful model
 607 : <element-model> ( editor element -- model )
 608     [ [ caret>> ] [ model>> ] bi ] dip
 609     '[ _ _ elt-string ] <arrow> ;
 610
 611 ! Fields wrap an editor
 612 TUPLE: field < border editor min-cols max-cols ;
 613
 614 <PRIVATE
 615
 616 : field-theme ( gadget -- gadget )
 617     { 2 2 } >>size
 618     { 1 0 } >>fill
 619     field-border-color <solid> >>boundary ; inline
 620
 621 : <field-border> ( gadget -- border )
 622     border new-border field-theme ;
 623
 624 PRIVATE>
 625
 626 : new-field ( class -- gadget )
 627     [ <editor> ] dip new-border
 628         dup gadget-child >>editor
 629         field-theme ; inline
 630
 631 ! For line-gadget-width
 632 M: field font>> editor>> font>> ;
 633
 634 M: field pref-dim*
 635     [ ]
 636     [ editor>> pref-dim ]
 637     [ [ line-gadget-width ] [ drop second ] 2bi 2array ]
 638     tri border-pref-dim ;
 639
 640 M: field default-text>> editor>> default-text>> ;
 641
 642 M: field default-text<< editor>> default-text<< ;
 643
 644 TUPLE: model-field < field field-model ;
 645
 646 : <model-field> ( model -- gadget )
 647     model-field new-field
 648         swap >>field-model ;
 649
 650 M: model-field graft*
 651     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 652     [ dup editor>> model>> add-connection ]
 653     bi ;
 654
 655 M: model-field ungraft*
 656     dup editor>> model>> remove-connection ;
 657
 658 M: model-field model-changed
 659     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;
 660
 661 TUPLE: action-field < field quot ;
 662
 663 : <action-field> ( quot: ( string -- ) -- gadget )
 664     action-field [ <editor> ] dip new-border
 665         dup gadget-child >>editor
 666         field-theme
 667         swap >>quot ;
 668
 669 : invoke-action-field ( field -- )
 670     [ editor>> editor-string ]
 671     [ editor>> clear-editor ]
 672     [ quot>> ]
 673     tri call( string -- ) ;
 674
 675 action-field H{
 676     { T{ key-down f f "RET" } [ invoke-action-field ] }
 677 } set-gestures