basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2011 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs calendar colors.constants combinators
   4 combinators.short-circuit documents documents.elements fonts fry
   5 grouping kernel locals make math math.functions math.order math.ranges
   6 math.rectangles math.vectors models models.arrow namespaces opengl
   7 sequences sorting splitting timers ui.baseline-alignment ui.clipboards
   8 ui.commands ui.gadgets ui.gadgets.borders ui.gadgets.line-support
   9 ui.gadgets.menus ui.gadgets.scrollers ui.gestures ui.pens.solid
  10 ui.render ui.text ui.theme unicode ;
  11 IN: ui.gadgets.editors
  12
  13 TUPLE: editor < line-gadget
  14     caret-color
  15     caret mark
  16     focused? blink blink-timer
  17     default-text ;
  18
  19 <PRIVATE
  20
  21 : <loc> ( -- loc ) { 0 0 } <model> ;
  22
  23 : init-editor-locs ( editor -- editor )
  24     <loc> >>caret
  25     <loc> >>mark ; inline
  26
  27 : editor-theme ( editor -- editor )
  28     monospace-font >>font ; inline
  29
  30 PRIVATE>
  31
  32 : new-editor ( class -- editor )
  33     new-line-gadget
  34         <document> >>model
  35         init-editor-locs
  36         editor-theme ; inline
  37
  38 : <editor> ( -- editor )
  39     editor new-editor ;
  40
  41 <PRIVATE
  42
  43 : activate-editor-model ( editor model -- )
  44     [ add-connection ]
  45     [ nip activate-model ]
  46     [ swap model>> add-loc ] 2tri ;
  47
  48 : deactivate-editor-model ( editor model -- )
  49     [ remove-connection ]
  50     [ nip deactivate-model ]
  51     [ swap model>> remove-loc ] 2tri ;
  52
  53 : blink-caret ( editor -- )
  54     [ not ] change-blink relayout-1 ;
  55
  56 SYMBOL: blink-interval
  57
  58 750 milliseconds blink-interval set-global
  59
  60 : stop-blinking ( editor -- )
  61     blink-timer>> [ stop-timer ] when* ;
  62
  63 : start-blinking ( editor -- )
  64     t >>blink
  65     blink-timer>> [ restart-timer ] when* ;
  66
  67 : restart-blinking ( editor -- )
  68     dup focused?>> [
  69         [ start-blinking ]
  70         [ relayout-1 ]
  71         bi
  72     ] [ drop ] if ;
  73
  74 PRIVATE>
  75
  76 M: editor graft*
  77     [ dup caret>> activate-editor-model ]
  78     [ dup mark>> activate-editor-model ]
  79     [
  80         [
  81             '[ _ blink-caret ] blink-interval get dup <timer>
  82         ] keep blink-timer<<
  83     ] tri ;
  84
  85 M: editor ungraft*
  86     [ [ stop-blinking ] [ f >>blink-timer drop ] bi ]
  87     [ dup caret>> deactivate-editor-model ]
  88     [ dup mark>> deactivate-editor-model ] tri ;
  89
  90 : editor-caret ( editor -- loc ) caret>> value>> ;
  91
  92 : editor-mark ( editor -- loc ) mark>> value>> ;
  93
  94 : set-caret ( loc editor -- )
  95     [ model>> validate-loc ] [ caret>> ] bi set-model ;
  96
  97 : change-caret ( editor quot: ( loc document -- newloc ) -- )
  98     [ [ [ editor-caret ] [ model>> ] bi ] dip call ] [ drop ] 2bi
  99     set-caret ; inline
 100
 101 : mark>caret ( editor -- )
 102     [ editor-caret ] [ mark>> ] bi set-model ;
 103
 104 : change-caret&mark ( editor quot: ( loc document -- newloc ) -- )
 105     [ change-caret ] [ drop mark>caret ] 2bi ; inline
 106
 107 : editor-line ( n editor -- str ) control-value nth ;
 108
 109 :: point>loc ( point editor -- loc )
 110     point second editor y>line {
 111         { [ dup 0 < ] [ drop { 0 0 } ] }
 112         { [ dup editor model>> last-line# > ] [ drop editor model>> doc-end ] }
 113         [| n |
 114             n
 115             point first
 116             editor font>>
 117             n editor editor-line
 118             x>offset 2array
 119         ]
 120     } cond ;
 121
 122 : clicked-loc ( editor -- loc )
 123     [ hand-rel ] keep point>loc ;
 124
 125 : click-loc ( editor model -- )
 126     [ clicked-loc ] dip set-model ;
 127
 128 : focus-editor ( editor -- )
 129     [ start-blinking ] [ t >>focused? relayout-1 ] bi ;
 130
 131 : unfocus-editor ( editor -- )
 132     [ stop-blinking ] [ f >>focused? relayout-1 ] bi ;
 133
 134 : loc>x ( loc editor -- x )
 135     [ first2 swap ] dip [ editor-line ] [ font>> ] bi swap offset>x round ;
 136
 137 : loc>point ( loc editor -- loc )
 138     [ loc>x ] [ [ first ] dip line>y ceiling ] 2bi 2array ;
 139
 140 : caret-loc ( editor -- loc )
 141     [ editor-caret ] keep loc>point ;
 142
 143 : caret-dim ( editor -- dim )
 144     [ 0 ] dip line-height 2array ;
 145
 146 : scroll>caret ( editor -- )
 147     dup graft-state>> second [
 148         [
 149             [ caret-loc ] [ caret-dim { 2 1 } v+ ] bi <rect>
 150         ] keep scroll>rect
 151     ] [ drop ] if ;
 152
 153 <PRIVATE
 154
 155 : draw-caret? ( editor -- ? )
 156     { [ focused?>> ] [ blink>> ] } 1&& ;
 157
 158 : draw-caret ( editor -- )
 159     dup draw-caret? [
 160         [ editor-caret-color gl-color ] dip
 161         [ caret-loc ] [ caret-dim ] bi
 162         over v+ gl-line
 163     ] [ drop ] if ;
 164
 165 : selection-start/end ( editor -- start end )
 166     [ editor-mark ] [ editor-caret ] bi sort-pair ;
 167
 168 SYMBOL: selected-lines
 169
 170 TUPLE: selected-line start end first? last? ;
 171
 172 : compute-selection ( editor -- assoc )
 173     dup gadget-selection? [
 174         [ selection-start/end [ [ first ] bi@ [a,b] ] [ ] 2bi ]
 175         [ model>> ] bi
 176         '[ [ _ _ ] [ _ start/end-on-line ] bi 2array ] H{ } map>assoc
 177     ] [ drop f ] if ;
 178
 179 :: draw-selection ( line pair editor -- )
 180     pair [ editor font>> line offset>x ] map :> pair
 181     editor selection-color>> gl-color
 182     pair first 0 2array
 183     pair second pair first - round 1 max editor line-height 2array
 184     gl-fill-rect ;
 185
 186 : draw-unselected-line ( line editor -- )
 187     font>> swap draw-text ;
 188
 189 : draw-selected-line ( line pair editor -- )
 190     over all-equal? [
 191         [ nip draw-unselected-line ] [ draw-selection ] 3bi
 192     ] [
 193         [ draw-selection ]
 194         [
 195             [ [ first2 ] [ selection-color>> ] bi* <selection> ]
 196             [ draw-unselected-line ] bi
 197         ] 3bi
 198     ] if ;
 199
 200 : draw-default-text? ( editor -- ? )
 201     { [ default-text>> ] [ model>> doc-string empty? ] } 1&& ;
 202
 203 : draw-default-text ( editor -- )
 204     [ font>> clone line-color >>foreground ]
 205     [ default-text>> ] bi draw-text ;
 206
 207 PRIVATE>
 208
 209 M: editor draw-line ( line index editor -- )
 210     [ selected-lines get at ] dip over
 211     [ draw-selected-line ] [ nip draw-unselected-line ] if ;
 212
 213 M: editor draw-gadget*
 214     dup draw-default-text? [
 215         [ draw-default-text ] [ draw-caret ] bi
 216     ] [
 217         dup compute-selection selected-lines [
 218             [ draw-lines ] [ draw-caret ] bi
 219         ] with-variable
 220     ] if ;
 221
 222 M: editor pref-dim*
 223     ! Add some space for the caret.
 224     [ font>> ] keep dup draw-default-text?
 225     [ default-text>> ] [ control-value ] if
 226     text-dim { 1 0 } v+ ;
 227
 228 M: editor baseline font>> font-metrics ascent>> ;
 229
 230 M: editor cap-height font>> font-metrics cap-height>> ;
 231
 232 <PRIVATE
 233
 234 : contents-changed ( model editor -- )
 235     [ [ nip caret>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 236     [ [ nip mark>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 237     [ nip relayout ] 2tri ;
 238
 239 : caret/mark-changed ( editor -- )
 240     [ restart-blinking ] keep scroll>caret ;
 241
 242 PRIVATE>
 243
 244 M: editor model-changed
 245     {
 246         { [ 2dup model>> eq? ] [ contents-changed ] }
 247         { [ 2dup caret>> eq? ] [ nip caret/mark-changed ] }
 248         { [ 2dup mark>> eq? ] [ nip caret/mark-changed ] }
 249     } cond ;
 250
 251 M: editor gadget-selection?
 252     selection-start/end = not ;
 253
 254 M: editor gadget-selection
 255     [ selection-start/end ] [ model>> ] bi doc-range ;
 256
 257 : remove-selection ( editor -- )
 258     [ selection-start/end ] [ model>> ] bi remove-doc-range ;
 259
 260 M: editor user-input*
 261     [ selection-start/end ] [ model>> ] bi set-doc-range t ;
 262
 263 : editor-string ( editor -- string )
 264     model>> doc-string ;
 265
 266 : set-editor-string ( string editor -- )
 267     model>> set-doc-string ;
 268
 269 M: editor gadget-text* editor-string % ;
 270
 271 : extend-selection ( editor -- )
 272     [ request-focus ]
 273     [ restart-blinking ]
 274     [ dup caret>> click-loc ] tri ;
 275
 276 : mouse-elt ( -- element )
 277     hand-click# get {
 278         { 1 one-char-elt }
 279         { 2 one-word-elt }
 280     } at one-line-elt or ;
 281
 282 : drag-direction? ( loc editor -- ? )
 283     editor-mark before? ;
 284
 285 : drag-selection-caret ( loc editor element -- loc )
 286     [
 287         [ drag-direction? ] [ model>> ] 2bi
 288     ] dip prev/next-elt ? ;
 289
 290 : drag-selection-mark ( loc editor element -- loc )
 291     [
 292         [ drag-direction? not ]
 293         [ editor-mark ]
 294         [ model>> ] tri
 295     ] dip prev/next-elt ? ;
 296
 297 : drag-caret&mark ( editor -- caret mark )
 298     [ clicked-loc ] [ mouse-elt ] bi
 299     [ drag-selection-caret ]
 300     [ drag-selection-mark ] 3bi ;
 301
 302 : drag-selection ( editor -- )
 303     [ drag-caret&mark ]
 304     [ mark>> set-model ]
 305     [ caret>> set-model ] tri ;
 306
 307 : editor-cut ( editor clipboard -- )
 308     [ gadget-copy ] [ drop remove-selection ] 2bi ;
 309
 310 : delete/backspace ( editor quot -- )
 311     over gadget-selection? [
 312         drop remove-selection
 313     ] [
 314         [ [ [ editor-caret ] [ model>> ] bi ] dip call ]
 315         [ drop model>> ]
 316         2bi remove-doc-range
 317     ] if ; inline
 318
 319 : editor-delete ( editor elt -- )
 320     '[ dupd _ next-elt ] delete/backspace ;
 321
 322 : editor-backspace ( editor elt -- )
 323     '[ over [ _ prev-elt ] dip ] delete/backspace ;
 324
 325 : editor-select-prev ( editor elt -- )
 326     '[ _ prev-elt ] change-caret ;
 327
 328 : editor-prev ( editor elt -- )
 329     [ editor-select-prev ] [ drop mark>caret ] 2bi ;
 330
 331 : editor-select-next ( editor elt -- )
 332     '[ _ next-elt ] change-caret ;
 333
 334 : editor-next ( editor elt -- )
 335     dupd editor-select-next mark>caret ;
 336
 337 : editor-select ( from to editor -- )
 338     [ mark>> set-model ] [ caret>> set-model ] bi-curry bi* ;
 339
 340 : select-elt ( editor elt -- )
 341     [ [ [ editor-caret ] [ model>> ] bi ] dip prev/next-elt ] [ drop ] 2bi
 342     editor-select ;
 343
 344 : start-of-document ( editor -- ) doc-elt editor-prev ;
 345
 346 : end-of-document ( editor -- ) doc-elt editor-next ;
 347
 348 : position-caret ( editor -- )
 349     mouse-elt dup one-char-elt =
 350     [ drop dup extend-selection dup mark>> click-loc ]
 351     [ select-elt ] if ;
 352
 353 : delete-previous-character ( editor -- )
 354     char-elt editor-backspace ;
 355
 356 : delete-next-character ( editor -- )
 357     char-elt editor-delete ;
 358
 359 : delete-previous-word ( editor -- )
 360     word-elt editor-backspace ;
 361
 362 : delete-next-word ( editor -- )
 363     word-elt editor-delete ;
 364
 365 : delete-to-start-of-line ( editor -- )
 366     one-line-elt editor-backspace ;
 367
 368 : delete-to-end-of-line ( editor -- )
 369     one-line-elt editor-delete ;
 370
 371 : delete-to-start-of-document ( editor -- )
 372     doc-elt editor-delete ;
 373
 374 : delete-to-end-of-document ( editor -- )
 375     doc-elt editor-delete ;
 376
 377 : com-undo ( editor -- ) model>> undo ;
 378
 379 : com-redo ( editor -- ) model>> redo ;
 380
 381 editor "editing" f {
 382     { undo-action com-undo }
 383     { redo-action com-redo }
 384     { T{ key-down f f "DELETE" } delete-next-character }
 385     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 386     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 387     { T{ key-down f { C+ } "DELETE" } delete-next-word }
 388     { T{ key-down f { C+ } "BACKSPACE" } delete-previous-word }
 389     { T{ key-down f { A+ } "DELETE" } delete-to-end-of-line }
 390     { T{ key-down f { A+ } "BACKSPACE" } delete-to-start-of-line }
 391 } define-command-map
 392
 393 : com-paste ( editor -- ) clipboard get paste-clipboard ;
 394
 395 : paste-selection ( editor -- ) ui.clipboards:selection get paste-clipboard ;
 396
 397 : com-cut ( editor -- ) clipboard get editor-cut ;
 398
 399 editor "clipboard" f {
 400     { cut-action com-cut }
 401     { copy-action com-copy }
 402     { paste-action com-paste }
 403     { T{ button-up } com-copy-selection }
 404     { T{ button-up f f 2 } paste-selection }
 405 } define-command-map
 406
 407 : previous-character ( editor -- )
 408     dup gadget-selection? [
 409         dup selection-start/end drop
 410         over set-caret mark>caret
 411     ] [
 412         char-elt editor-prev
 413     ] if ;
 414
 415 : next-character ( editor -- )
 416     dup gadget-selection? [
 417         dup selection-start/end nip
 418         over set-caret mark>caret
 419     ] [
 420         char-elt editor-next
 421     ] if ;
 422
 423 : previous-word ( editor -- ) word-elt editor-prev ;
 424
 425 : next-word ( editor -- ) word-elt editor-next ;
 426
 427 : start-of-line ( editor -- ) one-line-elt editor-prev ;
 428
 429 : end-of-line ( editor -- ) one-line-elt editor-next ;
 430
 431 editor "caret-motion" f {
 432     { T{ button-down } position-caret }
 433     { T{ key-down f f "LEFT" } previous-character }
 434     { T{ key-down f f "RIGHT" } next-character }
 435     { T{ key-down f { C+ } "LEFT" } previous-word }
 436     { T{ key-down f { C+ } "RIGHT" } next-word }
 437     { T{ key-down f f "HOME" } start-of-line }
 438     { T{ key-down f f "END" } end-of-line }
 439     { T{ key-down f { C+ } "HOME" } start-of-document }
 440     { T{ key-down f { C+ } "END" } end-of-document }
 441 } define-command-map
 442
 443 : clear-editor ( editor -- )
 444     model>> clear-doc ;
 445
 446 : select-all ( editor -- ) doc-elt select-elt ;
 447
 448 : select-line ( editor -- ) one-line-elt select-elt ;
 449
 450 : select-word ( editor -- ) one-word-elt select-elt ;
 451
 452 : selected-token ( editor -- string )
 453     dup gadget-selection?
 454     [ dup select-word ] unless
 455     gadget-selection ;
 456
 457 : select-previous-character ( editor -- )
 458     char-elt editor-select-prev ;
 459
 460 : select-next-character ( editor -- )
 461     char-elt editor-select-next ;
 462
 463 : select-previous-word ( editor -- )
 464     word-elt editor-select-prev ;
 465
 466 : select-next-word ( editor -- )
 467     word-elt editor-select-next ;
 468
 469 : select-start-of-line ( editor -- )
 470     one-line-elt editor-select-prev ;
 471
 472 : select-end-of-line ( editor -- )
 473     one-line-elt editor-select-next ;
 474
 475 : select-start-of-document ( editor -- )
 476     doc-elt editor-select-prev ;
 477
 478 : select-end-of-document ( editor -- )
 479     doc-elt editor-select-next ;
 480
 481 editor "selection" f {
 482     { T{ button-down f { S+ } 1 } extend-selection }
 483     { T{ button-up f { S+ } 1 } com-copy-selection }
 484     { T{ drag { # 1 } } drag-selection }
 485     { gain-focus focus-editor }
 486     { lose-focus unfocus-editor }
 487     { delete-action remove-selection }
 488     { select-all-action select-all }
 489     { T{ key-down f { C+ } "l" } select-line }
 490     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 491     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 492     { T{ key-down f { S+ C+ } "LEFT" } select-previous-word }
 493     { T{ key-down f { S+ C+ } "RIGHT" } select-next-word }
 494     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 495     { T{ key-down f { S+ } "END" } select-end-of-line }
 496     { T{ key-down f { S+ C+ } "HOME" } select-start-of-document }
 497     { T{ key-down f { S+ C+ } "END" } select-end-of-document }
 498 } define-command-map
 499
 500 : editor-menu ( editor -- )
 501     {
 502         com-undo
 503         com-redo
 504         ----
 505         com-cut
 506         com-copy
 507         com-paste
 508     } show-commands-menu ;
 509
 510 editor "misc" f {
 511     ! { T{ button-down f f 2 } paste-selection }
 512     { T{ button-down f f 3 } editor-menu }
 513 } define-command-map
 514
 515 ! Multi-line editors
 516 TUPLE: multiline-editor < editor ;
 517
 518 : <multiline-editor> ( -- editor )
 519     multiline-editor new-editor ;
 520
 521 : previous-line ( editor -- ) line-elt editor-prev ;
 522
 523 : next-line ( editor -- ) line-elt editor-next ;
 524
 525 <PRIVATE
 526
 527 : page-elt ( editor -- editor element ) dup visible-lines 1 - <page-elt> ;
 528
 529 PRIVATE>
 530
 531 : previous-page ( editor -- ) page-elt editor-prev ;
 532
 533 : next-page ( editor -- ) page-elt editor-next ;
 534
 535 : select-previous-line ( editor -- ) line-elt editor-select-prev ;
 536
 537 : select-next-line ( editor -- ) line-elt editor-select-next ;
 538
 539 : select-previous-page ( editor -- ) page-elt editor-select-prev ;
 540
 541 : select-next-page ( editor -- ) page-elt editor-select-next ;
 542
 543 : insert-newline ( editor -- )
 544     "\n" swap user-input* drop ;
 545
 546 : change-selection ( editor quot -- )
 547     '[ gadget-selection @ ] [ user-input* drop ] bi ; inline
 548
 549 <PRIVATE
 550
 551 : join-lines ( string -- string' )
 552     "\n" split
 553     [ rest-slice [ [ blank? ] trim-head-slice ] map! drop ]
 554     [ but-last-slice [ [ blank? ] trim-tail-slice ] map! drop ]
 555     [ " " join ]
 556     tri ;
 557
 558 : last-line? ( document line -- ? )
 559     [ last-line# ] dip = ;
 560
 561 : prev-line-and-this ( document line -- start end )
 562     swap [ drop 1 - 0 2array ] [ line-end ] 2bi ;
 563
 564 : join-with-prev ( document line -- )
 565     [ prev-line-and-this ] [ drop ] 2bi
 566     [ join-lines ] change-doc-range ;
 567
 568 : this-line-and-next ( document line -- start end )
 569     swap [ drop 0 2array ] [ [ 1 + ] dip line-end ] 2bi ;
 570
 571 : join-with-next ( document line -- )
 572     [ this-line-and-next ] [ drop ] 2bi
 573     [ join-lines ] change-doc-range ;
 574
 575 PRIVATE>
 576
 577 : com-join-lines ( editor -- )
 578     dup gadget-selection?
 579     [ [ join-lines ] change-selection ] [
 580         [ model>> ] [ editor-caret first ] bi {
 581             { [ over last-line# 0 = ] [ 2drop ] }
 582             { [ 2dup last-line? ] [ join-with-prev ] }
 583             [ join-with-next ]
 584         } cond
 585     ] if ;
 586
 587 multiline-editor "multiline" f {
 588     { T{ key-down f f "UP" } previous-line }
 589     { T{ key-down f f "DOWN" } next-line }
 590     { T{ key-down f { S+ } "UP" } select-previous-line }
 591     { T{ key-down f { S+ } "DOWN" } select-next-line }
 592     { T{ key-down f f "PAGE_UP" } previous-page }
 593     { T{ key-down f f "PAGE_DOWN" } next-page }
 594     { T{ key-down f { S+ } "PAGE_UP" } select-previous-page }
 595     { T{ key-down f { S+ } "PAGE_DOWN" } select-next-page }
 596     { T{ key-down f f "RET" } insert-newline }
 597     { T{ key-down f { S+ } "RET" } insert-newline }
 598     { T{ key-down f f "ENTER" } insert-newline }
 599     { T{ key-down f { C+ } "j" } com-join-lines }
 600 } define-command-map
 601
 602 TUPLE: source-editor < multiline-editor ;
 603
 604 : <source-editor> ( -- editor )
 605     source-editor new-editor ;
 606
 607 ! A useful model
 608 : <element-model> ( editor element -- model )
 609     [ [ caret>> ] [ model>> ] bi ] dip
 610     '[ _ _ elt-string ] <arrow> ;
 611
 612 ! Fields wrap an editor
 613 TUPLE: field < border editor min-cols max-cols ;
 614
 615 <PRIVATE
 616
 617 : field-theme ( gadget -- gadget )
 618     { 2 2 } >>size
 619     { 1 0 } >>fill
 620     field-border-color <solid> >>boundary ; inline
 621
 622 : <field-border> ( gadget -- border )
 623     border new-border field-theme ;
 624
 625 PRIVATE>
 626
 627 : new-field ( class -- gadget )
 628     [ <editor> ] dip new-border
 629         dup gadget-child >>editor
 630         field-theme ; inline
 631
 632 ! For line-gadget-width
 633 M: field font>> editor>> font>> ;
 634
 635 M: field pref-dim*
 636     [ ]
 637     [ editor>> pref-dim ]
 638     [ [ line-gadget-width ] [ drop second ] 2bi 2array ]
 639     tri border-pref-dim ;
 640
 641 M: field default-text>> editor>> default-text>> ;
 642
 643 M: field default-text<< editor>> default-text<< ;
 644
 645 TUPLE: model-field < field field-model ;
 646
 647 : <model-field> ( model -- gadget )
 648     model-field new-field
 649         swap >>field-model ;
 650
 651 M: model-field graft*
 652     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 653     [ dup editor>> model>> add-connection ]
 654     bi ;
 655
 656 M: model-field ungraft*
 657     dup editor>> model>> remove-connection ;
 658
 659 M: model-field model-changed
 660     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;
 661
 662 TUPLE: action-field < field quot ;
 663
 664 : <action-field> ( quot: ( string -- ) -- gadget )
 665     action-field [ <editor> ] dip new-border
 666         dup gadget-child >>editor
 667         field-theme
 668         swap >>quot ;
 669
 670 : invoke-action-field ( field -- )
 671     [ editor>> editor-string ]
 672     [ editor>> clear-editor ]
 673     [ quot>> ]
 674     tri call( string -- ) ;
 675
 676 action-field H{
 677     { T{ key-down f f "RET" } [ invoke-action-field ] }
 678 } set-gestures