basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2011 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs calendar colors.constants combinators
   4 combinators.short-circuit documents documents.elements fonts fry
   5 grouping kernel locals make math math.functions math.order math.ranges
   6 math.rectangles math.vectors models models.arrow namespaces opengl
   7 sequences sorting splitting timers ui.baseline-alignment ui.clipboards
   8 ui.commands ui.gadgets ui.gadgets.borders ui.gadgets.line-support
   9 ui.gadgets.menus ui.gadgets.scrollers ui.gestures ui.pens.solid
  10 ui.render ui.text ui.theme unicode opengl.gl ;
  11 IN: ui.gadgets.editors
  12
  13 TUPLE: editor < line-gadget
  14     caret mark
  15     focused? blink blink-timer
  16     default-text
  17     preedit-start
  18     preedit-end
  19     preedit-selected-start
  20     preedit-selected-end
  21     preedit-selection-mode?
  22     preedit-underlines ;
  23
  24 M: editor preedit? preedit-start>> [ t ] [ f ] if ;
  25
  26 <PRIVATE
  27
  28 : <loc> ( -- loc ) { 0 0 } <model> ;
  29
  30 : init-editor-locs ( editor -- editor )
  31     <loc> >>caret
  32     <loc> >>mark ; inline
  33
  34 : editor-theme ( editor -- editor )
  35     monospace-font >>font ; inline
  36
  37 PRIVATE>
  38
  39 : new-editor ( class -- editor )
  40     new-line-gadget
  41         <document> >>model
  42         init-editor-locs
  43         editor-theme ; inline
  44
  45 : <editor> ( -- editor )
  46     editor new-editor ;
  47
  48 <PRIVATE
  49
  50 : activate-editor-model ( editor model -- )
  51     [ add-connection ]
  52     [ nip activate-model ]
  53     [ swap model>> add-loc ] 2tri ;
  54
  55 : deactivate-editor-model ( editor model -- )
  56     [ remove-connection ]
  57     [ nip deactivate-model ]
  58     [ swap model>> remove-loc ] 2tri ;
  59
  60 : blink-caret ( editor -- )
  61     [ not ] change-blink relayout-1 ;
  62
  63 SYMBOL: blink-interval
  64
  65 750 milliseconds blink-interval set-global
  66
  67 : stop-blinking ( editor -- )
  68     blink-timer>> [ stop-timer ] when* ;
  69
  70 : start-blinking ( editor -- )
  71     t >>blink
  72     blink-timer>> [ restart-timer ] when* ;
  73
  74 : restart-blinking ( editor -- )
  75     dup focused?>> [
  76         [ start-blinking ]
  77         [ relayout-1 ]
  78         bi
  79     ] [ drop ] if ;
  80
  81 PRIVATE>
  82
  83 M: editor graft*
  84     [ dup caret>> activate-editor-model ]
  85     [ dup mark>> activate-editor-model ]
  86     [
  87         [
  88             '[ _ blink-caret ] blink-interval get dup <timer>
  89         ] keep blink-timer<<
  90     ] tri ;
  91
  92 M: editor ungraft*
  93     [ [ stop-blinking ] [ f >>blink-timer drop ] bi ]
  94     [ dup caret>> deactivate-editor-model ]
  95     [ dup mark>> deactivate-editor-model ] tri ;
  96
  97 : editor-caret ( editor -- loc ) caret>> value>> ;
  98
  99 : editor-mark ( editor -- loc ) mark>> value>> ;
 100
 101 : set-caret ( loc editor -- )
 102     [ model>> validate-loc ] [ caret>> ] bi set-model ;
 103
 104 : set-mark ( loc editor -- )
 105     [ model>> validate-loc ] [ mark>> ] bi set-model ;
 106
 107 : change-caret ( editor quot: ( loc document -- newloc ) -- )
 108     [ [ [ editor-caret ] [ model>> ] bi ] dip call ] [ drop ] 2bi
 109     set-caret ; inline
 110
 111 : mark>caret ( editor -- )
 112     [ editor-caret ] [ mark>> ] bi set-model ;
 113
 114 : change-caret&mark ( editor quot: ( loc document -- newloc ) -- )
 115     [ change-caret ] [ drop mark>caret ] 2bi ; inline
 116
 117 : editor-line ( n editor -- str ) control-value nth ;
 118
 119 :: point>loc ( point editor -- loc )
 120     point second editor y>line {
 121         { [ dup 0 < ] [ drop { 0 0 } ] }
 122         { [ dup editor model>> last-line# > ] [ drop editor model>> doc-end ] }
 123         [| n |
 124             n
 125             point first
 126             editor font>>
 127             n editor editor-line
 128             x>offset 2array
 129         ]
 130     } cond ;
 131
 132 : clicked-loc ( editor -- loc )
 133     [ hand-rel ] keep point>loc ;
 134
 135 : click-loc ( editor model -- )
 136     [ clicked-loc ] dip set-model ;
 137
 138 : focus-editor ( editor -- )
 139     [ start-blinking ] [ t >>focused? relayout-1 ] bi ;
 140
 141 : unfocus-editor ( editor -- )
 142     [ stop-blinking ] [ f >>focused? relayout-1 ] bi ;
 143
 144 : loc>x ( loc editor -- x )
 145     [ first2 swap ] dip [ editor-line ] [ font>> ] bi swap offset>x round ;
 146
 147 : loc>point ( loc editor -- loc )
 148     [ loc>x ] [ [ first ] dip line>y ceiling ] 2bi 2array ;
 149
 150 : caret-loc ( editor -- loc )
 151     [ editor-caret ] keep loc>point ;
 152
 153 : caret-dim ( editor -- dim )
 154     [ 0 ] dip line-height 2array ;
 155
 156 : scroll>caret ( editor -- )
 157     dup graft-state>> second [
 158         [
 159             [ caret-loc ] [ caret-dim { 2 1 } v+ ] bi <rect>
 160         ] keep scroll>rect
 161     ] [ drop ] if ;
 162
 163 <PRIVATE
 164
 165 : draw-caret? ( editor -- ? )
 166     { [ focused?>> ] [ blink>> ]
 167       [ [ preedit? not ] [ preedit-selection-mode?>> not ] bi or ] } 1&& ;
 168
 169 : draw-caret ( editor -- )
 170     dup draw-caret? [
 171         [ editor-caret-color gl-color ] dip
 172         [ caret-loc ] [ caret-dim ] bi
 173         over v+ gl-line
 174     ] [ drop ] if ;
 175
 176 :: draw-preedit-underlines ( editor -- )
 177     editor [ preedit? ] [ preedit-underlines>> ] bi and [
 178         editor [ caret-loc second ] [ caret-dim second ] bi + 2.0 - :> y
 179         editor editor-caret first :> row
 180         editor font>> foreground>> gl-color
 181         editor preedit-underlines>> [
 182             GL_LINE_BIT [
 183                 dup second glLineWidth
 184                 first editor preedit-start>> second dup 2array v+ first2
 185                 [ row swap 2array editor loc>x 1.0 + y 2array ]
 186                 [ row swap 2array editor loc>x 1.0 - y 2array ]
 187                 bi*
 188                 gl-line
 189             ] do-attribs
 190         ] each
 191     ] when ;
 192
 193 : selection-start/end ( editor -- start end )
 194     [ editor-mark ] [ editor-caret ] bi sort-pair ;
 195
 196 SYMBOL: selected-lines
 197
 198 TUPLE: selected-line start end first? last? ;
 199
 200 : compute-selection ( editor -- assoc )
 201     dup gadget-selection? [
 202         [ selection-start/end [ [ first ] bi@ [a,b] ] [ ] 2bi ]
 203         [ model>> ] bi
 204         '[ [ _ _ ] [ _ start/end-on-line ] bi 2array ] H{ } map>assoc
 205     ] [ drop f ] if ;
 206
 207 :: draw-selection ( line pair editor -- )
 208     pair [ editor font>> line offset>x ] map :> pair
 209     editor selection-color>> gl-color
 210     pair first 0 2array
 211     pair second pair first - round 1 max editor line-height 2array
 212     gl-fill-rect ;
 213
 214 : draw-unselected-line ( line editor -- )
 215     font>> swap draw-text ;
 216
 217 : draw-selected-line ( line pair editor -- )
 218     over all-equal? [
 219         [ nip draw-unselected-line ] [ draw-selection ] 3bi
 220     ] [
 221         [ draw-selection ]
 222         [
 223             [ [ first2 ] [ selection-color>> ] bi* <selection> ]
 224             [ draw-unselected-line ] bi
 225         ] 3bi
 226     ] if ;
 227
 228 : draw-default-text? ( editor -- ? )
 229     { [ default-text>> ] [ model>> doc-string empty? ] } 1&& ;
 230
 231 : draw-default-text ( editor -- )
 232     [ font>> clone line-color >>foreground ]
 233     [ default-text>> ] bi draw-text ;
 234
 235 PRIVATE>
 236
 237 M: editor draw-line ( line index editor -- )
 238     [ selected-lines get at ] dip over
 239     [ draw-selected-line ] [ nip draw-unselected-line ] if ;
 240
 241 M: editor draw-gadget*
 242     dup draw-default-text? [
 243         [ draw-default-text ] [ draw-caret ] [ draw-preedit-underlines ] tri
 244     ] [
 245         dup compute-selection selected-lines [
 246             [ draw-lines ] [ draw-caret ] [ draw-preedit-underlines ] tri
 247         ] with-variable
 248     ] if ;
 249
 250 M: editor pref-dim*
 251     ! Add some space for the caret.
 252     [ font>> ] keep dup draw-default-text?
 253     [ default-text>> ] [ control-value ] if
 254     text-dim { 1 0 } v+ ;
 255
 256 M: editor baseline font>> font-metrics ascent>> ;
 257
 258 M: editor cap-height font>> font-metrics cap-height>> ;
 259
 260 <PRIVATE
 261
 262 : contents-changed ( model editor -- )
 263     [ [ nip caret>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 264     [ [ nip mark>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 265     [ nip relayout ] 2tri ;
 266
 267 : caret/mark-changed ( editor -- )
 268     [ restart-blinking ] keep scroll>caret ;
 269
 270 PRIVATE>
 271
 272 M: editor model-changed
 273     {
 274         { [ 2dup model>> eq? ] [ contents-changed ] }
 275         { [ 2dup caret>> eq? ] [ nip caret/mark-changed ] }
 276         { [ 2dup mark>> eq? ] [ nip caret/mark-changed ] }
 277     } cond ;
 278
 279 M: editor gadget-selection?
 280     selection-start/end = not ;
 281
 282 M: editor gadget-selection
 283     [ selection-start/end ] [ model>> ] bi doc-range ;
 284
 285 : remove-selection ( editor -- )
 286     [ selection-start/end ] [ model>> ] bi remove-doc-range ;
 287
 288 M: editor user-input*
 289     [ selection-start/end ] [ model>> ] bi set-doc-range t ;
 290
 291 M: editor temp-im-input
 292     [ selection-start/end ] [ model>> ] bi set-doc-range* t ;
 293
 294 : editor-string ( editor -- string )
 295     model>> doc-string ;
 296
 297 : set-editor-string ( string editor -- )
 298     model>> set-doc-string ;
 299
 300 M: editor gadget-text* editor-string % ;
 301
 302 : extend-selection ( editor -- )
 303     [ request-focus ]
 304     [ restart-blinking ]
 305     [ dup caret>> click-loc ] tri ;
 306
 307 : remove-preedit-text ( editor -- )
 308     { [ preedit-start>> ] [ set-caret ]
 309       [ preedit-end>> ] [ set-mark ]
 310       [ remove-selection ]
 311     } cleave ;
 312
 313 : remove-preedit-info ( editor -- )
 314     f >>preedit-start
 315     f >>preedit-end
 316     f >>preedit-selected-start
 317     f >>preedit-selected-end
 318     f >>preedit-selection-mode?
 319     f >>preedit-underlines
 320     drop ;
 321
 322 : mouse-elt ( -- element )
 323     hand-click# get {
 324         { 1 one-char-elt }
 325         { 2 one-word-elt }
 326     } at one-line-elt or ;
 327
 328 : drag-direction? ( loc editor -- ? )
 329     editor-mark before? ;
 330
 331 : drag-selection-caret ( loc editor element -- loc )
 332     [
 333         [ drag-direction? ] [ model>> ] 2bi
 334     ] dip prev/next-elt ? ;
 335
 336 : drag-selection-mark ( loc editor element -- loc )
 337     [
 338         [ drag-direction? not ]
 339         [ editor-mark ]
 340         [ model>> ] tri
 341     ] dip prev/next-elt ? ;
 342
 343 : drag-caret&mark ( editor -- caret mark )
 344     [ clicked-loc ] [ mouse-elt ] bi
 345     [ drag-selection-caret ]
 346     [ drag-selection-mark ] 3bi ;
 347
 348 : drag-selection ( editor -- )
 349     [ drag-caret&mark ]
 350     [ mark>> set-model ]
 351     [ caret>> set-model ] tri ;
 352
 353 : editor-cut ( editor clipboard -- )
 354     [ gadget-copy ] [ drop remove-selection ] 2bi ;
 355
 356 : delete/backspace ( editor quot -- )
 357     over gadget-selection? [
 358         drop remove-selection
 359     ] [
 360         [ [ [ editor-caret ] [ model>> ] bi ] dip call ]
 361         [ drop model>> ]
 362         2bi remove-doc-range
 363     ] if ; inline
 364
 365 : editor-delete ( editor elt -- )
 366     '[ dupd _ next-elt ] delete/backspace ;
 367
 368 : editor-backspace ( editor elt -- )
 369     '[ over [ _ prev-elt ] dip ] delete/backspace ;
 370
 371 : editor-select-prev ( editor elt -- )
 372     '[ _ prev-elt ] change-caret ;
 373
 374 : editor-prev ( editor elt -- )
 375     [ editor-select-prev ] [ drop mark>caret ] 2bi ;
 376
 377 : editor-select-next ( editor elt -- )
 378     '[ _ next-elt ] change-caret ;
 379
 380 : editor-next ( editor elt -- )
 381     dupd editor-select-next mark>caret ;
 382
 383 : editor-select ( from to editor -- )
 384     [ mark>> set-model ] [ caret>> set-model ] bi-curry bi* ;
 385
 386 : select-elt ( editor elt -- )
 387     [ [ [ editor-caret ] [ model>> ] bi ] dip prev/next-elt ] [ drop ] 2bi
 388     editor-select ;
 389
 390 : start-of-document ( editor -- ) doc-elt editor-prev ;
 391
 392 : end-of-document ( editor -- ) doc-elt editor-next ;
 393
 394 : position-caret ( editor -- )
 395     mouse-elt dup one-char-elt =
 396     [ drop dup extend-selection dup mark>> click-loc ]
 397     [ select-elt ] if ;
 398
 399 : delete-previous-character ( editor -- )
 400     char-elt editor-backspace ;
 401
 402 : delete-next-character ( editor -- )
 403     char-elt editor-delete ;
 404
 405 : delete-previous-word ( editor -- )
 406     word-elt editor-backspace ;
 407
 408 : delete-next-word ( editor -- )
 409     word-elt editor-delete ;
 410
 411 : delete-to-start-of-line ( editor -- )
 412     one-line-elt editor-backspace ;
 413
 414 : delete-to-end-of-line ( editor -- )
 415     one-line-elt editor-delete ;
 416
 417 : delete-to-start-of-document ( editor -- )
 418     doc-elt editor-delete ;
 419
 420 : delete-to-end-of-document ( editor -- )
 421     doc-elt editor-delete ;
 422
 423 : com-undo ( editor -- ) model>> undo ;
 424
 425 : com-redo ( editor -- ) model>> redo ;
 426
 427 editor "editing" f {
 428     { undo-action com-undo }
 429     { redo-action com-redo }
 430     { T{ key-down f f "DELETE" } delete-next-character }
 431     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 432     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 433     { T{ key-down f { C+ } "DELETE" } delete-next-word }
 434     { T{ key-down f { C+ } "BACKSPACE" } delete-previous-word }
 435     { T{ key-down f { A+ } "DELETE" } delete-to-end-of-line }
 436     { T{ key-down f { A+ } "BACKSPACE" } delete-to-start-of-line }
 437 } define-command-map
 438
 439 : com-paste ( editor -- ) clipboard get paste-clipboard ;
 440
 441 : paste-selection ( editor -- ) ui.clipboards:selection get paste-clipboard ;
 442
 443 : com-cut ( editor -- ) clipboard get editor-cut ;
 444
 445 editor "clipboard" f {
 446     { cut-action com-cut }
 447     { copy-action com-copy }
 448     { paste-action com-paste }
 449     { T{ button-up } com-copy-selection }
 450     { T{ button-up f f 2 } paste-selection }
 451 } define-command-map
 452
 453 : previous-character ( editor -- )
 454     dup gadget-selection? [
 455         dup selection-start/end drop
 456         over set-caret mark>caret
 457     ] [
 458         char-elt editor-prev
 459     ] if ;
 460
 461 : next-character ( editor -- )
 462     dup gadget-selection? [
 463         dup selection-start/end nip
 464         over set-caret mark>caret
 465     ] [
 466         char-elt editor-next
 467     ] if ;
 468
 469 : previous-word ( editor -- ) word-elt editor-prev ;
 470
 471 : next-word ( editor -- ) word-elt editor-next ;
 472
 473 : start-of-line ( editor -- ) one-line-elt editor-prev ;
 474
 475 : end-of-line ( editor -- ) one-line-elt editor-next ;
 476
 477 editor "caret-motion" f {
 478     { T{ button-down } position-caret }
 479     { T{ key-down f f "LEFT" } previous-character }
 480     { T{ key-down f f "RIGHT" } next-character }
 481     { T{ key-down f { C+ } "LEFT" } previous-word }
 482     { T{ key-down f { C+ } "RIGHT" } next-word }
 483     { T{ key-down f f "HOME" } start-of-line }
 484     { T{ key-down f f "END" } end-of-line }
 485     { T{ key-down f { C+ } "HOME" } start-of-document }
 486     { T{ key-down f { C+ } "END" } end-of-document }
 487 } define-command-map
 488
 489 : clear-editor ( editor -- )
 490     model>> clear-doc ;
 491
 492 : select-all ( editor -- ) doc-elt select-elt ;
 493
 494 : select-line ( editor -- ) one-line-elt select-elt ;
 495
 496 : select-word ( editor -- ) one-word-elt select-elt ;
 497
 498 : selected-token ( editor -- string )
 499     dup gadget-selection?
 500     [ dup select-word ] unless
 501     gadget-selection ;
 502
 503 : select-previous-character ( editor -- )
 504     char-elt editor-select-prev ;
 505
 506 : select-next-character ( editor -- )
 507     char-elt editor-select-next ;
 508
 509 : select-previous-word ( editor -- )
 510     word-elt editor-select-prev ;
 511
 512 : select-next-word ( editor -- )
 513     word-elt editor-select-next ;
 514
 515 : select-start-of-line ( editor -- )
 516     one-line-elt editor-select-prev ;
 517
 518 : select-end-of-line ( editor -- )
 519     one-line-elt editor-select-next ;
 520
 521 : select-start-of-document ( editor -- )
 522     doc-elt editor-select-prev ;
 523
 524 : select-end-of-document ( editor -- )
 525     doc-elt editor-select-next ;
 526
 527 editor "selection" f {
 528     { T{ button-down f { S+ } 1 } extend-selection }
 529     { T{ button-up f { S+ } 1 } com-copy-selection }
 530     { T{ drag { # 1 } } drag-selection }
 531     { gain-focus focus-editor }
 532     { lose-focus unfocus-editor }
 533     { delete-action remove-selection }
 534     { select-all-action select-all }
 535     { T{ key-down f { C+ } "l" } select-line }
 536     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 537     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 538     { T{ key-down f { S+ C+ } "LEFT" } select-previous-word }
 539     { T{ key-down f { S+ C+ } "RIGHT" } select-next-word }
 540     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 541     { T{ key-down f { S+ } "END" } select-end-of-line }
 542     { T{ key-down f { S+ C+ } "HOME" } select-start-of-document }
 543     { T{ key-down f { S+ C+ } "END" } select-end-of-document }
 544 } define-command-map
 545
 546 : editor-menu ( editor -- )
 547     {
 548         com-undo
 549         com-redo
 550         ----
 551         com-cut
 552         com-copy
 553         com-paste
 554     } show-commands-menu ;
 555
 556 editor "misc" f {
 557     ! { T{ button-down f f 2 } paste-selection }
 558     { T{ button-down f f 3 } editor-menu }
 559 } define-command-map
 560
 561 ! Multi-line editors
 562 TUPLE: multiline-editor < editor ;
 563
 564 : <multiline-editor> ( -- editor )
 565     multiline-editor new-editor ;
 566
 567 : previous-line ( editor -- ) line-elt editor-prev ;
 568
 569 : next-line ( editor -- ) line-elt editor-next ;
 570
 571 <PRIVATE
 572
 573 : page-elt ( editor -- editor element ) dup visible-lines 1 - <page-elt> ;
 574
 575 PRIVATE>
 576
 577 : previous-page ( editor -- ) page-elt editor-prev ;
 578
 579 : next-page ( editor -- ) page-elt editor-next ;
 580
 581 : select-previous-line ( editor -- ) line-elt editor-select-prev ;
 582
 583 : select-next-line ( editor -- ) line-elt editor-select-next ;
 584
 585 : select-previous-page ( editor -- ) page-elt editor-select-prev ;
 586
 587 : select-next-page ( editor -- ) page-elt editor-select-next ;
 588
 589 : insert-newline ( editor -- )
 590     "\n" swap user-input* drop ;
 591
 592 : change-selection ( editor quot -- )
 593     '[ gadget-selection @ ] [ user-input* drop ] bi ; inline
 594
 595 <PRIVATE
 596
 597 : join-lines ( string -- string' )
 598     "\n" split
 599     [ rest-slice [ [ blank? ] trim-head-slice ] map! drop ]
 600     [ but-last-slice [ [ blank? ] trim-tail-slice ] map! drop ]
 601     [ " " join ]
 602     tri ;
 603
 604 : last-line? ( document line -- ? )
 605     [ last-line# ] dip = ;
 606
 607 : prev-line-and-this ( document line -- start end )
 608     swap [ drop 1 - 0 2array ] [ line-end ] 2bi ;
 609
 610 : join-with-prev ( document line -- )
 611     [ prev-line-and-this ] [ drop ] 2bi
 612     [ join-lines ] change-doc-range ;
 613
 614 : this-line-and-next ( document line -- start end )
 615     swap [ drop 0 2array ] [ [ 1 + ] dip line-end ] 2bi ;
 616
 617 : join-with-next ( document line -- )
 618     [ this-line-and-next ] [ drop ] 2bi
 619     [ join-lines ] change-doc-range ;
 620
 621 PRIVATE>
 622
 623 : com-join-lines ( editor -- )
 624     dup gadget-selection?
 625     [ [ join-lines ] change-selection ] [
 626         [ model>> ] [ editor-caret first ] bi {
 627             { [ over last-line# 0 = ] [ 2drop ] }
 628             { [ 2dup last-line? ] [ join-with-prev ] }
 629             [ join-with-next ]
 630         } cond
 631     ] if ;
 632
 633 multiline-editor "multiline" f {
 634     { T{ key-down f f "UP" } previous-line }
 635     { T{ key-down f f "DOWN" } next-line }
 636     { T{ key-down f { S+ } "UP" } select-previous-line }
 637     { T{ key-down f { S+ } "DOWN" } select-next-line }
 638     { T{ key-down f f "PAGE_UP" } previous-page }
 639     { T{ key-down f f "PAGE_DOWN" } next-page }
 640     { T{ key-down f { S+ } "PAGE_UP" } select-previous-page }
 641     { T{ key-down f { S+ } "PAGE_DOWN" } select-next-page }
 642     { T{ key-down f f "RET" } insert-newline }
 643     { T{ key-down f { S+ } "RET" } insert-newline }
 644     { T{ key-down f f "ENTER" } insert-newline }
 645     { T{ key-down f { C+ } "j" } com-join-lines }
 646 } define-command-map
 647
 648 TUPLE: source-editor < multiline-editor ;
 649
 650 : <source-editor> ( -- editor )
 651     source-editor new-editor ;
 652
 653 ! A useful model
 654 : <element-model> ( editor element -- model )
 655     [ [ caret>> ] [ model>> ] bi ] dip
 656     '[ _ _ elt-string ] <arrow> ;
 657
 658 ! Fields wrap an editor
 659 TUPLE: field < border editor min-cols max-cols ;
 660
 661 <PRIVATE
 662
 663 : field-theme ( gadget -- gadget )
 664     { 2 2 } >>size
 665     { 1 0 } >>fill
 666     field-border-color <solid> >>boundary ; inline
 667
 668 : <field-border> ( gadget -- border )
 669     border new-border field-theme ;
 670
 671 PRIVATE>
 672
 673 : new-field ( class -- gadget )
 674     [ <editor> ] dip new-border
 675         dup gadget-child >>editor
 676         field-theme ; inline
 677
 678 ! For line-gadget-width
 679 M: field font>> editor>> font>> ;
 680
 681 M: field pref-dim*
 682     [ ]
 683     [ editor>> pref-dim ]
 684     [ [ line-gadget-width ] [ drop second ] 2bi 2array ]
 685     tri border-pref-dim ;
 686
 687 M: field default-text>> editor>> default-text>> ;
 688
 689 M: field default-text<< editor>> default-text<< ;
 690
 691 TUPLE: model-field < field field-model ;
 692
 693 : <model-field> ( model -- gadget )
 694     model-field new-field
 695         swap >>field-model ;
 696
 697 M: model-field graft*
 698     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 699     [ dup editor>> model>> add-connection ]
 700     bi ;
 701
 702 M: model-field ungraft*
 703     dup editor>> model>> remove-connection ;
 704
 705 M: model-field model-changed
 706     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;
 707
 708 TUPLE: action-field < field quot ;
 709
 710 : <action-field> ( quot: ( string -- ) -- gadget )
 711     action-field [ <editor> ] dip new-border
 712         dup gadget-child >>editor
 713         field-theme
 714         swap >>quot ;
 715
 716 : invoke-action-field ( field -- )
 717     [ editor>> editor-string ]
 718     [ editor>> clear-editor ]
 719     [ quot>> ]
 720     tri call( string -- ) ;
 721
 722 action-field H{
 723     { T{ key-down f f "RET" } [ invoke-action-field ] }
 724 } set-gestures