basis/ui/gadgets/gadgets.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays hashtables kernel math namespaces
   4 make sequences quotations math.vectors combinators sorting
   5 binary-search vectors dlists deques models threads
   6 concurrency.flags math.order math.rectangles fry locals ;
   7 IN: ui.gadgets
   8
   9 ! Values for orientation slot
  10 CONSTANT: horizontal { 1 0 }
  11 CONSTANT: vertical { 0 1 }
  12
  13 TUPLE: gadget < rect
  14 pref-dim
  15 parent
  16 children
  17 { orientation initial: { 0 1 } }
  18 focus
  19 { visible? initial: t }
  20 root?
  21 clipped?
  22 layout-state
  23 { graft-state initial: { f f } }
  24 graft-node
  25 interior
  26 boundary
  27 model ;
  28
  29 M: gadget equal? 2drop f ;
  30
  31 M: gadget hashcode* nip identity-hashcode ;
  32
  33 M: gadget model-changed 2drop ;
  34
  35 : gadget-child ( gadget -- child ) children>> first ;
  36
  37 : nth-gadget ( n gadget -- child ) children>> nth ;
  38
  39 : <gadget> ( -- gadget )
  40     gadget new ;
  41
  42 : control-value ( control -- value )
  43     model>> value>> ;
  44
  45 : set-control-value ( value control -- )
  46     model>> set-model ;
  47
  48 : relative-loc ( fromgadget togadget -- loc )
  49     2dup eq? [
  50         2drop { 0 0 }
  51     ] [
  52         [ [ parent>> ] dip relative-loc ] [ drop loc>> ] 2bi v+
  53     ] if ;
  54
  55 GENERIC: user-input* ( str gadget -- ? )
  56
  57 M: gadget user-input* 2drop t ;
  58
  59 GENERIC: children-on ( rect gadget -- seq )
  60
  61 M: gadget children-on nip children>> ;
  62
  63 <PRIVATE
  64
  65 :: (fast-children-on) ( point axis children quot -- i )
  66     children [
  67         [ point ] dip
  68         quot call( value -- loc ) v-
  69         axis v. 0 <=>
  70     ] search drop ; inline
  71
  72 PRIVATE>
  73
  74 :: fast-children-on ( rect axis children quot -- slice )
  75     rect loc>> axis children quot (fast-children-on) 0 or
  76     rect rect-bounds v+ axis children quot (fast-children-on) ?1+
  77     children <slice> ; inline
  78
  79 M: gadget contains-rect? ( bounds gadget -- ? )
  80     dup visible?>> [ call-next-method ] [ 2drop f ] if ;
  81
  82 M: gadget contains-point? ( loc gadget -- ? )
  83     dup visible?>> [ call-next-method ] [ 2drop f ] if ;
  84
  85 : pick-up ( point gadget -- child/f )
  86     2dup [ dup point>rect ] dip children-on
  87     [ contains-point? ] with find-last nip
  88     [ [ loc>> v- ] [ pick-up ] bi ] [ nip ] ?if ;
  89
  90 : max-dim ( dims -- dim ) { 0 0 } [ vmax ] reduce ;
  91
  92 : dim-sum ( seq -- dim ) { 0 0 } [ v+ ] reduce ;
  93
  94 : each-child ( gadget quot -- )
  95     [ children>> ] dip each ; inline
  96
  97 ! Selection protocol
  98 GENERIC: gadget-selection? ( gadget -- ? )
  99
 100 M: gadget gadget-selection? drop f ;
 101
 102 GENERIC: gadget-selection ( gadget -- string/f )
 103
 104 M: gadget gadget-selection drop f ;
 105
 106 ! Text protocol
 107 GENERIC: gadget-text* ( gadget -- )
 108
 109 GENERIC: gadget-text-separator ( gadget -- str )
 110
 111 M: gadget gadget-text-separator
 112     orientation>> vertical = "\n" "" ? ;
 113
 114 : gadget-seq-text ( seq gadget -- )
 115     gadget-text-separator '[ _ % ] [ gadget-text* ] interleave ;
 116
 117 M: gadget gadget-text*
 118     [ children>> ] keep gadget-seq-text ;
 119
 120 M: array gadget-text*
 121     [ gadget-text* ] each ;
 122
 123 : gadget-text ( gadget -- string ) [ gadget-text* ] "" make ;
 124
 125 DEFER: relayout
 126
 127 <PRIVATE
 128
 129 SYMBOL: ui-notify-flag
 130
 131 : notify-ui-thread ( -- ) ui-notify-flag get-global raise-flag ;
 132
 133 : invalidate ( gadget -- )
 134     \ invalidate >>layout-state drop ;
 135
 136 : forget-pref-dim ( gadget -- ) f >>pref-dim drop ;
 137
 138 : layout-queue ( -- queue ) \ layout-queue get ;
 139
 140 : layout-later ( gadget -- )
 141     #! When unit testing gadgets without the UI running, the
 142     #! invalid queue is not initialized and we simply ignore
 143     #! invalidation requests.
 144     layout-queue [ push-front notify-ui-thread ] [ drop ] if* ;
 145
 146 : invalidate* ( gadget -- )
 147     \ invalidate* >>layout-state
 148     dup forget-pref-dim
 149     dup root?>>
 150     [ layout-later ] [ parent>> [ relayout ] when* ] if ;
 151
 152 PRIVATE>
 153
 154 : relayout ( gadget -- )
 155     dup layout-state>> \ invalidate* eq?
 156     [ drop ] [ invalidate* ] if ;
 157
 158 : relayout-1 ( gadget -- )
 159     dup layout-state>>
 160     [ drop ] [ dup invalidate layout-later ] if ;
 161
 162 : show-gadget ( gadget -- ) t >>visible? drop ;
 163
 164 : hide-gadget ( gadget -- ) f >>visible? drop ;
 165
 166 <PRIVATE
 167
 168 SYMBOL: in-layout?
 169
 170 GENERIC: dim-changed ( gadget -- )
 171
 172 M: gadget dim-changed
 173     in-layout? get [ invalidate ] [ invalidate* ] if ;
 174
 175 PRIVATE>
 176
 177 M: gadget dim<< ( dim gadget -- )
 178     2dup dim>> =
 179     [ 2drop ]
 180     [ [ nip ] [ call-next-method ] 2bi dim-changed ] if ;
 181
 182 GENERIC: pref-dim* ( gadget -- dim )
 183
 184 : pref-dim ( gadget -- dim )
 185     dup pref-dim>> [ ] [
 186         [ pref-dim* ] [ ] [ layout-state>> ] tri
 187         [ drop ] [ dupd pref-dim<< ] if
 188     ] ?if ;
 189
 190 : pref-dims ( gadgets -- seq ) [ pref-dim ] map ;
 191
 192 M: gadget pref-dim* dim>> ;
 193
 194 GENERIC: layout* ( gadget -- )
 195
 196 M: gadget layout* drop ;
 197
 198 : prefer ( gadget -- ) dup pref-dim >>dim drop ;
 199
 200 : layout ( gadget -- )
 201     dup layout-state>> [
 202         f >>layout-state
 203         dup layout*
 204         dup [ layout ] each-child
 205     ] when drop ;
 206
 207 GENERIC: graft* ( gadget -- )
 208
 209 M: gadget graft* drop ;
 210
 211 GENERIC: ungraft* ( gadget -- )
 212
 213 M: gadget ungraft* drop ;
 214
 215 <PRIVATE
 216
 217 : graft-queue ( -- dlist )
 218     \ graft-queue get [ "UI not running" throw ] unless* ;
 219
 220 : unqueue-graft ( gadget -- )
 221     [ graft-node>> graft-queue delete-node ]
 222     [ [ first { t t } { f f } ? ] change-graft-state drop ] bi ;
 223
 224 : (queue-graft) ( gadget flags -- )
 225     >>graft-state
 226     dup graft-queue push-front* >>graft-node drop
 227     notify-ui-thread ;
 228
 229 : queue-graft ( gadget -- )
 230     { f t } (queue-graft) ;
 231
 232 : queue-ungraft ( gadget -- )
 233     { t f } (queue-graft) ;
 234
 235 : graft-later ( gadget -- )
 236     dup graft-state>> {
 237         { { f t } [ drop ] }
 238         { { t t } [ drop ] }
 239         { { t f } [ unqueue-graft ] }
 240         { { f f } [ queue-graft ] }
 241     } case ;
 242
 243 : graft ( gadget -- )
 244     dup graft-later [ graft ] each-child ;
 245
 246 : ungraft-later ( gadget -- )
 247     dup graft-state>> {
 248         { { f f } [ drop ] }
 249         { { t f } [ drop ] }
 250         { { f t } [ unqueue-graft ] }
 251         { { t t } [ queue-ungraft ] }
 252     } case ;
 253
 254 : ungraft ( gadget -- )
 255     dup [ ungraft ] each-child ungraft-later ;
 256
 257 : activate-control ( gadget -- )
 258     dup model>> dup [
 259         2dup add-connection
 260         swap model-changed
 261     ] [
 262         2drop
 263     ] if ;
 264
 265 : deactivate-control ( gadget -- )
 266     dup model>> dup [ 2dup remove-connection ] when 2drop ;
 267
 268 : notify ( gadget -- )
 269     dup graft-state>>
 270     [ first { f f } { t t } ? >>graft-state ] [ ] bi
 271     {
 272         { { f t } [ dup activate-control graft* ] }
 273         { { t f } [ dup deactivate-control ungraft* ] }
 274     } case ;
 275
 276 : notify-queued ( -- )
 277     graft-queue [ notify ] slurp-deque ;
 278
 279 : (unparent) ( gadget -- )
 280     dup ungraft
 281     dup forget-pref-dim
 282     f >>parent drop ;
 283
 284 : (clear-gadget) ( gadget -- )
 285     dup [ (unparent) ] each-child
 286     f >>focus f >>children drop ;
 287
 288 : unfocus-gadget ( child gadget -- )
 289     [ nip ] [ focus>> eq? ] 2bi [ f >>focus ] when drop ;
 290
 291 PRIVATE>
 292
 293 : not-in-layout ( -- )
 294     in-layout? get
 295     [ "Cannot add/remove gadgets in layout*" throw ] when ;
 296
 297 GENERIC: remove-gadget ( gadget parent -- )
 298
 299 M: gadget remove-gadget 2drop ;
 300
 301 : unparent ( gadget -- )
 302     not-in-layout
 303     [
 304         dup parent>> dup
 305         [
 306             [ remove-gadget ] [
 307                 over (unparent)
 308                 [ unfocus-gadget ]
 309                 [ children>> remove! drop ]
 310                 [ nip relayout ]
 311                 2tri
 312             ] 2bi
 313         ] [ 2drop ] if
 314     ] when* ;
 315
 316 : clear-gadget ( gadget -- )
 317     not-in-layout
 318     [ (clear-gadget) ] [ relayout ] bi ;
 319
 320 <PRIVATE
 321
 322 : (add-gadget) ( child parent -- )
 323     {
 324         [ drop unparent ]
 325         [ >>parent drop ]
 326         [ [ ?push ] change-children drop ]
 327         [ graft-state>> second [ graft ] [ drop ] if ]
 328     } 2cleave ;
 329
 330 PRIVATE>
 331
 332 : add-gadget ( parent child -- parent )
 333     not-in-layout
 334     over (add-gadget)
 335     dup relayout ;
 336
 337 : add-gadgets ( parent children -- parent )
 338     not-in-layout
 339     [ over (add-gadget) ] each
 340     dup relayout ;
 341
 342 : parents ( gadget -- seq )
 343     [ parent>> ] follow ;
 344
 345 : each-parent ( gadget quot -- ? )
 346     [ parents ] dip all? ; inline
 347
 348 : find-parent ( gadget quot -- parent )
 349     [ parents ] dip find nip ; inline
 350
 351 : screen-loc ( gadget -- loc )
 352     parents { 0 0 } [ loc>> v+ ] reduce ;
 353
 354 <PRIVATE
 355
 356 : (screen-rect) ( gadget -- loc ext )
 357     dup parent>> [
 358         [ rect-extent ] dip (screen-rect)
 359         [ [ nip ] [ v+ ] 2bi ] dip [ v+ ] [ vmin ] 2bi*
 360     ] [
 361         rect-extent
 362     ] if* ;
 363
 364 PRIVATE>
 365
 366 : screen-rect ( gadget -- rect )
 367     (screen-rect) <extent-rect> ;
 368
 369 : child? ( parent child -- ? )
 370     {
 371         { [ 2dup eq? ] [ 2drop t ] }
 372         { [ dup not ] [ 2drop f ] }
 373         [ parent>> child? ]
 374     } cond ;
 375
 376 GENERIC: focusable-child* ( gadget -- child/t )
 377
 378 M: gadget focusable-child* drop t ;
 379
 380 : focusable-child ( gadget -- child )
 381     dup focusable-child*
 382     dup t eq? [ drop ] [ nip focusable-child ] if ;
 383
 384 GENERIC: request-focus-on ( child gadget -- )
 385
 386 M: gadget request-focus-on parent>> request-focus-on ;
 387
 388 M: f request-focus-on 2drop ;
 389
 390 : request-focus ( gadget -- )
 391     [ focusable-child ] keep request-focus-on ;
 392
 393 : focus-path ( gadget -- seq )
 394     [ focus>> ] follow ;
 395
 396 USE: vocabs.loader
 397
 398 { "ui.gadgets" "prettyprint" } "ui.gadgets.prettyprint" require-when