basis/ui/gadgets/gadgets.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays binary-search combinators concurrency.flags
   4 deques fry kernel locals make math math.order math.rectangles
   5 math.vectors models namespaces sequences threads vectors ;
   6 IN: ui.gadgets
   7
   8 ! Values for orientation slot
   9 CONSTANT: horizontal { 1 0 }
  10 CONSTANT: vertical { 0 1 }
  11
  12 TUPLE: gadget < rect
  13     pref-dim
  14     parent
  15     children
  16     { orientation initial: { 0 1 } }
  17     focus
  18     { visible? initial: t }
  19     root?
  20     clipped?
  21     layout-state
  22     { graft-state initial: { f f } }
  23     graft-node
  24     interior
  25     boundary
  26     model ;
  27
  28 M: gadget equal? 2drop f ;
  29
  30 M: gadget hashcode* nip identity-hashcode ;
  31
  32 M: gadget model-changed 2drop ;
  33
  34 : gadget-child ( gadget -- child ) children>> first ; inline
  35
  36 : nth-gadget ( n gadget -- child ) children>> nth ; inline
  37
  38 : <gadget> ( -- gadget )
  39     gadget new ; inline
  40
  41 : control-value ( control -- value )
  42     model>> value>> ;
  43
  44 : set-control-value ( value control -- )
  45     model>> set-model ;
  46
  47 : relative-loc ( fromgadget togadget -- loc )
  48     2dup eq? [
  49         2drop { 0 0 }
  50     ] [
  51         [ [ parent>> ] dip relative-loc ] [ drop loc>> ] 2bi v+
  52     ] if ;
  53
  54 GENERIC: user-input* ( str gadget -- ? )
  55
  56 M: gadget user-input* 2drop t ;
  57
  58 GENERIC: children-on ( rect gadget -- seq )
  59
  60 M: gadget children-on nip children>> ;
  61
  62 <PRIVATE
  63
  64 :: (fast-children-on) ( point axis children quot -- i )
  65     children [
  66         [ point ] dip
  67         quot call( value -- loc ) v-
  68         axis v. 0 <=>
  69     ] search drop ; inline
  70
  71 PRIVATE>
  72
  73 :: fast-children-on ( rect axis children quot -- slice )
  74     rect loc>> axis children quot (fast-children-on) 0 or
  75     rect rect-bounds v+ axis children quot (fast-children-on) ?1+
  76     children <slice> ; inline
  77
  78 M: gadget contains-rect? ( bounds gadget -- ? )
  79     dup visible?>> [ call-next-method ] [ 2drop f ] if ;
  80
  81 M: gadget contains-point? ( loc gadget -- ? )
  82     dup visible?>> [ call-next-method ] [ 2drop f ] if ;
  83
  84 : pick-up ( point gadget -- child/f )
  85     2dup [ dup point>rect ] dip children-on
  86     [ contains-point? ] with find-last nip
  87     [ [ loc>> v- ] [ pick-up ] bi ] [ nip ] ?if ;
  88
  89 : max-dims ( seq -- dim )
  90     [ 0 0 ] dip [ first2 swapd [ max ] 2bi@ ] each 2array ;
  91
  92 : sum-dims ( seq -- dim )
  93     [ 0 0 ] dip [ first2 swapd [ + ] 2bi@ ] each 2array ;
  94
  95 : each-child ( gadget quot -- )
  96     [ children>> ] dip each ; inline
  97
  98 ! Selection protocol
  99 GENERIC: gadget-selection? ( gadget -- ? )
 100
 101 M: gadget gadget-selection? drop f ;
 102
 103 GENERIC: gadget-selection ( gadget -- string/f )
 104
 105 M: gadget gadget-selection drop f ;
 106
 107 ! Text protocol
 108 GENERIC: gadget-text* ( gadget -- )
 109
 110 GENERIC: gadget-text-separator ( gadget -- str )
 111
 112 M: gadget gadget-text-separator
 113     orientation>> vertical = "\n" "" ? ;
 114
 115 : gadget-seq-text ( seq gadget -- )
 116     gadget-text-separator '[ _ % ] [ gadget-text* ] interleave ;
 117
 118 M: gadget gadget-text*
 119     [ children>> ] keep gadget-seq-text ;
 120
 121 M: array gadget-text*
 122     [ gadget-text* ] each ;
 123
 124 : gadget-text ( gadget -- string ) [ gadget-text* ] "" make ;
 125
 126 DEFER: relayout
 127
 128 <PRIVATE
 129
 130 SYMBOL: ui-notify-flag
 131
 132 : notify-ui-thread ( -- ) ui-notify-flag get-global raise-flag ;
 133
 134 : invalidate ( gadget -- )
 135     \ invalidate >>layout-state drop ;
 136
 137 : forget-pref-dim ( gadget -- ) f >>pref-dim drop ;
 138
 139 : layout-queue ( -- queue )
 140     \ layout-queue get ;
 141
 142 CONSTANT: layout-queue-limit 8000
 143
 144 : layout-later ( gadget -- )
 145     layout-queue [
 146         [ push notify-ui-thread ]
 147         [ length layout-queue-limit > [ yield ] when ] bi
 148     ] [ drop ] if* ;
 149
 150 : invalidate* ( gadget -- )
 151     \ invalidate* >>layout-state
 152     dup forget-pref-dim
 153     dup root?>>
 154     [ layout-later ] [ parent>> [ relayout ] when* ] if ;
 155
 156 PRIVATE>
 157
 158 : relayout ( gadget -- )
 159     dup layout-state>> \ invalidate* eq?
 160     [ drop ] [ invalidate* ] if ;
 161
 162 : relayout-1 ( gadget -- )
 163     dup layout-state>>
 164     [ drop ] [ dup invalidate layout-later ] if ;
 165
 166 : show-gadget ( gadget -- ) t >>visible? drop ;
 167
 168 : hide-gadget ( gadget -- ) f >>visible? drop ;
 169
 170 <PRIVATE
 171
 172 SYMBOL: in-layout?
 173
 174 GENERIC: dim-changed ( gadget -- )
 175
 176 M: gadget dim-changed
 177     in-layout? get [ invalidate ] [ invalidate* ] if ;
 178
 179 PRIVATE>
 180
 181 M: gadget dim<< ( dim gadget -- )
 182     2dup dim>> =
 183     [ 2drop ]
 184     [ [ nip ] [ call-next-method ] 2bi dim-changed ] if ;
 185
 186 GENERIC: pref-dim* ( gadget -- dim )
 187
 188 : pref-dim ( gadget -- dim )
 189     dup pref-dim>> [ ] [
 190         [ pref-dim* ] [ ] [ layout-state>> ] tri
 191         [ drop ] [ dupd pref-dim<< ] if
 192     ] ?if ;
 193
 194 : pref-dims ( gadgets -- seq ) [ pref-dim ] map ; inline
 195
 196 M: gadget pref-dim* dim>> ;
 197
 198 GENERIC: layout* ( gadget -- )
 199
 200 M: gadget layout* drop ;
 201
 202 : prefer ( gadget -- ) dup pref-dim >>dim drop ;
 203
 204 : layout ( gadget -- )
 205     dup layout-state>> [
 206         f >>layout-state
 207         dup layout*
 208         dup [ layout ] each-child
 209     ] when drop ;
 210
 211 GENERIC: graft* ( gadget -- )
 212
 213 M: gadget graft* drop ;
 214
 215 GENERIC: ungraft* ( gadget -- )
 216
 217 M: gadget ungraft* drop ;
 218
 219 <PRIVATE
 220
 221 : graft-queue ( -- dlist )
 222     \ graft-queue get [ "UI not running" throw ] unless* ;
 223
 224 : unqueue-graft ( gadget -- )
 225     [ graft-node>> graft-queue delete-node ]
 226     [ [ first { t t } { f f } ? ] change-graft-state drop ] bi ;
 227
 228 : (queue-graft) ( gadget flags -- )
 229     >>graft-state
 230     dup graft-queue push-front* >>graft-node drop
 231     notify-ui-thread ;
 232
 233 : queue-graft ( gadget -- )
 234     { f t } (queue-graft) ;
 235
 236 : queue-ungraft ( gadget -- )
 237     { t f } (queue-graft) ;
 238
 239 : graft-later ( gadget -- )
 240     dup graft-state>> {
 241         { { f t } [ drop ] }
 242         { { t t } [ drop ] }
 243         { { t f } [ unqueue-graft ] }
 244         { { f f } [ queue-graft ] }
 245     } case ;
 246
 247 : graft ( gadget -- )
 248     dup graft-later [ graft ] each-child ;
 249
 250 : ungraft-later ( gadget -- )
 251     dup graft-state>> {
 252         { { f f } [ drop ] }
 253         { { t f } [ drop ] }
 254         { { f t } [ unqueue-graft ] }
 255         { { t t } [ queue-ungraft ] }
 256     } case ;
 257
 258 : ungraft ( gadget -- )
 259     dup [ ungraft ] each-child ungraft-later ;
 260
 261 : activate-control ( gadget -- )
 262     dup model>> dup [
 263         2dup add-connection
 264         swap model-changed
 265     ] [
 266         2drop
 267     ] if ;
 268
 269 : deactivate-control ( gadget -- )
 270     dup model>> dup [ 2dup remove-connection ] when 2drop ;
 271
 272 : notify ( gadget -- )
 273     dup graft-state>>
 274     [ first { f f } { t t } ? >>graft-state ] [ ] bi
 275     {
 276         { { f t } [ dup activate-control graft* ] }
 277         { { t f } [ dup deactivate-control ungraft* ] }
 278     } case ;
 279
 280 : notify-queued ( -- )
 281     graft-queue [ notify ] slurp-deque ;
 282
 283 : (unparent) ( gadget -- )
 284     dup ungraft
 285     dup forget-pref-dim
 286     f >>parent drop ;
 287
 288 : (clear-gadget) ( gadget -- )
 289     dup [ (unparent) ] each-child
 290     f >>focus f >>children drop ;
 291
 292 : unfocus-gadget ( child gadget -- )
 293     [ nip ] [ focus>> eq? ] 2bi [ f >>focus ] when drop ;
 294
 295 PRIVATE>
 296
 297 : not-in-layout ( -- )
 298     in-layout? get
 299     [ "Cannot add/remove gadgets in layout*" throw ] when ;
 300
 301 GENERIC: remove-gadget ( gadget parent -- )
 302
 303 M: gadget remove-gadget 2drop ;
 304
 305 : unparent ( gadget -- )
 306     not-in-layout
 307     [
 308         dup parent>> dup
 309         [
 310             [ remove-gadget ] [
 311                 over (unparent)
 312                 [ unfocus-gadget ]
 313                 [ children>> remove! drop ]
 314                 [ nip relayout ]
 315                 2tri
 316             ] 2bi
 317         ] [ 2drop ] if
 318     ] when* ;
 319
 320 : clear-gadget ( gadget -- )
 321     not-in-layout
 322     [ (clear-gadget) ] [ relayout ] bi ;
 323
 324 <PRIVATE
 325
 326 : (add-gadget) ( child parent -- )
 327     {
 328         [ drop unparent ]
 329         [ >>parent drop ]
 330         [ [ ?push ] change-children drop ]
 331         [ graft-state>> second [ graft ] [ drop ] if ]
 332     } 2cleave ;
 333
 334 PRIVATE>
 335
 336 : add-gadget ( parent child -- parent )
 337     not-in-layout
 338     over (add-gadget)
 339     dup relayout ;
 340
 341 : add-gadgets ( parent children -- parent )
 342     not-in-layout
 343     over '[ _ (add-gadget) ] each
 344     dup relayout ;
 345
 346 : parents ( gadget -- seq )
 347     [ parent>> ] follow ;
 348
 349 : each-parent ( gadget quot -- ? )
 350     [ parents ] dip all? ; inline
 351
 352 : find-parent ( gadget quot -- parent )
 353     [ parents ] dip find nip ; inline
 354
 355 : screen-loc ( gadget -- loc )
 356     parents { 0 0 } [ loc>> v+ ] reduce ;
 357
 358 <PRIVATE
 359
 360 : (screen-rect) ( gadget -- loc ext )
 361     dup parent>> [
 362         [ rect-extent ] dip (screen-rect)
 363         [ [ nip ] [ v+ ] 2bi ] dip [ v+ ] [ vmin ] 2bi*
 364     ] [
 365         rect-extent
 366     ] if* ;
 367
 368 PRIVATE>
 369
 370 : screen-rect ( gadget -- rect )
 371     (screen-rect) <extent-rect> ;
 372
 373 : child? ( parent child -- ? )
 374     {
 375         { [ 2dup eq? ] [ 2drop t ] }
 376         { [ dup not ] [ 2drop f ] }
 377         [ parent>> child? ]
 378     } cond ;
 379
 380 GENERIC: focusable-child* ( gadget -- child/t )
 381
 382 M: gadget focusable-child* drop t ;
 383
 384 : focusable-child ( gadget -- child )
 385     dup focusable-child*
 386     dup t eq? [ drop ] [ nip focusable-child ] if ;
 387
 388 GENERIC: request-focus-on ( child gadget -- )
 389
 390 M: gadget request-focus-on parent>> request-focus-on ;
 391
 392 M: f request-focus-on 2drop ;
 393
 394 : request-focus ( gadget -- )
 395     [ focusable-child ] keep request-focus-on ;
 396
 397 : focus-path ( gadget -- seq )
 398     [ focus>> ] follow ;
 399
 400 USE: vocabs.loader
 401
 402 { "ui.gadgets" "prettyprint" } "ui.gadgets.prettyprint" require-when