basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2011 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs calendar colors.constants combinators
   4 combinators.short-circuit documents documents.elements fonts fry
   5 grouping kernel locals make math math.functions math.order math.ranges
   6 math.rectangles math.vectors models models.arrow namespaces opengl
   7 sequences sorting splitting timers ui.baseline-alignment ui.clipboards
   8 ui.commands ui.gadgets ui.gadgets.borders ui.gadgets.line-support
   9 ui.gadgets.menus ui.gadgets.scrollers ui.gestures ui.pens.solid
  10 ui.render ui.text ui.theme unicode opengl.gl ;
  11 IN: ui.gadgets.editors
  12
  13 TUPLE: editor < line-gadget
  14     caret mark
  15     focused? blink blink-timer
  16     default-text
  17     preedit-start
  18     preedit-end
  19     preedit-selected-start
  20     preedit-selected-end
  21     preedit-selection-mode?
  22     preedit-underlines ;
  23
  24 M: editor preedit? preedit-start>> ;
  25
  26 <PRIVATE
  27
  28 : <loc> ( -- loc ) { 0 0 } <model> ;
  29
  30 : init-editor-locs ( editor -- editor )
  31     <loc> >>caret
  32     <loc> >>mark ; inline
  33
  34 : editor-theme ( editor -- editor )
  35     monospace-font >>font ; inline
  36
  37 PRIVATE>
  38
  39 : new-editor ( class -- editor )
  40     new-line-gadget
  41         <document> >>model
  42         init-editor-locs
  43         editor-theme ; inline
  44
  45 : <editor> ( -- editor )
  46     editor new-editor ;
  47
  48 <PRIVATE
  49
  50 : activate-editor-model ( editor model -- )
  51     [ add-connection ]
  52     [ nip activate-model ]
  53     [ swap model>> add-loc ] 2tri ;
  54
  55 : deactivate-editor-model ( editor model -- )
  56     [ remove-connection ]
  57     [ nip deactivate-model ]
  58     [ swap model>> remove-loc ] 2tri ;
  59
  60 : blink-caret ( editor -- )
  61     [ not ] change-blink relayout-1 ;
  62
  63 SYMBOL: blink-interval
  64
  65 750 milliseconds blink-interval set-global
  66
  67 : stop-blinking ( editor -- )
  68     blink-timer>> [ stop-timer ] when* ;
  69
  70 : start-blinking ( editor -- )
  71     t >>blink
  72     blink-timer>> [ restart-timer ] when* ;
  73
  74 : restart-blinking ( editor -- )
  75     dup focused?>> [
  76         [ start-blinking ]
  77         [ relayout-1 ]
  78         bi
  79     ] [ drop ] if ;
  80
  81 PRIVATE>
  82
  83 M: editor graft*
  84     [ dup caret>> activate-editor-model ]
  85     [ dup mark>> activate-editor-model ]
  86     [
  87         [
  88             '[ _ blink-caret ] blink-interval get dup <timer>
  89         ] keep blink-timer<<
  90     ] tri ;
  91
  92 M: editor ungraft*
  93     [ [ stop-blinking ] [ f >>blink-timer drop ] bi ]
  94     [ dup caret>> deactivate-editor-model ]
  95     [ dup mark>> deactivate-editor-model ] tri ;
  96
  97 : editor-caret ( editor -- loc ) caret>> value>> ;
  98
  99 : editor-mark ( editor -- loc ) mark>> value>> ;
 100
 101 : set-caret ( loc editor -- )
 102     [ model>> validate-loc ] [ caret>> ] bi set-model ;
 103
 104 : set-mark ( loc editor -- )
 105     [ model>> validate-loc ] [ mark>> ] bi set-model ;
 106
 107 : change-caret ( editor quot: ( loc document -- newloc ) -- )
 108     [ [ [ editor-caret ] [ model>> ] bi ] dip call ] [ drop ] 2bi
 109     set-caret ; inline
 110
 111 : mark>caret ( editor -- )
 112     [ editor-caret ] [ mark>> ] bi set-model ;
 113
 114 : change-caret&mark ( editor quot: ( loc document -- newloc ) -- )
 115     [ change-caret ] [ drop mark>caret ] 2bi ; inline
 116
 117 : editor-line ( n editor -- str ) control-value nth ;
 118
 119 :: point>loc ( point editor -- loc )
 120     point second editor y>line {
 121         { [ dup 0 < ] [ drop { 0 0 } ] }
 122         { [ dup editor model>> last-line# > ] [ drop editor model>> doc-end ] }
 123         [| n |
 124             n
 125             point first
 126             editor font>>
 127             n editor editor-line
 128             x>offset 2array
 129         ]
 130     } cond ;
 131
 132 : clicked-loc ( editor -- loc )
 133     [ hand-rel ] keep point>loc ;
 134
 135 : click-loc ( editor model -- )
 136     [ clicked-loc ] dip set-model ;
 137
 138 : focus-editor ( editor -- )
 139     [ start-blinking ] [ t >>focused? relayout-1 ] bi ;
 140
 141 : unfocus-editor ( editor -- )
 142     [ stop-blinking ] [ f >>focused? relayout-1 ] bi ;
 143
 144 : loc>x ( loc editor -- x )
 145     [ first2 swap ] dip [ editor-line ] [ font>> ] bi swap offset>x round ;
 146
 147 : loc>point ( loc editor -- loc )
 148     [ loc>x ] [ [ first ] dip line>y ceiling ] 2bi 2array ;
 149
 150 : caret-loc ( editor -- loc )
 151     [ editor-caret ] keep loc>point ;
 152
 153 : caret-dim ( editor -- dim )
 154     [ 0 ] dip line-height 2array ;
 155
 156 : scroll>caret ( editor -- )
 157     dup graft-state>> second [
 158         [
 159             [ caret-loc ] [ caret-dim { 2 1 } v+ ] bi <rect>
 160         ] keep scroll>rect
 161     ] [ drop ] if ;
 162
 163 <PRIVATE
 164
 165 : draw-caret? ( editor -- ? )
 166     { [ focused?>> ] [ blink>> ]
 167       [ [ preedit? not ] [ preedit-selection-mode?>> not ] bi or ] } 1&& ;
 168
 169 : draw-caret ( editor -- )
 170     dup draw-caret? [
 171         [ editor-caret-color gl-color ] dip
 172         [ caret-loc ] [ caret-dim ] bi
 173         over v+ gl-line
 174     ] [ drop ] if ;
 175
 176 :: draw-preedit-underlines ( editor -- )
 177     editor [ preedit? ] [ preedit-underlines>> ] bi and [
 178         editor [ caret-loc second ] [ caret-dim second ] bi + 2.0 - :> y
 179         editor editor-caret first :> row
 180         editor font>> foreground>> gl-color
 181         editor preedit-underlines>> [
 182             GL_LINE_BIT [
 183                 dup second glLineWidth
 184                 first editor preedit-start>> second dup 2array v+ first2
 185                 [ row swap 2array editor loc>x 1.0 + y 2array ]
 186                 [ row swap 2array editor loc>x 1.0 - y 2array ]
 187                 bi*
 188                 gl-line
 189             ] do-attribs
 190         ] each
 191     ] when ;
 192
 193 : selection-start/end ( editor -- start end )
 194     [ editor-mark ] [ editor-caret ] bi sort-pair ;
 195
 196 SYMBOL: selected-lines
 197
 198 TUPLE: selected-line start end first? last? ;
 199
 200 : compute-selection ( editor -- assoc )
 201     dup gadget-selection? [
 202         [ selection-start/end [ [ first ] bi@ [a,b] ] [ ] 2bi ]
 203         [ model>> ] bi
 204         '[ [ _ _ ] [ _ start/end-on-line ] bi 2array ] H{ } map>assoc
 205     ] [ drop f ] if ;
 206
 207 :: draw-selection ( line pair editor -- )
 208     pair [ editor font>> line offset>x ] map :> pair
 209     editor selection-color>> gl-color
 210     pair first 0 2array
 211     pair second pair first - round 1 max editor line-height 2array
 212     gl-fill-rect ;
 213
 214 : draw-unselected-line ( line editor -- )
 215     font>> swap draw-text ;
 216
 217 : draw-selected-line ( line pair editor -- )
 218     over all-equal? [
 219         [ nip draw-unselected-line ] [ draw-selection ] 3bi
 220     ] [
 221         [ draw-selection ]
 222         [
 223             [ [ first2 ] [ selection-color>> ] bi* <selection> ]
 224             [ draw-unselected-line ] bi
 225         ] 3bi
 226     ] if ;
 227
 228 : draw-default-text? ( editor -- ? )
 229     { [ default-text>> ] [ model>> doc-string empty? ] } 1&& ;
 230
 231 : draw-default-text ( editor -- )
 232     [ font>> clone line-color >>foreground ]
 233     [ default-text>> ] bi draw-text ;
 234
 235 PRIVATE>
 236
 237 M: editor draw-line
 238     [ selected-lines get at ] dip over
 239     [ draw-selected-line ] [ nip draw-unselected-line ] if ;
 240
 241 M: editor draw-gadget*
 242     dup draw-default-text? [
 243         [ draw-default-text ] [ draw-caret ] [ draw-preedit-underlines ] tri
 244     ] [
 245         dup compute-selection selected-lines [
 246             [ draw-lines ] [ draw-caret ] [ draw-preedit-underlines ] tri
 247         ] with-variable
 248     ] if ;
 249
 250 M: editor pref-dim*
 251     [ call-next-method ] keep ! at least as big as our min-rows/min-cols
 252     ! Add some space for the caret.
 253     [ font>> ] keep dup draw-default-text?
 254     [ default-text>> ] [ control-value ] if
 255     text-dim { 1 0 } v+ vmax ;
 256
 257 M: editor baseline font>> font-metrics ascent>> ;
 258
 259 M: editor cap-height font>> font-metrics cap-height>> ;
 260
 261 <PRIVATE
 262
 263 : contents-changed ( model editor -- )
 264     [ [ nip caret>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 265     [ [ nip mark>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 266     [ nip relayout ] 2tri ;
 267
 268 : caret/mark-changed ( editor -- )
 269     [ restart-blinking ] keep scroll>caret ;
 270
 271 PRIVATE>
 272
 273 M: editor model-changed
 274     {
 275         { [ 2dup model>> eq? ] [ contents-changed ] }
 276         { [ 2dup caret>> eq? ] [ nip caret/mark-changed ] }
 277         { [ 2dup mark>> eq? ] [ nip caret/mark-changed ] }
 278     } cond ;
 279
 280 M: editor gadget-selection?
 281     selection-start/end = not ;
 282
 283 M: editor gadget-selection
 284     [ selection-start/end ] [ model>> ] bi doc-range ;
 285
 286 : remove-selection ( editor -- )
 287     [ selection-start/end ] [ model>> ] bi remove-doc-range ;
 288
 289 M: editor user-input*
 290     [ selection-start/end ] [ model>> ] bi set-doc-range t ;
 291
 292 M: editor temp-im-input
 293     [ selection-start/end ] [ model>> ] bi set-doc-range* t ;
 294
 295 : editor-string ( editor -- string )
 296     model>> doc-string ;
 297
 298 : set-editor-string ( string editor -- )
 299     model>> set-doc-string ;
 300
 301 M: editor gadget-text* editor-string % ;
 302
 303 : extend-selection ( editor -- )
 304     [ request-focus ]
 305     [ restart-blinking ]
 306     [ dup caret>> click-loc ] tri ;
 307
 308 : remove-preedit-text ( editor -- )
 309     { [ preedit-start>> ] [ set-caret ]
 310       [ preedit-end>> ] [ set-mark ]
 311       [ remove-selection ]
 312     } cleave ;
 313
 314 : remove-preedit-info ( editor -- )
 315     f >>preedit-start
 316     f >>preedit-end
 317     f >>preedit-selected-start
 318     f >>preedit-selected-end
 319     f >>preedit-selection-mode?
 320     f >>preedit-underlines
 321     drop ;
 322
 323 : mouse-elt ( -- element )
 324     hand-click# get {
 325         { 1 one-char-elt }
 326         { 2 one-word-elt }
 327     } at one-line-elt or ;
 328
 329 : drag-direction? ( loc editor -- ? )
 330     editor-mark before? ;
 331
 332 : drag-selection-caret ( loc editor element -- loc )
 333     [
 334         [ drag-direction? ] [ model>> ] 2bi
 335     ] dip prev/next-elt ? ;
 336
 337 : drag-selection-mark ( loc editor element -- loc )
 338     [
 339         [ drag-direction? not ]
 340         [ editor-mark ]
 341         [ model>> ] tri
 342     ] dip prev/next-elt ? ;
 343
 344 : drag-caret&mark ( editor -- caret mark )
 345     [ clicked-loc ] [ mouse-elt ] bi
 346     [ drag-selection-caret ]
 347     [ drag-selection-mark ] 3bi ;
 348
 349 : drag-selection ( editor -- )
 350     [ drag-caret&mark ]
 351     [ mark>> set-model ]
 352     [ caret>> set-model ] tri ;
 353
 354 : editor-cut ( editor clipboard -- )
 355     [ gadget-copy ] [ drop remove-selection ] 2bi ;
 356
 357 : delete/backspace ( editor quot -- )
 358     over gadget-selection? [
 359         drop remove-selection
 360     ] [
 361         [ [ [ editor-caret ] [ model>> ] bi ] dip call ]
 362         [ drop model>> ]
 363         2bi remove-doc-range
 364     ] if ; inline
 365
 366 : editor-delete ( editor elt -- )
 367     '[ dupd _ next-elt ] delete/backspace ;
 368
 369 : editor-backspace ( editor elt -- )
 370     '[ over [ _ prev-elt ] dip ] delete/backspace ;
 371
 372 : editor-select-prev ( editor elt -- )
 373     '[ _ prev-elt ] change-caret ;
 374
 375 : editor-prev ( editor elt -- )
 376     [ editor-select-prev ] [ drop mark>caret ] 2bi ;
 377
 378 : editor-select-next ( editor elt -- )
 379     '[ _ next-elt ] change-caret ;
 380
 381 : editor-next ( editor elt -- )
 382     dupd editor-select-next mark>caret ;
 383
 384 : editor-select ( from to editor -- )
 385     [ mark>> set-model ] [ caret>> set-model ] bi-curry bi* ;
 386
 387 : select-elt ( editor elt -- )
 388     [ [ [ editor-caret ] [ model>> ] bi ] dip prev/next-elt ] [ drop ] 2bi
 389     editor-select ;
 390
 391 : start-of-document ( editor -- ) doc-elt editor-prev ;
 392
 393 : end-of-document ( editor -- ) doc-elt editor-next ;
 394
 395 : position-caret ( editor -- )
 396     mouse-elt dup one-char-elt =
 397     [ drop dup extend-selection dup mark>> click-loc ]
 398     [ select-elt ] if ;
 399
 400 : delete-previous-character ( editor -- )
 401     char-elt editor-backspace ;
 402
 403 : delete-next-character ( editor -- )
 404     char-elt editor-delete ;
 405
 406 : delete-previous-word ( editor -- )
 407     word-elt editor-backspace ;
 408
 409 : delete-next-word ( editor -- )
 410     word-elt editor-delete ;
 411
 412 : delete-to-start-of-line ( editor -- )
 413     one-line-elt editor-backspace ;
 414
 415 : delete-to-end-of-line ( editor -- )
 416     one-line-elt editor-delete ;
 417
 418 : delete-to-start-of-document ( editor -- )
 419     doc-elt editor-delete ;
 420
 421 : delete-to-end-of-document ( editor -- )
 422     doc-elt editor-delete ;
 423
 424 : com-undo ( editor -- ) model>> undo ;
 425
 426 : com-redo ( editor -- ) model>> redo ;
 427
 428 editor "editing" f {
 429     { undo-action com-undo }
 430     { redo-action com-redo }
 431     { T{ key-down f f "DELETE" } delete-next-character }
 432     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 433     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 434     { T{ key-down f { C+ } "DELETE" } delete-next-word }
 435     { T{ key-down f { C+ } "BACKSPACE" } delete-previous-word }
 436     { T{ key-down f { A+ } "DELETE" } delete-to-end-of-line }
 437     { T{ key-down f { A+ } "BACKSPACE" } delete-to-start-of-line }
 438     { T{ key-down f { C+ } "d" } delete-next-character }
 439     { T{ key-down f { C+ } "h" } delete-previous-character }
 440     { T{ key-down f { C+ } "u" } delete-to-start-of-line }
 441     { T{ key-down f { C+ } "k" } delete-to-end-of-line }
 442     { T{ key-down f { C+ } "w" } delete-previous-word }
 443 } define-command-map
 444
 445 : com-paste ( editor -- ) clipboard get paste-clipboard ;
 446
 447 : paste-selection ( editor -- ) ui.clipboards:selection get paste-clipboard ;
 448
 449 : com-cut ( editor -- ) clipboard get editor-cut ;
 450
 451 editor "clipboard" f {
 452     { cut-action com-cut }
 453     { copy-action com-copy }
 454     { paste-action com-paste }
 455     { T{ button-up } com-copy-selection }
 456     { T{ button-up f f 2 } paste-selection }
 457 } define-command-map
 458
 459 : previous-character ( editor -- )
 460     dup gadget-selection? [
 461         dup selection-start/end drop
 462         over set-caret mark>caret
 463     ] [
 464         char-elt editor-prev
 465     ] if ;
 466
 467 : next-character ( editor -- )
 468     dup gadget-selection? [
 469         dup selection-start/end nip
 470         over set-caret mark>caret
 471     ] [
 472         char-elt editor-next
 473     ] if ;
 474
 475 : previous-word ( editor -- ) word-elt editor-prev ;
 476
 477 : next-word ( editor -- ) word-elt editor-next ;
 478
 479 : start-of-line ( editor -- ) one-line-elt editor-prev ;
 480
 481 : end-of-line ( editor -- ) one-line-elt editor-next ;
 482
 483 editor "caret-motion" f {
 484     { T{ button-down } position-caret }
 485     { T{ key-down f f "LEFT" } previous-character }
 486     { T{ key-down f f "RIGHT" } next-character }
 487     { T{ key-down f { C+ } "LEFT" } previous-word }
 488     { T{ key-down f { C+ } "RIGHT" } next-word }
 489     { T{ key-down f f "HOME" } start-of-line }
 490     { T{ key-down f f "END" } end-of-line }
 491     { T{ key-down f { C+ } "HOME" } start-of-document }
 492     { T{ key-down f { C+ } "END" } end-of-document }
 493     { T{ key-down f { C+ } "b" } previous-character }
 494     { T{ key-down f { C+ } "f" } next-character }
 495     { T{ key-down f { C+ } "a" } start-of-line }
 496     { T{ key-down f { C+ } "e" } end-of-line }
 497 } define-command-map
 498
 499 : clear-editor ( editor -- )
 500     model>> clear-doc ;
 501
 502 : select-all ( editor -- ) doc-elt select-elt ;
 503
 504 : select-line ( editor -- ) one-line-elt select-elt ;
 505
 506 : select-word ( editor -- ) one-word-elt select-elt ;
 507
 508 : selected-token ( editor -- string )
 509     dup gadget-selection?
 510     [ dup select-word ] unless
 511     gadget-selection ;
 512
 513 : select-previous-character ( editor -- )
 514     char-elt editor-select-prev ;
 515
 516 : select-next-character ( editor -- )
 517     char-elt editor-select-next ;
 518
 519 : select-previous-word ( editor -- )
 520     word-elt editor-select-prev ;
 521
 522 : select-next-word ( editor -- )
 523     word-elt editor-select-next ;
 524
 525 : select-start-of-line ( editor -- )
 526     one-line-elt editor-select-prev ;
 527
 528 : select-end-of-line ( editor -- )
 529     one-line-elt editor-select-next ;
 530
 531 : select-start-of-document ( editor -- )
 532     doc-elt editor-select-prev ;
 533
 534 : select-end-of-document ( editor -- )
 535     doc-elt editor-select-next ;
 536
 537 editor "selection" f {
 538     { T{ button-down f { S+ } 1 } extend-selection }
 539     { T{ button-up f { S+ } 1 } com-copy-selection }
 540     { T{ drag { # 1 } } drag-selection }
 541     { gain-focus focus-editor }
 542     { lose-focus unfocus-editor }
 543     { delete-action remove-selection }
 544     { select-all-action select-all }
 545     { T{ key-down f { C+ } "l" } select-line }
 546     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 547     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 548     { T{ key-down f { S+ C+ } "LEFT" } select-previous-word }
 549     { T{ key-down f { S+ C+ } "RIGHT" } select-next-word }
 550     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 551     { T{ key-down f { S+ } "END" } select-end-of-line }
 552     { T{ key-down f { S+ C+ } "HOME" } select-start-of-document }
 553     { T{ key-down f { S+ C+ } "END" } select-end-of-document }
 554 } define-command-map
 555
 556 : editor-menu ( editor -- )
 557     {
 558         com-undo
 559         com-redo
 560         ----
 561         com-cut
 562         com-copy
 563         com-paste
 564     } show-commands-menu ;
 565
 566 editor "misc" f {
 567     ! { T{ button-down f f 2 } paste-selection }
 568     { T{ button-down f f 3 } editor-menu }
 569 } define-command-map
 570
 571 ! Multi-line editors
 572 TUPLE: multiline-editor < editor ;
 573
 574 : <multiline-editor> ( -- editor )
 575     multiline-editor new-editor ;
 576
 577 : previous-line ( editor -- ) line-elt editor-prev ;
 578
 579 : next-line ( editor -- ) line-elt editor-next ;
 580
 581 <PRIVATE
 582
 583 : page-elt ( editor n -- editor element )
 584     over visible-lines 1 - min 1 max <page-elt> ;
 585
 586 : prev-page-elt ( editor -- editor element )
 587     dup editor-caret first page-elt ;
 588
 589 : next-page-elt ( editor -- editor element )
 590     dup [ control-value length 1 - ] [ editor-caret first ] bi - page-elt ;
 591
 592 PRIVATE>
 593
 594 : previous-page ( editor -- ) prev-page-elt editor-prev ;
 595
 596 : next-page ( editor -- ) next-page-elt editor-next ;
 597
 598 : select-previous-line ( editor -- ) line-elt editor-select-prev ;
 599
 600 : select-next-line ( editor -- ) line-elt editor-select-next ;
 601
 602 : select-previous-page ( editor -- ) prev-page-elt editor-select-prev ;
 603
 604 : select-next-page ( editor -- ) next-page-elt editor-select-next ;
 605
 606 : insert-newline ( editor -- )
 607     "\n" swap user-input* drop ;
 608
 609 : change-selection ( editor quot -- )
 610     '[ gadget-selection @ ] [ user-input* drop ] bi ; inline
 611
 612 <PRIVATE
 613
 614 : join-lines ( string -- string' )
 615     "\n" split
 616     [ rest-slice [ [ blank? ] trim-head-slice ] map! drop ]
 617     [ but-last-slice [ [ blank? ] trim-tail-slice ] map! drop ]
 618     [ " " join ]
 619     tri ;
 620
 621 : last-line? ( document line -- ? )
 622     [ last-line# ] dip = ;
 623
 624 : prev-line-and-this ( document line -- start end )
 625     swap [ drop 1 - 0 2array ] [ line-end ] 2bi ;
 626
 627 : join-with-prev ( document line -- )
 628     [ prev-line-and-this ] [ drop ] 2bi
 629     [ join-lines ] change-doc-range ;
 630
 631 : this-line-and-next ( document line -- start end )
 632     swap [ drop 0 2array ] [ [ 1 + ] dip line-end ] 2bi ;
 633
 634 : join-with-next ( document line -- )
 635     [ this-line-and-next ] [ drop ] 2bi
 636     [ join-lines ] change-doc-range ;
 637
 638 PRIVATE>
 639
 640 : com-join-lines ( editor -- )
 641     dup gadget-selection?
 642     [ [ join-lines ] change-selection ] [
 643         [ model>> ] [ editor-caret first ] bi {
 644             { [ over last-line# 0 = ] [ 2drop ] }
 645             { [ 2dup last-line? ] [ join-with-prev ] }
 646             [ join-with-next ]
 647         } cond
 648     ] if ;
 649
 650 multiline-editor "multiline" f {
 651     { T{ key-down f f "UP" } previous-line }
 652     { T{ key-down f f "DOWN" } next-line }
 653     { T{ key-down f { S+ } "UP" } select-previous-line }
 654     { T{ key-down f { S+ } "DOWN" } select-next-line }
 655     { T{ key-down f f "PAGE_UP" } previous-page }
 656     { T{ key-down f f "PAGE_DOWN" } next-page }
 657     { T{ key-down f { S+ } "PAGE_UP" } select-previous-page }
 658     { T{ key-down f { S+ } "PAGE_DOWN" } select-next-page }
 659     { T{ key-down f f "RET" } insert-newline }
 660     { T{ key-down f { S+ } "RET" } insert-newline }
 661     { T{ key-down f f "ENTER" } insert-newline }
 662     { T{ key-down f { C+ } "j" } com-join-lines }
 663     { T{ key-down f { C+ } "p" } previous-line }
 664     { T{ key-down f { C+ } "n" } next-line }
 665 } define-command-map
 666
 667 TUPLE: source-editor < multiline-editor ;
 668
 669 : <source-editor> ( -- editor )
 670     source-editor new-editor ;
 671
 672 ! A useful model
 673 : <element-model> ( editor element -- model )
 674     [ [ caret>> ] [ model>> ] bi ] dip
 675     '[ _ _ elt-string ] <arrow> ;
 676
 677 ! Fields wrap an editor
 678 TUPLE: field < border editor min-cols max-cols ;
 679
 680 <PRIVATE
 681
 682 : field-theme ( gadget -- gadget )
 683     { 2 2 } >>size
 684     { 1 0 } >>fill
 685     field-border-color <solid> >>boundary ; inline
 686
 687 : <field-border> ( gadget -- border )
 688     border new-border field-theme ;
 689
 690 PRIVATE>
 691
 692 : new-field ( class -- gadget )
 693     [ <editor> ] dip new-border
 694         dup gadget-child >>editor
 695         field-theme ; inline
 696
 697 ! For line-gadget-width
 698 M: field font>> editor>> font>> ;
 699
 700 M: field pref-dim*
 701     [ ]
 702     [ editor>> pref-dim ]
 703     [ [ line-gadget-width ] [ drop second ] 2bi 2array ]
 704     tri border-pref-dim ;
 705
 706 M: field default-text>> editor>> default-text>> ;
 707
 708 M: field default-text<< editor>> default-text<< ;
 709
 710 TUPLE: model-field < field field-model ;
 711
 712 : <model-field> ( model -- gadget )
 713     model-field new-field
 714         swap >>field-model ;
 715
 716 M: model-field graft*
 717     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 718     [ dup editor>> model>> add-connection ]
 719     bi ;
 720
 721 M: model-field ungraft*
 722     dup editor>> model>> remove-connection ;
 723
 724 M: model-field model-changed
 725     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;
 726
 727 TUPLE: action-field < field quot ;
 728
 729 : <action-field> ( quot: ( string -- ) -- gadget )
 730     action-field [ <editor> ] dip new-border
 731         dup gadget-child >>editor
 732         field-theme
 733         swap >>quot ;
 734
 735 : invoke-action-field ( field -- )
 736     [ editor>> editor-string ]
 737     [ editor>> clear-editor ]
 738     [ quot>> ]
 739     tri call( string -- ) ;
 740
 741 action-field H{
 742     { T{ key-down f f "RET" } [ invoke-action-field ] }
 743 } set-gestures