basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2011 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs calendar colors.constants combinators
   4 combinators.short-circuit documents documents.elements fonts fry
   5 grouping kernel locals make math math.functions math.order math.ranges
   6 math.rectangles math.vectors models models.arrow namespaces opengl
   7 sequences sorting splitting timers ui.baseline-alignment ui.clipboards
   8 ui.commands ui.gadgets ui.gadgets.borders ui.gadgets.line-support
   9 ui.gadgets.menus ui.gadgets.scrollers ui.gestures ui.pens.solid
  10 ui.render ui.text ui.theme unicode opengl.gl ;
  11 IN: ui.gadgets.editors
  12
  13 TUPLE: editor < line-gadget
  14     caret mark
  15     focused? blink blink-timer
  16     default-text
  17     preedit-start
  18     preedit-end
  19     preedit-selected-start
  20     preedit-selected-end
  21     preedit-selection-mode?
  22     preedit-underlines ;
  23
  24 M: editor preedit? preedit-start>> ;
  25
  26 <PRIVATE
  27
  28 : <loc> ( -- loc ) { 0 0 } <model> ;
  29
  30 : init-editor-locs ( editor -- editor )
  31     <loc> >>caret
  32     <loc> >>mark ; inline
  33
  34 : editor-theme ( editor -- editor )
  35     monospace-font >>font ; inline
  36
  37 PRIVATE>
  38
  39 : new-editor ( class -- editor )
  40     new-line-gadget
  41         <document> >>model
  42         init-editor-locs
  43         editor-theme ; inline
  44
  45 : <editor> ( -- editor )
  46     editor new-editor ;
  47
  48 <PRIVATE
  49
  50 : activate-editor-model ( editor model -- )
  51     [ add-connection ]
  52     [ nip activate-model ]
  53     [ swap model>> add-loc ] 2tri ;
  54
  55 : deactivate-editor-model ( editor model -- )
  56     [ remove-connection ]
  57     [ nip deactivate-model ]
  58     [ swap model>> remove-loc ] 2tri ;
  59
  60 : blink-caret ( editor -- )
  61     [ not ] change-blink relayout-1 ;
  62
  63 SYMBOL: blink-interval
  64
  65 750 milliseconds blink-interval set-global
  66
  67 : stop-blinking ( editor -- )
  68     blink-timer>> [ stop-timer ] when* ;
  69
  70 : start-blinking ( editor -- )
  71     t >>blink
  72     blink-timer>> [ restart-timer ] when* ;
  73
  74 : restart-blinking ( editor -- )
  75     dup focused?>> [
  76         [ start-blinking ]
  77         [ relayout-1 ]
  78         bi
  79     ] [ drop ] if ;
  80
  81 PRIVATE>
  82
  83 M: editor graft*
  84     [ dup caret>> activate-editor-model ]
  85     [ dup mark>> activate-editor-model ]
  86     [
  87         [
  88             '[ _ blink-caret ] blink-interval get dup <timer>
  89         ] keep blink-timer<<
  90     ] tri ;
  91
  92 M: editor ungraft*
  93     [ [ stop-blinking ] [ f >>blink-timer drop ] bi ]
  94     [ dup caret>> deactivate-editor-model ]
  95     [ dup mark>> deactivate-editor-model ] tri ;
  96
  97 : editor-caret ( editor -- loc ) caret>> value>> ;
  98
  99 : editor-mark ( editor -- loc ) mark>> value>> ;
 100
 101 : set-caret ( loc editor -- )
 102     [ model>> validate-loc ] [ caret>> ] bi set-model ;
 103
 104 : set-mark ( loc editor -- )
 105     [ model>> validate-loc ] [ mark>> ] bi set-model ;
 106
 107 : change-caret ( editor quot: ( loc document -- newloc ) -- )
 108     [ [ [ editor-caret ] [ model>> ] bi ] dip call ] [ drop ] 2bi
 109     set-caret ; inline
 110
 111 : mark>caret ( editor -- )
 112     [ editor-caret ] [ mark>> ] bi set-model ;
 113
 114 : change-caret&mark ( editor quot: ( loc document -- newloc ) -- )
 115     [ change-caret ] [ drop mark>caret ] 2bi ; inline
 116
 117 : editor-line ( n editor -- str ) control-value nth ;
 118
 119 :: point>loc ( point editor -- loc )
 120     point second editor y>line {
 121         { [ dup 0 < ] [ drop { 0 0 } ] }
 122         { [ dup editor model>> last-line# > ] [ drop editor model>> doc-end ] }
 123         [| n |
 124             n
 125             point first
 126             editor font>>
 127             n editor editor-line
 128             x>offset 2array
 129         ]
 130     } cond ;
 131
 132 : clicked-loc ( editor -- loc )
 133     [ hand-rel ] keep point>loc ;
 134
 135 : click-loc ( editor model -- )
 136     [ clicked-loc ] dip set-model ;
 137
 138 : focus-editor ( editor -- )
 139     [ start-blinking ] [ t >>focused? relayout-1 ] bi ;
 140
 141 : unfocus-editor ( editor -- )
 142     [ stop-blinking ] [ f >>focused? relayout-1 ] bi ;
 143
 144 : loc>x ( loc editor -- x )
 145     [ first2 swap ] dip [ editor-line ] [ font>> ] bi swap offset>x round ;
 146
 147 : loc>point ( loc editor -- loc )
 148     [ loc>x ] [ [ first ] dip line>y ceiling ] 2bi 2array ;
 149
 150 : caret-loc ( editor -- loc )
 151     [ editor-caret ] keep loc>point ;
 152
 153 : caret-dim ( editor -- dim )
 154     [ 0 ] dip line-height 2array ;
 155
 156 : scroll>caret ( editor -- )
 157     dup graft-state>> second [
 158         [
 159             [ caret-loc ] [ caret-dim { 2 1 } v+ ] bi <rect>
 160         ] keep scroll>rect
 161     ] [ drop ] if ;
 162
 163 <PRIVATE
 164
 165 : draw-caret? ( editor -- ? )
 166     { [ focused?>> ] [ blink>> ]
 167       [ [ preedit? not ] [ preedit-selection-mode?>> not ] bi or ] } 1&& ;
 168
 169 : draw-caret ( editor -- )
 170     dup draw-caret? [
 171         [ editor-caret-color gl-color ] dip
 172         [ caret-loc ] [ caret-dim ] bi
 173         over v+ gl-line
 174     ] [ drop ] if ;
 175
 176 :: draw-preedit-underlines ( editor -- )
 177     editor [ preedit? ] [ preedit-underlines>> ] bi and [
 178         editor [ caret-loc second ] [ caret-dim second ] bi + 2.0 - :> y
 179         editor editor-caret first :> row
 180         editor font>> foreground>> gl-color
 181         editor preedit-underlines>> [
 182             GL_LINE_BIT [
 183                 dup second glLineWidth
 184                 first editor preedit-start>> second dup 2array v+ first2
 185                 [ row swap 2array editor loc>x 1.0 + y 2array ]
 186                 [ row swap 2array editor loc>x 1.0 - y 2array ]
 187                 bi*
 188                 gl-line
 189             ] do-attribs
 190         ] each
 191     ] when ;
 192
 193 : selection-start/end ( editor -- start end )
 194     [ editor-mark ] [ editor-caret ] bi sort-pair ;
 195
 196 SYMBOL: selected-lines
 197
 198 TUPLE: selected-line start end first? last? ;
 199
 200 : compute-selection ( editor -- assoc )
 201     dup gadget-selection? [
 202         [ selection-start/end [ [ first ] bi@ [a,b] ] [ ] 2bi ]
 203         [ model>> ] bi
 204         '[ [ _ _ ] [ _ start/end-on-line ] bi 2array ] H{ } map>assoc
 205     ] [ drop f ] if ;
 206
 207 :: draw-selection ( line pair editor -- )
 208     pair [ editor font>> line offset>x ] map :> pair
 209     editor selection-color>> gl-color
 210     pair first 0 2array
 211     pair second pair first - round 1 max editor line-height 2array
 212     gl-fill-rect ;
 213
 214 : draw-unselected-line ( line editor -- )
 215     font>> swap draw-text ;
 216
 217 : draw-selected-line ( line pair editor -- )
 218     over all-equal? [
 219         [ nip draw-unselected-line ] [ draw-selection ] 3bi
 220     ] [
 221         [ draw-selection ]
 222         [
 223             [ [ first2 ] [ selection-color>> ] bi* <selection> ]
 224             [ draw-unselected-line ] bi
 225         ] 3bi
 226     ] if ;
 227
 228 : draw-default-text? ( editor -- ? )
 229     { [ default-text>> ] [ model>> doc-string empty? ] } 1&& ;
 230
 231 : draw-default-text ( editor -- )
 232     [ font>> clone line-color >>foreground ]
 233     [ default-text>> ] bi draw-text ;
 234
 235 PRIVATE>
 236
 237 M: editor draw-line ( line index editor -- )
 238     [ selected-lines get at ] dip over
 239     [ draw-selected-line ] [ nip draw-unselected-line ] if ;
 240
 241 M: editor draw-gadget*
 242     dup draw-default-text? [
 243         [ draw-default-text ] [ draw-caret ] [ draw-preedit-underlines ] tri
 244     ] [
 245         dup compute-selection selected-lines [
 246             [ draw-lines ] [ draw-caret ] [ draw-preedit-underlines ] tri
 247         ] with-variable
 248     ] if ;
 249
 250 M: editor pref-dim*
 251     ! Add some space for the caret.
 252     [ font>> ] keep dup draw-default-text?
 253     [ default-text>> ] [ control-value ] if
 254     text-dim { 1 0 } v+ ;
 255
 256 M: editor baseline font>> font-metrics ascent>> ;
 257
 258 M: editor cap-height font>> font-metrics cap-height>> ;
 259
 260 <PRIVATE
 261
 262 : contents-changed ( model editor -- )
 263     [ [ nip caret>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 264     [ [ nip mark>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 265     [ nip relayout ] 2tri ;
 266
 267 : caret/mark-changed ( editor -- )
 268     [ restart-blinking ] keep scroll>caret ;
 269
 270 PRIVATE>
 271
 272 M: editor model-changed
 273     {
 274         { [ 2dup model>> eq? ] [ contents-changed ] }
 275         { [ 2dup caret>> eq? ] [ nip caret/mark-changed ] }
 276         { [ 2dup mark>> eq? ] [ nip caret/mark-changed ] }
 277     } cond ;
 278
 279 M: editor gadget-selection?
 280     selection-start/end = not ;
 281
 282 M: editor gadget-selection
 283     [ selection-start/end ] [ model>> ] bi doc-range ;
 284
 285 : remove-selection ( editor -- )
 286     [ selection-start/end ] [ model>> ] bi remove-doc-range ;
 287
 288 M: editor user-input*
 289     [ selection-start/end ] [ model>> ] bi set-doc-range t ;
 290
 291 M: editor temp-im-input
 292     [ selection-start/end ] [ model>> ] bi set-doc-range* t ;
 293
 294 : editor-string ( editor -- string )
 295     model>> doc-string ;
 296
 297 : set-editor-string ( string editor -- )
 298     model>> set-doc-string ;
 299
 300 M: editor gadget-text* editor-string % ;
 301
 302 : extend-selection ( editor -- )
 303     [ request-focus ]
 304     [ restart-blinking ]
 305     [ dup caret>> click-loc ] tri ;
 306
 307 : remove-preedit-text ( editor -- )
 308     { [ preedit-start>> ] [ set-caret ]
 309       [ preedit-end>> ] [ set-mark ]
 310       [ remove-selection ]
 311     } cleave ;
 312
 313 : remove-preedit-info ( editor -- )
 314     f >>preedit-start
 315     f >>preedit-end
 316     f >>preedit-selected-start
 317     f >>preedit-selected-end
 318     f >>preedit-selection-mode?
 319     f >>preedit-underlines
 320     drop ;
 321
 322 : mouse-elt ( -- element )
 323     hand-click# get {
 324         { 1 one-char-elt }
 325         { 2 one-word-elt }
 326     } at one-line-elt or ;
 327
 328 : drag-direction? ( loc editor -- ? )
 329     editor-mark before? ;
 330
 331 : drag-selection-caret ( loc editor element -- loc )
 332     [
 333         [ drag-direction? ] [ model>> ] 2bi
 334     ] dip prev/next-elt ? ;
 335
 336 : drag-selection-mark ( loc editor element -- loc )
 337     [
 338         [ drag-direction? not ]
 339         [ editor-mark ]
 340         [ model>> ] tri
 341     ] dip prev/next-elt ? ;
 342
 343 : drag-caret&mark ( editor -- caret mark )
 344     [ clicked-loc ] [ mouse-elt ] bi
 345     [ drag-selection-caret ]
 346     [ drag-selection-mark ] 3bi ;
 347
 348 : drag-selection ( editor -- )
 349     [ drag-caret&mark ]
 350     [ mark>> set-model ]
 351     [ caret>> set-model ] tri ;
 352
 353 : editor-cut ( editor clipboard -- )
 354     [ gadget-copy ] [ drop remove-selection ] 2bi ;
 355
 356 : delete/backspace ( editor quot -- )
 357     over gadget-selection? [
 358         drop remove-selection
 359     ] [
 360         [ [ [ editor-caret ] [ model>> ] bi ] dip call ]
 361         [ drop model>> ]
 362         2bi remove-doc-range
 363     ] if ; inline
 364
 365 : editor-delete ( editor elt -- )
 366     '[ dupd _ next-elt ] delete/backspace ;
 367
 368 : editor-backspace ( editor elt -- )
 369     '[ over [ _ prev-elt ] dip ] delete/backspace ;
 370
 371 : editor-select-prev ( editor elt -- )
 372     '[ _ prev-elt ] change-caret ;
 373
 374 : editor-prev ( editor elt -- )
 375     [ editor-select-prev ] [ drop mark>caret ] 2bi ;
 376
 377 : editor-select-next ( editor elt -- )
 378     '[ _ next-elt ] change-caret ;
 379
 380 : editor-next ( editor elt -- )
 381     dupd editor-select-next mark>caret ;
 382
 383 : editor-select ( from to editor -- )
 384     [ mark>> set-model ] [ caret>> set-model ] bi-curry bi* ;
 385
 386 : select-elt ( editor elt -- )
 387     [ [ [ editor-caret ] [ model>> ] bi ] dip prev/next-elt ] [ drop ] 2bi
 388     editor-select ;
 389
 390 : start-of-document ( editor -- ) doc-elt editor-prev ;
 391
 392 : end-of-document ( editor -- ) doc-elt editor-next ;
 393
 394 : position-caret ( editor -- )
 395     mouse-elt dup one-char-elt =
 396     [ drop dup extend-selection dup mark>> click-loc ]
 397     [ select-elt ] if ;
 398
 399 : delete-previous-character ( editor -- )
 400     char-elt editor-backspace ;
 401
 402 : delete-next-character ( editor -- )
 403     char-elt editor-delete ;
 404
 405 : delete-previous-word ( editor -- )
 406     word-elt editor-backspace ;
 407
 408 : delete-next-word ( editor -- )
 409     word-elt editor-delete ;
 410
 411 : delete-to-start-of-line ( editor -- )
 412     one-line-elt editor-backspace ;
 413
 414 : delete-to-end-of-line ( editor -- )
 415     one-line-elt editor-delete ;
 416
 417 : delete-to-start-of-document ( editor -- )
 418     doc-elt editor-delete ;
 419
 420 : delete-to-end-of-document ( editor -- )
 421     doc-elt editor-delete ;
 422
 423 : com-undo ( editor -- ) model>> undo ;
 424
 425 : com-redo ( editor -- ) model>> redo ;
 426
 427 editor "editing" f {
 428     { undo-action com-undo }
 429     { redo-action com-redo }
 430     { T{ key-down f f "DELETE" } delete-next-character }
 431     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 432     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 433     { T{ key-down f { C+ } "DELETE" } delete-next-word }
 434     { T{ key-down f { C+ } "BACKSPACE" } delete-previous-word }
 435     { T{ key-down f { A+ } "DELETE" } delete-to-end-of-line }
 436     { T{ key-down f { A+ } "BACKSPACE" } delete-to-start-of-line }
 437     { T{ key-down f { C+ } "u" } delete-to-start-of-line }
 438     { T{ key-down f { C+ } "k" } delete-to-end-of-line }
 439 } define-command-map
 440
 441 : com-paste ( editor -- ) clipboard get paste-clipboard ;
 442
 443 : paste-selection ( editor -- ) ui.clipboards:selection get paste-clipboard ;
 444
 445 : com-cut ( editor -- ) clipboard get editor-cut ;
 446
 447 editor "clipboard" f {
 448     { cut-action com-cut }
 449     { copy-action com-copy }
 450     { paste-action com-paste }
 451     { T{ button-up } com-copy-selection }
 452     { T{ button-up f f 2 } paste-selection }
 453 } define-command-map
 454
 455 : previous-character ( editor -- )
 456     dup gadget-selection? [
 457         dup selection-start/end drop
 458         over set-caret mark>caret
 459     ] [
 460         char-elt editor-prev
 461     ] if ;
 462
 463 : next-character ( editor -- )
 464     dup gadget-selection? [
 465         dup selection-start/end nip
 466         over set-caret mark>caret
 467     ] [
 468         char-elt editor-next
 469     ] if ;
 470
 471 : previous-word ( editor -- ) word-elt editor-prev ;
 472
 473 : next-word ( editor -- ) word-elt editor-next ;
 474
 475 : start-of-line ( editor -- ) one-line-elt editor-prev ;
 476
 477 DEFER: select-all
 478
 479 : start-of-line/select-all ( editor -- )
 480     dup editor-caret second 0 =
 481     [ select-all ] [ start-of-line ] if ;
 482
 483 : end-of-line ( editor -- ) one-line-elt editor-next ;
 484
 485 editor "caret-motion" f {
 486     { T{ button-down } position-caret }
 487     { T{ key-down f f "LEFT" } previous-character }
 488     { T{ key-down f f "RIGHT" } next-character }
 489     { T{ key-down f { C+ } "b" } previous-character }
 490     { T{ key-down f { C+ } "f" } next-character }
 491     { T{ key-down f { C+ } "LEFT" } previous-word }
 492     { T{ key-down f { C+ } "RIGHT" } next-word }
 493     { T{ key-down f f "HOME" } start-of-line }
 494     { T{ key-down f f "END" } end-of-line }
 495     { T{ key-down f { C+ } "a" } start-of-line/select-all }
 496     { T{ key-down f { C+ } "e" } end-of-line }
 497     { T{ key-down f { C+ } "HOME" } start-of-document }
 498     { T{ key-down f { C+ } "END" } end-of-document }
 499 } define-command-map
 500
 501 : clear-editor ( editor -- )
 502     model>> clear-doc ;
 503
 504 : select-all ( editor -- ) doc-elt select-elt ;
 505
 506 : select-line ( editor -- ) one-line-elt select-elt ;
 507
 508 : select-word ( editor -- ) one-word-elt select-elt ;
 509
 510 : selected-token ( editor -- string )
 511     dup gadget-selection?
 512     [ dup select-word ] unless
 513     gadget-selection ;
 514
 515 : select-previous-character ( editor -- )
 516     char-elt editor-select-prev ;
 517
 518 : select-next-character ( editor -- )
 519     char-elt editor-select-next ;
 520
 521 : select-previous-word ( editor -- )
 522     word-elt editor-select-prev ;
 523
 524 : select-next-word ( editor -- )
 525     word-elt editor-select-next ;
 526
 527 : select-start-of-line ( editor -- )
 528     one-line-elt editor-select-prev ;
 529
 530 : select-end-of-line ( editor -- )
 531     one-line-elt editor-select-next ;
 532
 533 : select-start-of-document ( editor -- )
 534     doc-elt editor-select-prev ;
 535
 536 : select-end-of-document ( editor -- )
 537     doc-elt editor-select-next ;
 538
 539 editor "selection" f {
 540     { T{ button-down f { S+ } 1 } extend-selection }
 541     { T{ button-up f { S+ } 1 } com-copy-selection }
 542     { T{ drag { # 1 } } drag-selection }
 543     { gain-focus focus-editor }
 544     { lose-focus unfocus-editor }
 545     { delete-action remove-selection }
 546     { select-all-action select-all }
 547     { T{ key-down f { C+ } "l" } select-line }
 548     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 549     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 550     { T{ key-down f { S+ C+ } "LEFT" } select-previous-word }
 551     { T{ key-down f { S+ C+ } "RIGHT" } select-next-word }
 552     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 553     { T{ key-down f { S+ } "END" } select-end-of-line }
 554     { T{ key-down f { S+ C+ } "HOME" } select-start-of-document }
 555     { T{ key-down f { S+ C+ } "END" } select-end-of-document }
 556 } define-command-map
 557
 558 : editor-menu ( editor -- )
 559     {
 560         com-undo
 561         com-redo
 562         ----
 563         com-cut
 564         com-copy
 565         com-paste
 566     } show-commands-menu ;
 567
 568 editor "misc" f {
 569     ! { T{ button-down f f 2 } paste-selection }
 570     { T{ button-down f f 3 } editor-menu }
 571 } define-command-map
 572
 573 ! Multi-line editors
 574 TUPLE: multiline-editor < editor ;
 575
 576 : <multiline-editor> ( -- editor )
 577     multiline-editor new-editor ;
 578
 579 : previous-line ( editor -- ) line-elt editor-prev ;
 580
 581 : next-line ( editor -- ) line-elt editor-next ;
 582
 583 <PRIVATE
 584
 585 : page-elt ( editor n -- editor element )
 586     over visible-lines 1 - min 1 max <page-elt> ;
 587
 588 : prev-page-elt ( editor -- editor element )
 589     dup editor-caret first page-elt ;
 590
 591 : next-page-elt ( editor -- editor element )
 592     dup [ control-value length 1 - ] [ editor-caret first ] bi - page-elt ;
 593
 594 PRIVATE>
 595
 596 : previous-page ( editor -- ) prev-page-elt editor-prev ;
 597
 598 : next-page ( editor -- ) next-page-elt editor-next ;
 599
 600 : select-previous-line ( editor -- ) line-elt editor-select-prev ;
 601
 602 : select-next-line ( editor -- ) line-elt editor-select-next ;
 603
 604 : select-previous-page ( editor -- ) prev-page-elt editor-select-prev ;
 605
 606 : select-next-page ( editor -- ) next-page-elt editor-select-next ;
 607
 608 : insert-newline ( editor -- )
 609     "\n" swap user-input* drop ;
 610
 611 : change-selection ( editor quot -- )
 612     '[ gadget-selection @ ] [ user-input* drop ] bi ; inline
 613
 614 <PRIVATE
 615
 616 : join-lines ( string -- string' )
 617     "\n" split
 618     [ rest-slice [ [ blank? ] trim-head-slice ] map! drop ]
 619     [ but-last-slice [ [ blank? ] trim-tail-slice ] map! drop ]
 620     [ " " join ]
 621     tri ;
 622
 623 : last-line? ( document line -- ? )
 624     [ last-line# ] dip = ;
 625
 626 : prev-line-and-this ( document line -- start end )
 627     swap [ drop 1 - 0 2array ] [ line-end ] 2bi ;
 628
 629 : join-with-prev ( document line -- )
 630     [ prev-line-and-this ] [ drop ] 2bi
 631     [ join-lines ] change-doc-range ;
 632
 633 : this-line-and-next ( document line -- start end )
 634     swap [ drop 0 2array ] [ [ 1 + ] dip line-end ] 2bi ;
 635
 636 : join-with-next ( document line -- )
 637     [ this-line-and-next ] [ drop ] 2bi
 638     [ join-lines ] change-doc-range ;
 639
 640 PRIVATE>
 641
 642 : com-join-lines ( editor -- )
 643     dup gadget-selection?
 644     [ [ join-lines ] change-selection ] [
 645         [ model>> ] [ editor-caret first ] bi {
 646             { [ over last-line# 0 = ] [ 2drop ] }
 647             { [ 2dup last-line? ] [ join-with-prev ] }
 648             [ join-with-next ]
 649         } cond
 650     ] if ;
 651
 652 multiline-editor "multiline" f {
 653     { T{ key-down f f "UP" } previous-line }
 654     { T{ key-down f f "DOWN" } next-line }
 655     { T{ key-down f { C+ } "p" } previous-line }
 656     { T{ key-down f { C+ } "n" } next-line }
 657     { T{ key-down f { S+ } "UP" } select-previous-line }
 658     { T{ key-down f { S+ } "DOWN" } select-next-line }
 659     { T{ key-down f f "PAGE_UP" } previous-page }
 660     { T{ key-down f f "PAGE_DOWN" } next-page }
 661     { T{ key-down f { S+ } "PAGE_UP" } select-previous-page }
 662     { T{ key-down f { S+ } "PAGE_DOWN" } select-next-page }
 663     { T{ key-down f f "RET" } insert-newline }
 664     { T{ key-down f { S+ } "RET" } insert-newline }
 665     { T{ key-down f f "ENTER" } insert-newline }
 666     { T{ key-down f { C+ } "j" } com-join-lines }
 667 } define-command-map
 668
 669 TUPLE: source-editor < multiline-editor ;
 670
 671 : <source-editor> ( -- editor )
 672     source-editor new-editor ;
 673
 674 ! A useful model
 675 : <element-model> ( editor element -- model )
 676     [ [ caret>> ] [ model>> ] bi ] dip
 677     '[ _ _ elt-string ] <arrow> ;
 678
 679 ! Fields wrap an editor
 680 TUPLE: field < border editor min-cols max-cols ;
 681
 682 <PRIVATE
 683
 684 : field-theme ( gadget -- gadget )
 685     { 2 2 } >>size
 686     { 1 0 } >>fill
 687     field-border-color <solid> >>boundary ; inline
 688
 689 : <field-border> ( gadget -- border )
 690     border new-border field-theme ;
 691
 692 PRIVATE>
 693
 694 : new-field ( class -- gadget )
 695     [ <editor> ] dip new-border
 696         dup gadget-child >>editor
 697         field-theme ; inline
 698
 699 ! For line-gadget-width
 700 M: field font>> editor>> font>> ;
 701
 702 M: field pref-dim*
 703     [ ]
 704     [ editor>> pref-dim ]
 705     [ [ line-gadget-width ] [ drop second ] 2bi 2array ]
 706     tri border-pref-dim ;
 707
 708 M: field default-text>> editor>> default-text>> ;
 709
 710 M: field default-text<< editor>> default-text<< ;
 711
 712 TUPLE: model-field < field field-model ;
 713
 714 : <model-field> ( model -- gadget )
 715     model-field new-field
 716         swap >>field-model ;
 717
 718 M: model-field graft*
 719     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 720     [ dup editor>> model>> add-connection ]
 721     bi ;
 722
 723 M: model-field ungraft*
 724     dup editor>> model>> remove-connection ;
 725
 726 M: model-field model-changed
 727     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;
 728
 729 TUPLE: action-field < field quot ;
 730
 731 : <action-field> ( quot: ( string -- ) -- gadget )
 732     action-field [ <editor> ] dip new-border
 733         dup gadget-child >>editor
 734         field-theme
 735         swap >>quot ;
 736
 737 : invoke-action-field ( field -- )
 738     [ editor>> editor-string ]
 739     [ editor>> clear-editor ]
 740     [ quot>> ]
 741     tri call( string -- ) ;
 742
 743 action-field H{
 744     { T{ key-down f f "RET" } [ invoke-action-field ] }
 745 } set-gestures