basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2011 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs calendar colors.constants
   4 combinators combinators.short-circuit documents
   5 documents.elements fonts fry grouping kernel literals locals
   6 make math math.functions math.order math.ranges math.rectangles
   7 math.vectors models models.arrow namespaces opengl opengl.gl
   8 sequences sorting splitting system timers ui.baseline-alignment
   9 ui.clipboards ui.commands ui.gadgets ui.gadgets.borders
  10 ui.gadgets.line-support ui.gadgets.menus ui.gadgets.scrollers
  11 ui.gestures ui.pens.solid ui.render ui.text ui.theme unicode ;
  12 IN: ui.gadgets.editors
  13
  14 TUPLE: editor < line-gadget
  15     caret mark
  16     focused? blink blink-timer
  17     default-text
  18     preedit-start
  19     preedit-end
  20     preedit-selected-start
  21     preedit-selected-end
  22     preedit-selection-mode?
  23     preedit-underlines ;
  24
  25 M: editor preedit? preedit-start>> ;
  26
  27 <PRIVATE
  28
  29 : <loc> ( -- loc ) { 0 0 } <model> ;
  30
  31 : init-editor-locs ( editor -- editor )
  32     <loc> >>caret
  33     <loc> >>mark ; inline
  34
  35 : editor-theme ( editor -- editor )
  36     monospace-font >>font ; inline
  37
  38 PRIVATE>
  39
  40 : new-editor ( class -- editor )
  41     new-line-gadget
  42         <document> >>model
  43         init-editor-locs
  44         editor-theme ; inline
  45
  46 : <editor> ( -- editor )
  47     editor new-editor ;
  48
  49 <PRIVATE
  50
  51 : activate-editor-model ( editor model -- )
  52     [ add-connection ]
  53     [ nip activate-model ]
  54     [ swap model>> add-loc ] 2tri ;
  55
  56 : deactivate-editor-model ( editor model -- )
  57     [ remove-connection ]
  58     [ nip deactivate-model ]
  59     [ swap model>> remove-loc ] 2tri ;
  60
  61 : blink-caret ( editor -- )
  62     [ not ] change-blink relayout-1 ;
  63
  64 SYMBOL: blink-interval
  65
  66 750 milliseconds blink-interval set-global
  67
  68 : stop-blinking ( editor -- )
  69     blink-timer>> [ stop-timer ] when* ;
  70
  71 : start-blinking ( editor -- )
  72     t >>blink
  73     blink-timer>> [ restart-timer ] when* ;
  74
  75 : restart-blinking ( editor -- )
  76     dup focused?>> [
  77         [ start-blinking ]
  78         [ relayout-1 ]
  79         bi
  80     ] [ drop ] if ;
  81
  82 PRIVATE>
  83
  84 M: editor graft*
  85     [ dup caret>> activate-editor-model ]
  86     [ dup mark>> activate-editor-model ]
  87     [
  88         [
  89             '[ _ blink-caret ] blink-interval get dup <timer>
  90         ] keep blink-timer<<
  91     ] tri ;
  92
  93 M: editor ungraft*
  94     [ [ stop-blinking ] [ f >>blink-timer drop ] bi ]
  95     [ dup caret>> deactivate-editor-model ]
  96     [ dup mark>> deactivate-editor-model ] tri ;
  97
  98 : editor-caret ( editor -- loc ) caret>> value>> ;
  99
 100 : editor-mark ( editor -- loc ) mark>> value>> ;
 101
 102 : set-caret ( loc editor -- )
 103     [ model>> validate-loc ] [ caret>> ] bi set-model ;
 104
 105 : set-mark ( loc editor -- )
 106     [ model>> validate-loc ] [ mark>> ] bi set-model ;
 107
 108 : change-caret ( editor quot: ( loc document -- newloc ) -- )
 109     [ [ [ editor-caret ] [ model>> ] bi ] dip call ] [ drop ] 2bi
 110     set-caret ; inline
 111
 112 : mark>caret ( editor -- )
 113     [ editor-caret ] [ mark>> ] bi set-model ;
 114
 115 : change-caret&mark ( editor quot: ( loc document -- newloc ) -- )
 116     [ change-caret ] [ drop mark>caret ] 2bi ; inline
 117
 118 : editor-line ( n editor -- str ) control-value nth ;
 119
 120 :: point>loc ( point editor -- loc )
 121     point second editor y>line {
 122         { [ dup 0 < ] [ drop { 0 0 } ] }
 123         { [ dup editor model>> last-line# > ] [ drop editor model>> doc-end ] }
 124         [| n |
 125             n
 126             point first
 127             editor font>>
 128             n editor editor-line
 129             x>offset 2array
 130         ]
 131     } cond ;
 132
 133 : clicked-loc ( editor -- loc )
 134     [ hand-rel ] keep point>loc ;
 135
 136 : click-loc ( editor model -- )
 137     [ clicked-loc ] dip set-model ;
 138
 139 : focus-editor ( editor -- )
 140     [ start-blinking ] [ t >>focused? relayout-1 ] bi ;
 141
 142 : unfocus-editor ( editor -- )
 143     [ stop-blinking ] [ f >>focused? relayout-1 ] bi ;
 144
 145 : loc>x ( loc editor -- x )
 146     [ first2 swap ] dip [ editor-line ] [ font>> ] bi swap offset>x round ;
 147
 148 : loc>point ( loc editor -- loc )
 149     [ loc>x ] [ [ first ] dip line>y ceiling ] 2bi 2array ;
 150
 151 : caret-loc ( editor -- loc )
 152     [ editor-caret ] keep loc>point ;
 153
 154 : caret-dim ( editor -- dim )
 155     [ 0 ] dip line-height 2array ;
 156
 157 : scroll>caret ( editor -- )
 158     dup graft-state>> second [
 159         [
 160             [ caret-loc ] [ caret-dim { 2 1 } v+ ] bi <rect>
 161         ] keep scroll>rect
 162     ] [ drop ] if ;
 163
 164 <PRIVATE
 165
 166 : draw-caret? ( editor -- ? )
 167     { [ focused?>> ] [ blink>> ]
 168       [ [ preedit? not ] [ preedit-selection-mode?>> not ] bi or ] } 1&& ;
 169
 170 : draw-caret ( editor -- )
 171     dup draw-caret? [
 172         [ editor-caret-color gl-color ] dip
 173         [ caret-loc ] [ caret-dim ] bi
 174         over v+ gl-line
 175     ] [ drop ] if ;
 176
 177 :: draw-preedit-underlines ( editor -- )
 178     editor [ preedit? ] [ preedit-underlines>> ] bi and [
 179         editor [ caret-loc second ] [ caret-dim second ] bi + 2.0 - :> y
 180         editor editor-caret first :> row
 181         editor font>> foreground>> gl-color
 182         editor preedit-underlines>> [
 183             GL_LINE_BIT [
 184                 dup second glLineWidth
 185                 first editor preedit-start>> second dup 2array v+ first2
 186                 [ row swap 2array editor loc>x 1.0 + y 2array ]
 187                 [ row swap 2array editor loc>x 1.0 - y 2array ]
 188                 bi*
 189                 gl-line
 190             ] do-attribs
 191         ] each
 192     ] when ;
 193
 194 : selection-start/end ( editor -- start end )
 195     [ editor-mark ] [ editor-caret ] bi sort-pair ;
 196
 197 SYMBOL: selected-lines
 198
 199 TUPLE: selected-line start end first? last? ;
 200
 201 : compute-selection ( editor -- assoc )
 202     dup gadget-selection? [
 203         [ selection-start/end [ [ first ] bi@ [a,b] ] [ ] 2bi ]
 204         [ model>> ] bi
 205         '[ [ _ _ ] [ _ start/end-on-line ] bi 2array ] H{ } map>assoc
 206     ] [ drop f ] if ;
 207
 208 :: draw-selection ( line pair editor -- )
 209     pair [ editor font>> line offset>x ] map :> pair
 210     editor selection-color>> gl-color
 211     pair first 0 2array
 212     pair second pair first - round 1 max editor line-height 2array
 213     gl-fill-rect ;
 214
 215 : draw-unselected-line ( line editor -- )
 216     font>> swap draw-text ;
 217
 218 : draw-selected-line ( line pair editor -- )
 219     over all-equal? [
 220         [ nip draw-unselected-line ] [ draw-selection ] 3bi
 221     ] [
 222         [ draw-selection ]
 223         [
 224             [ [ first2 ] [ selection-color>> ] bi* <selection> ]
 225             [ draw-unselected-line ] bi
 226         ] 3bi
 227     ] if ;
 228
 229 : draw-default-text? ( editor -- ? )
 230     { [ default-text>> ] [ model>> doc-string empty? ] } 1&& ;
 231
 232 : draw-default-text ( editor -- )
 233     [ font>> clone line-color >>foreground ]
 234     [ default-text>> ] bi draw-text ;
 235
 236 PRIVATE>
 237
 238 M: editor draw-line
 239     [ selected-lines get at ] dip over
 240     [ draw-selected-line ] [ nip draw-unselected-line ] if ;
 241
 242 M: editor draw-gadget*
 243     dup draw-default-text? [
 244         [ draw-default-text ] [ draw-caret ] [ draw-preedit-underlines ] tri
 245     ] [
 246         dup compute-selection selected-lines [
 247             [ draw-lines ] [ draw-caret ] [ draw-preedit-underlines ] tri
 248         ] with-variable
 249     ] if ;
 250
 251 M: editor pref-dim*
 252     [ call-next-method ] keep ! at least as big as our min-rows/min-cols
 253     ! Add some space for the caret.
 254     [ font>> ] keep dup draw-default-text?
 255     [ default-text>> ] [ control-value ] if
 256     text-dim { 1 0 } v+ vmax ;
 257
 258 M: editor baseline font>> font-metrics ascent>> ;
 259
 260 M: editor cap-height font>> font-metrics cap-height>> ;
 261
 262 <PRIVATE
 263
 264 : contents-changed ( model editor -- )
 265     [ [ nip caret>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 266     [ [ nip mark>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 267     [ nip relayout ] 2tri ;
 268
 269 : caret/mark-changed ( editor -- )
 270     [ restart-blinking ] keep scroll>caret ;
 271
 272 PRIVATE>
 273
 274 M: editor model-changed
 275     {
 276         { [ 2dup model>> eq? ] [ contents-changed ] }
 277         { [ 2dup caret>> eq? ] [ nip caret/mark-changed ] }
 278         { [ 2dup mark>> eq? ] [ nip caret/mark-changed ] }
 279     } cond ;
 280
 281 M: editor gadget-selection?
 282     selection-start/end = not ;
 283
 284 M: editor gadget-selection
 285     [ selection-start/end ] [ model>> ] bi doc-range ;
 286
 287 : remove-selection ( editor -- )
 288     [ selection-start/end ] [ model>> ] bi remove-doc-range ;
 289
 290 M: editor user-input*
 291     [ selection-start/end ] [ model>> ] bi set-doc-range t ;
 292
 293 M: editor temp-im-input
 294     [ selection-start/end ] [ model>> ] bi set-doc-range* t ;
 295
 296 : editor-string ( editor -- string )
 297     model>> doc-string ;
 298
 299 : set-editor-string ( string editor -- )
 300     model>> set-doc-string ;
 301
 302 M: editor gadget-text* editor-string % ;
 303
 304 : extend-selection ( editor -- )
 305     [ request-focus ]
 306     [ restart-blinking ]
 307     [ dup caret>> click-loc ] tri ;
 308
 309 : remove-preedit-text ( editor -- )
 310     { [ preedit-start>> ] [ set-caret ]
 311       [ preedit-end>> ] [ set-mark ]
 312       [ remove-selection ]
 313     } cleave ;
 314
 315 : remove-preedit-info ( editor -- )
 316     f >>preedit-start
 317     f >>preedit-end
 318     f >>preedit-selected-start
 319     f >>preedit-selected-end
 320     f >>preedit-selection-mode?
 321     f >>preedit-underlines
 322     drop ;
 323
 324 : mouse-elt ( -- element )
 325     hand-click# get {
 326         { 1 one-char-elt }
 327         { 2 one-word-elt }
 328     } at one-line-elt or ;
 329
 330 : drag-direction? ( loc editor -- ? )
 331     editor-mark before? ;
 332
 333 : drag-selection-caret ( loc editor element -- loc )
 334     [
 335         [ drag-direction? ] [ model>> ] 2bi
 336     ] dip prev/next-elt ? ;
 337
 338 : drag-selection-mark ( loc editor element -- loc )
 339     [
 340         [ drag-direction? not ]
 341         [ editor-mark ]
 342         [ model>> ] tri
 343     ] dip prev/next-elt ? ;
 344
 345 : drag-caret&mark ( editor -- caret mark )
 346     [ clicked-loc ] [ mouse-elt ] bi
 347     [ drag-selection-caret ]
 348     [ drag-selection-mark ] 3bi ;
 349
 350 : drag-selection ( editor -- )
 351     [ drag-caret&mark ]
 352     [ mark>> set-model ]
 353     [ caret>> set-model ] tri ;
 354
 355 : editor-cut ( editor clipboard -- )
 356     [ gadget-copy ] [ drop remove-selection ] 2bi ;
 357
 358 : delete/backspace ( editor quot -- )
 359     over gadget-selection? [
 360         drop remove-selection
 361     ] [
 362         [ [ [ editor-caret ] [ model>> ] bi ] dip call ]
 363         [ drop model>> ]
 364         2bi remove-doc-range
 365     ] if ; inline
 366
 367 : editor-delete ( editor elt -- )
 368     '[ dupd _ next-elt ] delete/backspace ;
 369
 370 : editor-backspace ( editor elt -- )
 371     '[ over [ _ prev-elt ] dip ] delete/backspace ;
 372
 373 : editor-select-prev ( editor elt -- )
 374     '[ _ prev-elt ] change-caret ;
 375
 376 : editor-prev ( editor elt -- )
 377     [ editor-select-prev ] [ drop mark>caret ] 2bi ;
 378
 379 : editor-select-next ( editor elt -- )
 380     '[ _ next-elt ] change-caret ;
 381
 382 : editor-next ( editor elt -- )
 383     dupd editor-select-next mark>caret ;
 384
 385 : editor-select ( from to editor -- )
 386     [ mark>> set-model ] [ caret>> set-model ] bi-curry bi* ;
 387
 388 : select-elt ( editor elt -- )
 389     [ [ [ editor-caret ] [ model>> ] bi ] dip prev/next-elt ] [ drop ] 2bi
 390     editor-select ;
 391
 392 : start-of-document ( editor -- ) doc-elt editor-prev ;
 393
 394 : end-of-document ( editor -- ) doc-elt editor-next ;
 395
 396 : position-caret ( editor -- )
 397     mouse-elt dup one-char-elt =
 398     [ drop dup extend-selection dup mark>> click-loc ]
 399     [ select-elt ] if ;
 400
 401 : delete-previous-character ( editor -- )
 402     char-elt editor-backspace ;
 403
 404 : delete-next-character ( editor -- )
 405     char-elt editor-delete ;
 406
 407 : delete-previous-word ( editor -- )
 408     word-elt editor-backspace ;
 409
 410 : delete-next-word ( editor -- )
 411     word-elt editor-delete ;
 412
 413 : delete-to-start-of-line ( editor -- )
 414     one-line-elt editor-backspace ;
 415
 416 : delete-to-end-of-line ( editor -- )
 417     one-line-elt editor-delete ;
 418
 419 : delete-to-start-of-document ( editor -- )
 420     doc-elt editor-delete ;
 421
 422 : delete-to-end-of-document ( editor -- )
 423     doc-elt editor-delete ;
 424
 425 : com-undo ( editor -- ) model>> undo ;
 426
 427 : com-redo ( editor -- ) model>> redo ;
 428
 429 editor "editing" f {
 430     { undo-action com-undo }
 431     { redo-action com-redo }
 432     { T{ key-down f f "DELETE" } delete-next-character }
 433     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 434     { T{ key-down f { S+ } "DELETE" } delete-next-character }
 435     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 436     { T{ key-down f ${ os macosx? A+ C+ ? } "DELETE" } delete-next-word }
 437     { T{ key-down f ${ os macosx? A+ C+ ? } "BACKSPACE" } delete-previous-word }
 438     { T{ key-down f ${ os macosx? M+ A+ ? } "DELETE" } delete-to-end-of-line }
 439     { T{ key-down f ${ os macosx? M+ A+ ? } "BACKSPACE" } delete-to-start-of-line }
 440 } os macosx? [ {
 441     { T{ key-down f { C+ } "DELETE" } delete-next-character }
 442     { T{ key-down f { C+ } "BACKSPACE" } delete-previous-character }
 443     ! { T{ key-down f { C+ } "t" } transpose-character }
 444     { T{ key-down f { C+ } "d" } delete-next-character }
 445     { T{ key-down f { C+ } "h" } delete-previous-character }
 446     { T{ key-down f { C+ } "u" } delete-to-start-of-line }
 447     { T{ key-down f { C+ } "k" } delete-to-end-of-line }
 448     { T{ key-down f { C+ } "w" } delete-previous-word }
 449 } append ] when define-command-map
 450
 451 : com-paste ( editor -- ) clipboard get paste-clipboard ;
 452
 453 : paste-selection ( editor -- ) ui.clipboards:selection get paste-clipboard ;
 454
 455 : com-cut ( editor -- ) clipboard get editor-cut ;
 456
 457 editor "clipboard" f {
 458     { cut-action com-cut }
 459     { copy-action com-copy }
 460     { paste-action com-paste }
 461     { T{ button-up } com-copy-selection }
 462     { T{ button-up f f 2 } paste-selection }
 463 } define-command-map
 464
 465 : previous-character ( editor -- )
 466     dup gadget-selection? [
 467         dup selection-start/end drop
 468         over set-caret mark>caret
 469     ] [
 470         char-elt editor-prev
 471     ] if ;
 472
 473 : next-character ( editor -- )
 474     dup gadget-selection? [
 475         dup selection-start/end nip
 476         over set-caret mark>caret
 477     ] [
 478         char-elt editor-next
 479     ] if ;
 480
 481 : previous-word ( editor -- ) word-elt editor-prev ;
 482
 483 : next-word ( editor -- ) word-elt editor-next ;
 484
 485 : start-of-line ( editor -- ) one-line-elt editor-prev ;
 486
 487 : end-of-line ( editor -- ) one-line-elt editor-next ;
 488
 489 : start-of-paragraph ( editor -- ) paragraph-elt editor-prev ;
 490
 491 : end-of-paragraph ( editor -- ) paragraph-elt editor-next ;
 492
 493 editor "caret-motion" f {
 494     { T{ button-down } position-caret }
 495     { T{ key-down f f "LEFT" } previous-character }
 496     { T{ key-down f f "RIGHT" } next-character }
 497     { T{ key-down f ${ os macosx? A+ C+ ? } "LEFT" } previous-word }
 498     { T{ key-down f ${ os macosx? A+ C+ ? } "RIGHT" } next-word }
 499     { T{ key-down f f "HOME" } start-of-line }
 500     { T{ key-down f f "END" } end-of-line }
 501     { T{ key-down f ${ os macosx? A+ C+ ? } "UP" } start-of-paragraph }
 502     { T{ key-down f ${ os macosx? A+ C+ ? } "DOWN" } end-of-paragraph }
 503     { T{ key-down f ${ os macosx? A+ C+ ? } "HOME" } start-of-document }
 504     { T{ key-down f ${ os macosx? A+ C+ ? } "END" } end-of-document }
 505 } os macosx? [ {
 506     { T{ key-down f { M+ } "LEFT" } start-of-line }
 507     { T{ key-down f { M+ } "RIGHT" } end-of-line }
 508     { T{ key-down f { M+ } "UP" } start-of-paragraph }
 509     { T{ key-down f { M+ } "DOWN" } end-of-paragraph }
 510     { T{ key-down f { M+ } "HOME" } start-of-document }
 511     { T{ key-down f { M+ } "END" } end-of-document }
 512     { T{ key-down f { C+ } "b" } previous-character }
 513     { T{ key-down f { C+ } "f" } next-character }
 514     { T{ key-down f { C+ } "a" } start-of-line }
 515     { T{ key-down f { C+ } "e" } end-of-line }
 516 } append ] when define-command-map
 517
 518 : clear-editor ( editor -- )
 519     model>> clear-doc ;
 520
 521 : select-all ( editor -- ) doc-elt select-elt ;
 522
 523 : select-line ( editor -- ) one-line-elt select-elt ;
 524
 525 : select-word ( editor -- ) one-word-elt select-elt ;
 526
 527 : selected-token ( editor -- string )
 528     dup gadget-selection?
 529     [ dup select-word ] unless
 530     gadget-selection ;
 531
 532 : select-previous-character ( editor -- )
 533     char-elt editor-select-prev ;
 534
 535 : select-next-character ( editor -- )
 536     char-elt editor-select-next ;
 537
 538 : select-previous-word ( editor -- )
 539     word-elt editor-select-prev ;
 540
 541 : select-next-word ( editor -- )
 542     word-elt editor-select-next ;
 543
 544 : select-start-of-line ( editor -- )
 545     one-line-elt editor-select-prev ;
 546
 547 : select-end-of-line ( editor -- )
 548     one-line-elt editor-select-next ;
 549
 550 : select-start-of-paragraph ( editor -- )
 551     paragraph-elt editor-select-prev ;
 552
 553 : select-end-of-paragraph ( editor -- )
 554     paragraph-elt editor-select-next ;
 555
 556 : select-start-of-document ( editor -- )
 557     doc-elt editor-select-prev ;
 558
 559 : select-end-of-document ( editor -- )
 560     doc-elt editor-select-next ;
 561
 562 editor "selection" f {
 563     { T{ button-down f { S+ } 1 } extend-selection }
 564     { T{ button-up f { S+ } 1 } com-copy-selection }
 565     { T{ drag { # 1 } } drag-selection }
 566     { gain-focus focus-editor }
 567     { lose-focus unfocus-editor }
 568     { delete-action remove-selection }
 569     { select-all-action select-all }
 570     { T{ key-down f { C+ } "l" } select-line }
 571     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 572     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 573     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "LEFT" } select-previous-word }
 574     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "RIGHT" } select-next-word }
 575     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 576     { T{ key-down f { S+ } "END" } select-end-of-line }
 577     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "UP" } select-start-of-paragraph }
 578     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "DOWN" } select-end-of-paragraph }
 579     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "HOME" } select-start-of-document }
 580     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "END" } select-end-of-document }
 581 } os macosx? [ {
 582     { T{ key-down f { S+ M+ } "LEFT" } select-start-of-line }
 583     { T{ key-down f { S+ M+ } "RIGHT" } select-end-of-line }
 584     { T{ key-down f { S+ M+ } "UP" } select-start-of-paragraph }
 585     { T{ key-down f { S+ M+ } "DOWN" } select-end-of-paragraph }
 586     { T{ key-down f { S+ M+ } "HOME" } select-start-of-document }
 587     { T{ key-down f { S+ M+ } "END" } select-end-of-document }
 588 } append ] when define-command-map
 589
 590 : editor-menu ( editor -- )
 591     {
 592         com-undo
 593         com-redo
 594         ----
 595         com-cut
 596         com-copy
 597         com-paste
 598     } show-commands-menu ;
 599
 600 editor "misc" f {
 601     ! { T{ button-down f f 2 } paste-selection }
 602     { T{ button-down f f 3 } editor-menu }
 603 } define-command-map
 604
 605 ! Multi-line editors
 606 TUPLE: multiline-editor < editor ;
 607
 608 : <multiline-editor> ( -- editor )
 609     multiline-editor new-editor ;
 610
 611 : previous-line ( editor -- ) line-elt editor-prev ;
 612
 613 : next-line ( editor -- ) line-elt editor-next ;
 614
 615 <PRIVATE
 616
 617 : page-elt ( editor n -- editor element )
 618     over visible-lines 1 - min 1 max <page-elt> ;
 619
 620 : prev-page-elt ( editor -- editor element )
 621     dup editor-caret first page-elt ;
 622
 623 : next-page-elt ( editor -- editor element )
 624     dup [ control-value length 1 - ] [ editor-caret first ] bi - page-elt ;
 625
 626 PRIVATE>
 627
 628 : previous-page ( editor -- ) prev-page-elt editor-prev ;
 629
 630 : next-page ( editor -- ) next-page-elt editor-next ;
 631
 632 : select-previous-line ( editor -- ) line-elt editor-select-prev ;
 633
 634 : select-next-line ( editor -- ) line-elt editor-select-next ;
 635
 636 : select-previous-page ( editor -- ) prev-page-elt editor-select-prev ;
 637
 638 : select-next-page ( editor -- ) next-page-elt editor-select-next ;
 639
 640 : insert-newline ( editor -- )
 641     "\n" swap user-input* drop ;
 642
 643 : change-selection ( editor quot -- )
 644     '[ gadget-selection @ ] [ user-input* drop ] bi ; inline
 645
 646 <PRIVATE
 647
 648 : join-lines ( string -- string' )
 649     "\n" split
 650     [ rest-slice [ [ blank? ] trim-head-slice ] map! drop ]
 651     [ but-last-slice [ [ blank? ] trim-tail-slice ] map! drop ]
 652     [ " " join ]
 653     tri ;
 654
 655 : last-line? ( document line -- ? )
 656     [ last-line# ] dip = ;
 657
 658 : prev-line-and-this ( document line -- start end )
 659     swap [ drop 1 - 0 2array ] [ line-end ] 2bi ;
 660
 661 : join-with-prev ( document line -- )
 662     [ prev-line-and-this ] [ drop ] 2bi
 663     [ join-lines ] change-doc-range ;
 664
 665 : this-line-and-next ( document line -- start end )
 666     swap [ drop 0 2array ] [ [ 1 + ] dip line-end ] 2bi ;
 667
 668 : join-with-next ( document line -- )
 669     [ this-line-and-next ] [ drop ] 2bi
 670     [ join-lines ] change-doc-range ;
 671
 672 PRIVATE>
 673
 674 : com-join-lines ( editor -- )
 675     dup gadget-selection?
 676     [ [ join-lines ] change-selection ] [
 677         [ model>> ] [ editor-caret first ] bi {
 678             { [ over last-line# 0 = ] [ 2drop ] }
 679             { [ 2dup last-line? ] [ join-with-prev ] }
 680             [ join-with-next ]
 681         } cond
 682     ] if ;
 683
 684 multiline-editor "multiline" f {
 685     { T{ key-down f f "UP" } previous-line }
 686     { T{ key-down f f "DOWN" } next-line }
 687     { T{ key-down f { S+ } "UP" } select-previous-line }
 688     { T{ key-down f { S+ } "DOWN" } select-next-line }
 689     { T{ key-down f f "PAGE_UP" } previous-page }
 690     { T{ key-down f f "PAGE_DOWN" } next-page }
 691     { T{ key-down f { S+ } "PAGE_UP" } select-previous-page }
 692     { T{ key-down f { S+ } "PAGE_DOWN" } select-next-page }
 693     { T{ key-down f f "RET" } insert-newline }
 694     { T{ key-down f { S+ } "RET" } insert-newline }
 695     { T{ key-down f f "ENTER" } insert-newline }
 696     { T{ key-down f { S+ } "ENTER" } insert-newline }
 697     { T{ key-down f { C+ } "j" } com-join-lines }
 698 } os unix? [ {
 699     { T{ key-down f { C+ } "p" } previous-line }
 700     { T{ key-down f { C+ } "n" } next-line }
 701 } append ] when define-command-map
 702
 703 TUPLE: source-editor < multiline-editor ;
 704
 705 : <source-editor> ( -- editor )
 706     source-editor new-editor ;
 707
 708 ! A useful model
 709 : <element-model> ( editor element -- model )
 710     [ [ caret>> ] [ model>> ] bi ] dip
 711     '[ _ _ elt-string ] <arrow> ;
 712
 713 ! Fields wrap an editor
 714 TUPLE: field < border editor min-cols max-cols ;
 715
 716 <PRIVATE
 717
 718 : field-theme ( gadget -- gadget )
 719     { 2 2 } >>size
 720     { 1 0 } >>fill
 721     field-border-color <solid> >>boundary ; inline
 722
 723 : <field-border> ( gadget -- border )
 724     border new-border field-theme ;
 725
 726 PRIVATE>
 727
 728 : new-field ( class -- gadget )
 729     [ <editor> ] dip new-border
 730         dup gadget-child >>editor
 731         field-theme ; inline
 732
 733 ! For line-gadget-width
 734 M: field font>> editor>> font>> ;
 735
 736 M: field pref-dim*
 737     [ ]
 738     [ editor>> pref-dim ]
 739     [ [ line-gadget-width ] [ drop second ] 2bi 2array ]
 740     tri border-pref-dim ;
 741
 742 M: field default-text>> editor>> default-text>> ;
 743
 744 M: field default-text<< editor>> default-text<< ;
 745
 746 TUPLE: model-field < field field-model ;
 747
 748 : <model-field> ( model -- gadget )
 749     model-field new-field
 750         swap >>field-model ;
 751
 752 M: model-field graft*
 753     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 754     [ dup editor>> model>> add-connection ]
 755     bi ;
 756
 757 M: model-field ungraft*
 758     dup editor>> model>> remove-connection ;
 759
 760 M: model-field model-changed
 761     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;
 762
 763 TUPLE: action-field < field quot ;
 764
 765 : <action-field> ( quot: ( string -- ) -- gadget )
 766     action-field [ <editor> ] dip new-border
 767         dup gadget-child >>editor
 768         field-theme
 769         swap >>quot ;
 770
 771 : invoke-action-field ( field -- )
 772     [ editor>> editor-string ]
 773     [ editor>> clear-editor ]
 774     [ quot>> ]
 775     tri call( string -- ) ;
 776
 777 action-field H{
 778     { T{ key-down f f "RET" } [ invoke-action-field ] }
 779 } set-gestures