basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2011 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs calendar colors.constants combinators
   4 combinators.short-circuit documents documents.elements fonts fry
   5 grouping kernel locals make math math.functions math.order math.ranges
   6 math.rectangles math.vectors models models.arrow namespaces opengl
   7 sequences sorting splitting timers ui.baseline-alignment ui.clipboards
   8 ui.commands ui.gadgets ui.gadgets.borders ui.gadgets.line-support
   9 ui.gadgets.menus ui.gadgets.scrollers ui.gestures ui.pens.solid
  10 ui.render ui.text ui.theme unicode ;
  11 IN: ui.gadgets.editors
  12
  13 TUPLE: editor < line-gadget
  14     caret-color
  15     caret mark
  16     focused? blink blink-timer ;
  17
  18 <PRIVATE
  19
  20 : <loc> ( -- loc ) { 0 0 } <model> ;
  21
  22 : init-editor-locs ( editor -- editor )
  23     <loc> >>caret
  24     <loc> >>mark ; inline
  25
  26 : editor-theme ( editor -- editor )
  27     COLOR: red >>caret-color
  28     monospace-font >>font ; inline
  29
  30 PRIVATE>
  31
  32 : new-editor ( class -- editor )
  33     new-line-gadget
  34         <document> >>model
  35         init-editor-locs
  36         editor-theme ; inline
  37
  38 : <editor> ( -- editor )
  39     editor new-editor ;
  40
  41 <PRIVATE
  42
  43 : activate-editor-model ( editor model -- )
  44     [ add-connection ]
  45     [ nip activate-model ]
  46     [ swap model>> add-loc ] 2tri ;
  47
  48 : deactivate-editor-model ( editor model -- )
  49     [ remove-connection ]
  50     [ nip deactivate-model ]
  51     [ swap model>> remove-loc ] 2tri ;
  52
  53 : blink-caret ( editor -- )
  54     [ not ] change-blink relayout-1 ;
  55
  56 SYMBOL: blink-interval
  57
  58 750 milliseconds blink-interval set-global
  59
  60 : stop-blinking ( editor -- )
  61     blink-timer>> [ stop-timer ] when* ;
  62
  63 : start-blinking ( editor -- )
  64     t >>blink
  65     blink-timer>> [ restart-timer ] when* ;
  66
  67 : restart-blinking ( editor -- )
  68     dup focused?>> [
  69         [ start-blinking ]
  70         [ relayout-1 ]
  71         bi
  72     ] [ drop ] if ;
  73
  74 PRIVATE>
  75
  76 M: editor graft*
  77     [ dup caret>> activate-editor-model ]
  78     [ dup mark>> activate-editor-model ]
  79     [
  80         [
  81             '[ _ blink-caret ] blink-interval get dup <timer>
  82         ] keep blink-timer<<
  83     ] tri ;
  84
  85 M: editor ungraft*
  86     [ [ stop-blinking ] [ f >>blink-timer drop ] bi ]
  87     [ dup caret>> deactivate-editor-model ]
  88     [ dup mark>> deactivate-editor-model ] tri ;
  89
  90 : editor-caret ( editor -- loc ) caret>> value>> ;
  91
  92 : editor-mark ( editor -- loc ) mark>> value>> ;
  93
  94 : set-caret ( loc editor -- )
  95     [ model>> validate-loc ] [ caret>> ] bi set-model ;
  96
  97 : change-caret ( editor quot: ( loc document -- newloc ) -- )
  98     [ [ [ editor-caret ] [ model>> ] bi ] dip call ] [ drop ] 2bi
  99     set-caret ; inline
 100
 101 : mark>caret ( editor -- )
 102     [ editor-caret ] [ mark>> ] bi set-model ;
 103
 104 : change-caret&mark ( editor quot: ( loc document -- newloc ) -- )
 105     [ change-caret ] [ drop mark>caret ] 2bi ; inline
 106
 107 : editor-line ( n editor -- str ) control-value nth ;
 108
 109 :: point>loc ( point editor -- loc )
 110     point second editor y>line {
 111         { [ dup 0 < ] [ drop { 0 0 } ] }
 112         { [ dup editor model>> last-line# > ] [ drop editor model>> doc-end ] }
 113         [| n |
 114             n
 115             point first
 116             editor font>>
 117             n editor editor-line
 118             x>offset 2array
 119         ]
 120     } cond ;
 121
 122 : clicked-loc ( editor -- loc )
 123     [ hand-rel ] keep point>loc ;
 124
 125 : click-loc ( editor model -- )
 126     [ clicked-loc ] dip set-model ;
 127
 128 : focus-editor ( editor -- )
 129     [ start-blinking ] [ t >>focused? relayout-1 ] bi ;
 130
 131 : unfocus-editor ( editor -- )
 132     [ stop-blinking ] [ f >>focused? relayout-1 ] bi ;
 133
 134 : loc>x ( loc editor -- x )
 135     [ first2 swap ] dip [ editor-line ] [ font>> ] bi swap offset>x round ;
 136
 137 : loc>point ( loc editor -- loc )
 138     [ loc>x ] [ [ first ] dip line>y ceiling ] 2bi 2array ;
 139
 140 : caret-loc ( editor -- loc )
 141     [ editor-caret ] keep loc>point ;
 142
 143 : caret-dim ( editor -- dim )
 144     [ 0 ] dip line-height 2array ;
 145
 146 : scroll>caret ( editor -- )
 147     dup graft-state>> second [
 148         [
 149             [ caret-loc ] [ caret-dim { 2 1 } v+ ] bi <rect>
 150         ] keep scroll>rect
 151     ] [ drop ] if ;
 152
 153 <PRIVATE
 154
 155 : draw-caret? ( editor -- ? )
 156     { [ focused?>> ] [ blink>> ] } 1&& ;
 157
 158 : draw-caret ( editor -- )
 159     dup draw-caret? [
 160         [ caret-color>> gl-color ]
 161         [
 162             [ caret-loc ] [ caret-dim ] bi
 163             over v+ gl-line
 164         ] bi
 165     ] [ drop ] if ;
 166
 167 : selection-start/end ( editor -- start end )
 168     [ editor-mark ] [ editor-caret ] bi sort-pair ;
 169
 170 SYMBOL: selected-lines
 171
 172 TUPLE: selected-line start end first? last? ;
 173
 174 : compute-selection ( editor -- assoc )
 175     dup gadget-selection? [
 176         [ selection-start/end [ [ first ] bi@ [a,b] ] [ ] 2bi ]
 177         [ model>> ] bi
 178         '[ [ _ _ ] [ _ start/end-on-line ] bi 2array ] H{ } map>assoc
 179     ] [ drop f ] if ;
 180
 181 :: draw-selection ( line pair editor -- )
 182     pair [ editor font>> line offset>x ] map :> pair
 183     editor selection-color>> gl-color
 184     pair first 0 2array
 185     pair second pair first - round 1 max editor line-height 2array
 186     gl-fill-rect ;
 187
 188 : draw-unselected-line ( line editor -- )
 189     font>> swap draw-text ;
 190
 191 : draw-selected-line ( line pair editor -- )
 192     over all-equal? [
 193         [ nip draw-unselected-line ] [ draw-selection ] 3bi
 194     ] [
 195         [ draw-selection ]
 196         [
 197             [ [ first2 ] [ selection-color>> ] bi* <selection> ]
 198             [ draw-unselected-line ] bi
 199         ] 3bi
 200     ] if ;
 201
 202 PRIVATE>
 203
 204 M: editor draw-line ( line index editor -- )
 205     [ selected-lines get at ] dip over
 206     [ draw-selected-line ] [ nip draw-unselected-line ] if ;
 207
 208 M: editor draw-gadget*
 209     dup compute-selection selected-lines [
 210         [ draw-lines ] [ draw-caret ] bi
 211     ] with-variable ;
 212
 213 M: editor pref-dim*
 214     ! Add some space for the caret.
 215     [ font>> ] [ control-value ] bi text-dim { 1 0 } v+ ;
 216
 217 M: editor baseline font>> font-metrics ascent>> ;
 218
 219 M: editor cap-height font>> font-metrics cap-height>> ;
 220
 221 <PRIVATE
 222
 223 : contents-changed ( model editor -- )
 224     [ [ nip caret>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 225     [ [ nip mark>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 226     [ nip relayout ] 2tri ;
 227
 228 : caret/mark-changed ( editor -- )
 229     [ restart-blinking ] keep scroll>caret ;
 230
 231 PRIVATE>
 232
 233 M: editor model-changed
 234     {
 235         { [ 2dup model>> eq? ] [ contents-changed ] }
 236         { [ 2dup caret>> eq? ] [ nip caret/mark-changed ] }
 237         { [ 2dup mark>> eq? ] [ nip caret/mark-changed ] }
 238     } cond ;
 239
 240 M: editor gadget-selection?
 241     selection-start/end = not ;
 242
 243 M: editor gadget-selection
 244     [ selection-start/end ] [ model>> ] bi doc-range ;
 245
 246 : remove-selection ( editor -- )
 247     [ selection-start/end ] [ model>> ] bi remove-doc-range ;
 248
 249 M: editor user-input*
 250     [ selection-start/end ] [ model>> ] bi set-doc-range t ;
 251
 252 : editor-string ( editor -- string )
 253     model>> doc-string ;
 254
 255 : set-editor-string ( string editor -- )
 256     model>> set-doc-string ;
 257
 258 M: editor gadget-text* editor-string % ;
 259
 260 : extend-selection ( editor -- )
 261     [ request-focus ]
 262     [ restart-blinking ]
 263     [ dup caret>> click-loc ] tri ;
 264
 265 : mouse-elt ( -- element )
 266     hand-click# get {
 267         { 1 one-char-elt }
 268         { 2 one-word-elt }
 269     } at one-line-elt or ;
 270
 271 : drag-direction? ( loc editor -- ? )
 272     editor-mark before? ;
 273
 274 : drag-selection-caret ( loc editor element -- loc )
 275     [
 276         [ drag-direction? ] [ model>> ] 2bi
 277     ] dip prev/next-elt ? ;
 278
 279 : drag-selection-mark ( loc editor element -- loc )
 280     [
 281         [ drag-direction? not ]
 282         [ editor-mark ]
 283         [ model>> ] tri
 284     ] dip prev/next-elt ? ;
 285
 286 : drag-caret&mark ( editor -- caret mark )
 287     [ clicked-loc ] [ mouse-elt ] bi
 288     [ drag-selection-caret ]
 289     [ drag-selection-mark ] 3bi ;
 290
 291 : drag-selection ( editor -- )
 292     [ drag-caret&mark ]
 293     [ mark>> set-model ]
 294     [ caret>> set-model ] tri ;
 295
 296 : editor-cut ( editor clipboard -- )
 297     [ gadget-copy ] [ drop remove-selection ] 2bi ;
 298
 299 : delete/backspace ( editor quot -- )
 300     over gadget-selection? [
 301         drop remove-selection
 302     ] [
 303         [ [ [ editor-caret ] [ model>> ] bi ] dip call ]
 304         [ drop model>> ]
 305         2bi remove-doc-range
 306     ] if ; inline
 307
 308 : editor-delete ( editor elt -- )
 309     '[ dupd _ next-elt ] delete/backspace ;
 310
 311 : editor-backspace ( editor elt -- )
 312     '[ over [ _ prev-elt ] dip ] delete/backspace ;
 313
 314 : editor-select-prev ( editor elt -- )
 315     '[ _ prev-elt ] change-caret ;
 316
 317 : editor-prev ( editor elt -- )
 318     [ editor-select-prev ] [ drop mark>caret ] 2bi ;
 319
 320 : editor-select-next ( editor elt -- )
 321     '[ _ next-elt ] change-caret ;
 322
 323 : editor-next ( editor elt -- )
 324     dupd editor-select-next mark>caret ;
 325
 326 : editor-select ( from to editor -- )
 327     [ mark>> set-model ] [ caret>> set-model ] bi-curry bi* ;
 328
 329 : select-elt ( editor elt -- )
 330     [ [ [ editor-caret ] [ model>> ] bi ] dip prev/next-elt ] [ drop ] 2bi
 331     editor-select ;
 332
 333 : start-of-document ( editor -- ) doc-elt editor-prev ;
 334
 335 : end-of-document ( editor -- ) doc-elt editor-next ;
 336
 337 : position-caret ( editor -- )
 338     mouse-elt dup one-char-elt =
 339     [ drop dup extend-selection dup mark>> click-loc ]
 340     [ select-elt ] if ;
 341
 342 : delete-previous-character ( editor -- )
 343     char-elt editor-backspace ;
 344
 345 : delete-next-character ( editor -- )
 346     char-elt editor-delete ;
 347
 348 : delete-previous-word ( editor -- )
 349     word-elt editor-backspace ;
 350
 351 : delete-next-word ( editor -- )
 352     word-elt editor-delete ;
 353
 354 : delete-to-start-of-line ( editor -- )
 355     one-line-elt editor-backspace ;
 356
 357 : delete-to-end-of-line ( editor -- )
 358     one-line-elt editor-delete ;
 359
 360 : delete-to-start-of-document ( editor -- )
 361     doc-elt editor-delete ;
 362
 363 : delete-to-end-of-document ( editor -- )
 364     doc-elt editor-delete ;
 365
 366 : com-undo ( editor -- ) model>> undo ;
 367
 368 : com-redo ( editor -- ) model>> redo ;
 369
 370 editor "editing" f {
 371     { undo-action com-undo }
 372     { redo-action com-redo }
 373     { T{ key-down f f "DELETE" } delete-next-character }
 374     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 375     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 376     { T{ key-down f { C+ } "DELETE" } delete-next-word }
 377     { T{ key-down f { C+ } "BACKSPACE" } delete-previous-word }
 378     { T{ key-down f { A+ } "DELETE" } delete-to-end-of-line }
 379     { T{ key-down f { A+ } "BACKSPACE" } delete-to-start-of-line }
 380 } define-command-map
 381
 382 : com-paste ( editor -- ) clipboard get paste-clipboard ;
 383
 384 : paste-selection ( editor -- ) ui.clipboards:selection get paste-clipboard ;
 385
 386 : com-cut ( editor -- ) clipboard get editor-cut ;
 387
 388 editor "clipboard" f {
 389     { cut-action com-cut }
 390     { copy-action com-copy }
 391     { paste-action com-paste }
 392     { T{ button-up } com-copy-selection }
 393     { T{ button-up f f 2 } paste-selection }
 394 } define-command-map
 395
 396 : previous-character ( editor -- )
 397     dup gadget-selection? [
 398         dup selection-start/end drop
 399         over set-caret mark>caret
 400     ] [
 401         char-elt editor-prev
 402     ] if ;
 403
 404 : next-character ( editor -- )
 405     dup gadget-selection? [
 406         dup selection-start/end nip
 407         over set-caret mark>caret
 408     ] [
 409         char-elt editor-next
 410     ] if ;
 411
 412 : previous-word ( editor -- ) word-elt editor-prev ;
 413
 414 : next-word ( editor -- ) word-elt editor-next ;
 415
 416 : start-of-line ( editor -- ) one-line-elt editor-prev ;
 417
 418 : end-of-line ( editor -- ) one-line-elt editor-next ;
 419
 420 editor "caret-motion" f {
 421     { T{ button-down } position-caret }
 422     { T{ key-down f f "LEFT" } previous-character }
 423     { T{ key-down f f "RIGHT" } next-character }
 424     { T{ key-down f { C+ } "LEFT" } previous-word }
 425     { T{ key-down f { C+ } "RIGHT" } next-word }
 426     { T{ key-down f f "HOME" } start-of-line }
 427     { T{ key-down f f "END" } end-of-line }
 428     { T{ key-down f { C+ } "HOME" } start-of-document }
 429     { T{ key-down f { C+ } "END" } end-of-document }
 430 } define-command-map
 431
 432 : clear-editor ( editor -- )
 433     model>> clear-doc ;
 434
 435 : select-all ( editor -- ) doc-elt select-elt ;
 436
 437 : select-line ( editor -- ) one-line-elt select-elt ;
 438
 439 : select-word ( editor -- ) one-word-elt select-elt ;
 440
 441 : selected-token ( editor -- string )
 442     dup gadget-selection?
 443     [ dup select-word ] unless
 444     gadget-selection ;
 445
 446 : select-previous-character ( editor -- )
 447     char-elt editor-select-prev ;
 448
 449 : select-next-character ( editor -- )
 450     char-elt editor-select-next ;
 451
 452 : select-previous-word ( editor -- )
 453     word-elt editor-select-prev ;
 454
 455 : select-next-word ( editor -- )
 456     word-elt editor-select-next ;
 457
 458 : select-start-of-line ( editor -- )
 459     one-line-elt editor-select-prev ;
 460
 461 : select-end-of-line ( editor -- )
 462     one-line-elt editor-select-next ;
 463
 464 : select-start-of-document ( editor -- )
 465     doc-elt editor-select-prev ;
 466
 467 : select-end-of-document ( editor -- )
 468     doc-elt editor-select-next ;
 469
 470 editor "selection" f {
 471     { T{ button-down f { S+ } 1 } extend-selection }
 472     { T{ button-up f { S+ } 1 } com-copy-selection }
 473     { T{ drag { # 1 } } drag-selection }
 474     { gain-focus focus-editor }
 475     { lose-focus unfocus-editor }
 476     { delete-action remove-selection }
 477     { select-all-action select-all }
 478     { T{ key-down f { C+ } "l" } select-line }
 479     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 480     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 481     { T{ key-down f { S+ C+ } "LEFT" } select-previous-word }
 482     { T{ key-down f { S+ C+ } "RIGHT" } select-next-word }
 483     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 484     { T{ key-down f { S+ } "END" } select-end-of-line }
 485     { T{ key-down f { S+ C+ } "HOME" } select-start-of-document }
 486     { T{ key-down f { S+ C+ } "END" } select-end-of-document }
 487 } define-command-map
 488
 489 : editor-menu ( editor -- )
 490     {
 491         com-undo
 492         com-redo
 493         ----
 494         com-cut
 495         com-copy
 496         com-paste
 497     } show-commands-menu ;
 498
 499 editor "misc" f {
 500     ! { T{ button-down f f 2 } paste-selection }
 501     { T{ button-down f f 3 } editor-menu }
 502 } define-command-map
 503
 504 ! Multi-line editors
 505 TUPLE: multiline-editor < editor ;
 506
 507 : <multiline-editor> ( -- editor )
 508     multiline-editor new-editor ;
 509
 510 : previous-line ( editor -- ) line-elt editor-prev ;
 511
 512 : next-line ( editor -- ) line-elt editor-next ;
 513
 514 <PRIVATE
 515
 516 : page-elt ( editor -- editor element ) dup visible-lines 1 - <page-elt> ;
 517
 518 PRIVATE>
 519
 520 : previous-page ( editor -- ) page-elt editor-prev ;
 521
 522 : next-page ( editor -- ) page-elt editor-next ;
 523
 524 : select-previous-line ( editor -- ) line-elt editor-select-prev ;
 525
 526 : select-next-line ( editor -- ) line-elt editor-select-next ;
 527
 528 : select-previous-page ( editor -- ) page-elt editor-select-prev ;
 529
 530 : select-next-page ( editor -- ) page-elt editor-select-next ;
 531
 532 : insert-newline ( editor -- )
 533     "\n" swap user-input* drop ;
 534
 535 : change-selection ( editor quot -- )
 536     '[ gadget-selection @ ] [ user-input* drop ] bi ; inline
 537
 538 <PRIVATE
 539
 540 : join-lines ( string -- string' )
 541     "\n" split
 542     [ rest-slice [ [ blank? ] trim-head-slice ] map! drop ]
 543     [ but-last-slice [ [ blank? ] trim-tail-slice ] map! drop ]
 544     [ " " join ]
 545     tri ;
 546
 547 : last-line? ( document line -- ? )
 548     [ last-line# ] dip = ;
 549
 550 : prev-line-and-this ( document line -- start end )
 551     swap [ drop 1 - 0 2array ] [ line-end ] 2bi ;
 552
 553 : join-with-prev ( document line -- )
 554     [ prev-line-and-this ] [ drop ] 2bi
 555     [ join-lines ] change-doc-range ;
 556
 557 : this-line-and-next ( document line -- start end )
 558     swap [ drop 0 2array ] [ [ 1 + ] dip line-end ] 2bi ;
 559
 560 : join-with-next ( document line -- )
 561     [ this-line-and-next ] [ drop ] 2bi
 562     [ join-lines ] change-doc-range ;
 563
 564 PRIVATE>
 565
 566 : com-join-lines ( editor -- )
 567     dup gadget-selection?
 568     [ [ join-lines ] change-selection ] [
 569         [ model>> ] [ editor-caret first ] bi {
 570             { [ over last-line# 0 = ] [ 2drop ] }
 571             { [ 2dup last-line? ] [ join-with-prev ] }
 572             [ join-with-next ]
 573         } cond
 574     ] if ;
 575
 576 multiline-editor "multiline" f {
 577     { T{ key-down f f "UP" } previous-line }
 578     { T{ key-down f f "DOWN" } next-line }
 579     { T{ key-down f { S+ } "UP" } select-previous-line }
 580     { T{ key-down f { S+ } "DOWN" } select-next-line }
 581     { T{ key-down f f "PAGE_UP" } previous-page }
 582     { T{ key-down f f "PAGE_DOWN" } next-page }
 583     { T{ key-down f { S+ } "PAGE_UP" } select-previous-page }
 584     { T{ key-down f { S+ } "PAGE_DOWN" } select-next-page }
 585     { T{ key-down f f "RET" } insert-newline }
 586     { T{ key-down f { S+ } "RET" } insert-newline }
 587     { T{ key-down f f "ENTER" } insert-newline }
 588     { T{ key-down f { C+ } "j" } com-join-lines }
 589 } define-command-map
 590
 591 TUPLE: source-editor < multiline-editor ;
 592
 593 : <source-editor> ( -- editor )
 594     source-editor new-editor ;
 595
 596 ! A useful model
 597 : <element-model> ( editor element -- model )
 598     [ [ caret>> ] [ model>> ] bi ] dip
 599     '[ _ _ elt-string ] <arrow> ;
 600
 601 ! Fields wrap an editor
 602 TUPLE: field < border editor min-cols max-cols ;
 603
 604 <PRIVATE
 605
 606 : field-theme ( gadget -- gadget )
 607     { 2 2 } >>size
 608     { 1 0 } >>fill
 609     field-border-color <solid> >>boundary ; inline
 610
 611 : <field-border> ( gadget -- border )
 612     border new-border field-theme ;
 613
 614 PRIVATE>
 615
 616 : new-field ( class -- gadget )
 617     [ <editor> ] dip new-border
 618         dup gadget-child >>editor
 619         field-theme ; inline
 620
 621 ! For line-gadget-width
 622 M: field font>> editor>> font>> ;
 623
 624 M: field pref-dim*
 625     [ ]
 626     [ editor>> pref-dim ]
 627     [ [ line-gadget-width ] [ drop second ] 2bi 2array ]
 628     tri border-pref-dim ;
 629
 630 TUPLE: model-field < field field-model ;
 631
 632 : <model-field> ( model -- gadget )
 633     model-field new-field
 634         swap >>field-model ;
 635
 636 M: model-field graft*
 637     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 638     [ dup editor>> model>> add-connection ]
 639     bi ;
 640
 641 M: model-field ungraft*
 642     dup editor>> model>> remove-connection ;
 643
 644 M: model-field model-changed
 645     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;
 646
 647 TUPLE: action-editor < editor default-text ;
 648
 649 : <action-editor> ( -- editor )
 650     action-editor new-editor ;
 651
 652 <PRIVATE
 653
 654 : draw-default-text? ( editor -- ? )
 655     { [ default-text>> ] [ model>> doc-string empty? ] } 1&& ;
 656
 657 : draw-default-text ( editor -- )
 658     [ font>> clone line-color >>foreground ]
 659     [ default-text>> ] bi draw-text ;
 660
 661 PRIVATE>
 662
 663 M: action-editor draw-gadget*
 664     dup draw-default-text? [
 665         [ draw-default-text ] [ draw-caret ] bi
 666     ] [
 667         call-next-method
 668     ] if ;
 669
 670 M: action-editor pref-dim*
 671     dup draw-default-text? [
 672         [ font>> ] [ default-text>> ] bi text-dim { 1 0 } v+
 673     ] [
 674         call-next-method
 675     ] if ;
 676
 677 TUPLE: action-field < field quot ;
 678
 679 : <action-field> ( quot: ( string -- ) -- gadget )
 680     action-field [ <action-editor> ] dip new-border
 681         dup gadget-child >>editor
 682         field-theme
 683         swap >>quot ;
 684
 685 M: action-field default-text>> editor>> default-text>> ;
 686
 687 M: action-field default-text<< editor>> default-text<< ;
 688
 689 : invoke-action-field ( field -- )
 690     [ editor>> editor-string ]
 691     [ editor>> clear-editor ]
 692     [ quot>> ]
 693     tri call( string -- ) ;
 694
 695 action-field H{
 696     { T{ key-down f f "RET" } [ invoke-action-field ] }
 697 } set-gestures