basis/ui/gadgets/gadgets.factor

   1 ! Copyright (C) 2005, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays hashtables kernel models math namespaces
   4 make sequences quotations math.vectors combinators sorting
   5 binary-search vectors dlists deques models threads
   6 concurrency.flags math.order math.geometry.rect ;
   7 IN: ui.gadgets
   8
   9 SYMBOL: ui-notify-flag
  10
  11 : notify-ui-thread ( -- ) ui-notify-flag get-global raise-flag ;
  12
  13 TUPLE: gadget < rect
  14        pref-dim parent children orientation focus
  15        visible? root? clipped? layout-state graft-state graft-node
  16        interior boundary
  17        model ;
  18
  19 M: gadget equal? 2drop f ;
  20
  21 M: gadget hashcode* drop gadget hashcode* ;
  22
  23 M: gadget model-changed 2drop ;
  24
  25 : gadget-child ( gadget -- child ) children>> first ;
  26
  27 : nth-gadget ( n gadget -- child ) children>> nth ;
  28
  29 : init-gadget ( gadget -- gadget )
  30     init-rect
  31     { 0 1 } >>orientation
  32     t >>visible?
  33     { f f } >>graft-state ; inline
  34
  35 : new-gadget ( class -- gadget ) new init-gadget ; inline
  36
  37 : <gadget> ( -- gadget )
  38     gadget new-gadget ;
  39
  40 : activate-control ( gadget -- )
  41     dup model>> dup [
  42         2dup add-connection
  43         swap model-changed
  44     ] [
  45         2drop
  46     ] if ;
  47
  48 : deactivate-control ( gadget -- )
  49     dup model>> dup [ 2dup remove-connection ] when 2drop ;
  50
  51 : control-value ( control -- value )
  52     model>> value>> ;
  53
  54 : set-control-value ( value control -- )
  55     model>> set-model ;
  56
  57 : relative-loc ( fromgadget togadget -- loc )
  58     2dup eq? [
  59         2drop { 0 0 }
  60     ] [
  61         over rect-loc >r
  62         >r parent>> r> relative-loc
  63         r> v+
  64     ] if ;
  65
  66 GENERIC: user-input* ( str gadget -- ? )
  67
  68 M: gadget user-input* 2drop t ;
  69
  70 GENERIC: children-on ( rect/point gadget -- seq )
  71
  72 M: gadget children-on nip children>> ;
  73
  74 : ((fast-children-on)) ( gadget dim axis -- <=> )
  75     [ swap loc>> v- ] dip v. 0 <=> ;
  76
  77 : (fast-children-on) ( dim axis children -- i )
  78     -rot [ ((fast-children-on)) ] 2curry search drop ;
  79
  80 : fast-children-on ( rect axis children -- from to )
  81     [ [ rect-loc ] 2dip (fast-children-on) 0 or ]
  82     [ [ rect-bounds v+ ] 2dip (fast-children-on) ?1+ ]
  83     3bi ;
  84
  85 : inside? ( bounds gadget -- ? )
  86     dup visible?>> [ intersects? ] [ 2drop f ] if ;
  87
  88 : (pick-up) ( point gadget -- gadget )
  89     dupd children-on [ inside? ] with find-last nip ;
  90
  91 : pick-up ( point gadget -- child/f )
  92     2dup (pick-up) dup
  93     [ nip [ rect-loc v- ] keep pick-up ] [ rot 2drop ] if ;
  94
  95 : max-dim ( dims -- dim ) { 0 0 } [ vmax ] reduce ;
  96
  97 : dim-sum ( seq -- dim ) { 0 0 } [ v+ ] reduce ;
  98
  99 : orient ( gadget seq1 seq2 -- seq )
 100     >r >r orientation>> r> r> [ pick set-axis ] 2map nip ;
 101
 102 : each-child ( gadget quot -- )
 103     >r children>> r> each ; inline
 104
 105 ! Selection protocol
 106 GENERIC: gadget-selection? ( gadget -- ? )
 107
 108 M: gadget gadget-selection? drop f ;
 109
 110 GENERIC: gadget-selection ( gadget -- string/f )
 111
 112 M: gadget gadget-selection drop f ;
 113
 114 ! Text protocol
 115 GENERIC: gadget-text* ( gadget -- )
 116
 117 GENERIC: gadget-text-separator ( gadget -- str )
 118
 119 M: gadget gadget-text-separator
 120     orientation>> { 0 1 } = "\n" "" ? ;
 121
 122 : gadget-seq-text ( seq gadget -- )
 123     gadget-text-separator swap
 124     [ dup % ] [ gadget-text* ] interleave drop ;
 125
 126 M: gadget gadget-text*
 127     dup children>> swap gadget-seq-text ;
 128
 129 M: array gadget-text*
 130     [ gadget-text* ] each ;
 131
 132 : gadget-text ( gadget -- string ) [ gadget-text* ] "" make ;
 133
 134 : invalidate ( gadget -- )
 135     \ invalidate >>layout-state drop ;
 136
 137 : forget-pref-dim ( gadget -- ) f >>pref-dim drop ;
 138
 139 : layout-queue ( -- queue ) \ layout-queue get ;
 140
 141 : layout-later ( gadget -- )
 142     #! When unit testing gadgets without the UI running, the
 143     #! invalid queue is not initialized and we simply ignore
 144     #! invalidation requests.
 145     layout-queue [ push-front notify-ui-thread ] [ drop ] if* ;
 146
 147 DEFER: relayout
 148
 149 : invalidate* ( gadget -- )
 150     \ invalidate* >>layout-state
 151     dup forget-pref-dim
 152     dup root?>>
 153     [ layout-later ] [ parent>> [ relayout ] when* ] if ;
 154
 155 : relayout ( gadget -- )
 156     dup layout-state>> \ invalidate* eq?
 157     [ drop ] [ invalidate* ] if ;
 158
 159 : relayout-1 ( gadget -- )
 160     dup layout-state>>
 161     [ drop ] [ dup invalidate layout-later ] if ;
 162
 163 : show-gadget ( gadget -- ) t >>visible? drop ;
 164
 165 : hide-gadget ( gadget -- ) f >>visible? drop ;
 166
 167 DEFER: in-layout?
 168
 169 GENERIC: dim-changed ( gadget -- )
 170
 171 M: gadget dim-changed
 172     in-layout? get [ invalidate ] [ invalidate* ] if ;
 173
 174 M: gadget (>>dim) ( dim gadget -- )
 175     2dup dim>> = [ 2drop ] [ tuck call-next-method dim-changed ] if ;
 176
 177 GENERIC: pref-dim* ( gadget -- dim )
 178
 179 : ?set-gadget-pref-dim ( dim gadget -- )
 180     dup layout-state>>
 181     [ 2drop ] [ (>>pref-dim) ] if ;
 182
 183 : pref-dim ( gadget -- dim )
 184     dup pref-dim>> [ ] [
 185         [ pref-dim* dup ] keep ?set-gadget-pref-dim
 186     ] ?if ;
 187
 188 : pref-dims ( gadgets -- seq ) [ pref-dim ] map ;
 189
 190 M: gadget pref-dim* rect-dim ;
 191
 192 GENERIC: layout* ( gadget -- )
 193
 194 M: gadget layout* drop ;
 195
 196 : prefer ( gadget -- ) dup pref-dim >>dim drop ;
 197
 198 : validate ( gadget -- ) f >>layout-state drop ;
 199
 200 : layout ( gadget -- )
 201     dup layout-state>> [
 202         dup validate
 203         dup layout*
 204         dup [ layout ] each-child
 205     ] when drop ;
 206
 207 : graft-queue ( -- dlist ) \ graft-queue get ;
 208
 209 : unqueue-graft ( gadget -- )
 210     [ graft-node>> graft-queue delete-node ]
 211     [ [ first { t t } { f f } ? ] change-graft-state drop ] bi ;
 212
 213 : (queue-graft) ( gadget flags -- )
 214     >>graft-state
 215     dup graft-queue push-front* >>graft-node drop
 216     notify-ui-thread ;
 217
 218 : queue-graft ( gadget -- )
 219     { f t } (queue-graft) ;
 220
 221 : queue-ungraft ( gadget -- )
 222     { t f } (queue-graft) ;
 223
 224 : graft-later ( gadget -- )
 225     dup graft-state>> {
 226         { { f t } [ drop ] }
 227         { { t t } [ drop ] }
 228         { { t f } [ unqueue-graft ] }
 229         { { f f } [ queue-graft ] }
 230     } case ;
 231
 232 : ungraft-later ( gadget -- )
 233     dup graft-state>> {
 234         { { f f } [ drop ] }
 235         { { t f } [ drop ] }
 236         { { f t } [ unqueue-graft ] }
 237         { { t t } [ queue-ungraft ] }
 238     } case ;
 239
 240 GENERIC: graft* ( gadget -- )
 241
 242 M: gadget graft* drop ;
 243
 244 : graft ( gadget -- )
 245     dup graft-later [ graft ] each-child ;
 246
 247 GENERIC: ungraft* ( gadget -- )
 248
 249 M: gadget ungraft* drop ;
 250
 251 : ungraft ( gadget -- )
 252     dup [ ungraft ] each-child ungraft-later ;
 253
 254 : (unparent) ( gadget -- )
 255     dup ungraft
 256     dup forget-pref-dim
 257     f >>parent drop ;
 258
 259 : unfocus-gadget ( child gadget -- )
 260     tuck focus>> eq? [ f >>focus ] when drop ;
 261
 262 SYMBOL: in-layout?
 263
 264 : not-in-layout ( -- )
 265     in-layout? get
 266     [ "Cannot add/remove gadgets in layout*" throw ] when ;
 267
 268 : unparent ( gadget -- )
 269     not-in-layout
 270     [
 271         dup parent>> dup [
 272             over (unparent)
 273             [ unfocus-gadget ] 2keep
 274             [ children>> delete ] keep
 275             relayout
 276         ] [
 277             2drop
 278         ] if
 279     ] when* ;
 280
 281 : (clear-gadget) ( gadget -- )
 282     dup [ (unparent) ] each-child
 283     f >>focus f >>children drop ;
 284
 285 : clear-gadget ( gadget -- )
 286     not-in-layout
 287     dup (clear-gadget) relayout ;
 288
 289 : ((add-gadget)) ( parent child -- parent )
 290     over children>> ?push >>children ;
 291
 292 : (add-gadget) ( parent child -- parent )
 293     dup unparent
 294     over >>parent
 295     tuck ((add-gadget))
 296     tuck graft-state>> second
 297         [ graft ]
 298         [ drop  ]
 299     if ;
 300
 301 : add-gadget ( parent child -- parent )
 302     not-in-layout
 303     (add-gadget)
 304     dup relayout ;
 305
 306 : add-gadgets ( parent children -- parent )
 307     not-in-layout
 308     [ (add-gadget) ] each
 309     dup relayout ;
 310
 311 : parents ( gadget -- seq )
 312     [ parent>> ] follow ;
 313
 314 : each-parent ( gadget quot -- ? )
 315     >r parents r> all? ; inline
 316
 317 : find-parent ( gadget quot -- parent )
 318     >r parents r> find nip ; inline
 319
 320 : screen-loc ( gadget -- loc )
 321     parents { 0 0 } [ rect-loc v+ ] reduce ;
 322
 323 : (screen-rect) ( gadget -- loc ext )
 324     dup parent>> [
 325         >r rect-extent r> (screen-rect)
 326         >r tuck v+ r> vmin >r v+ r>
 327     ] [
 328         rect-extent
 329     ] if* ;
 330
 331 : screen-rect ( gadget -- rect )
 332     (screen-rect) <extent-rect> ;
 333
 334 : child? ( parent child -- ? )
 335     {
 336         { [ 2dup eq? ] [ 2drop t ] }
 337         { [ dup not ] [ 2drop f ] }
 338         [ parent>> child? ]
 339     } cond ;
 340
 341 GENERIC: focusable-child* ( gadget -- child/t )
 342
 343 M: gadget focusable-child* drop t ;
 344
 345 : focusable-child ( gadget -- child )
 346     dup focusable-child*
 347     dup t eq? [ drop ] [ nip focusable-child ] if ;
 348
 349 GENERIC: request-focus-on ( child gadget -- )
 350
 351 M: gadget request-focus-on parent>> request-focus-on ;
 352
 353 M: f request-focus-on 2drop ;
 354
 355 : request-focus ( gadget -- )
 356     [ focusable-child ] keep request-focus-on ;
 357
 358 : focus-path ( world -- seq )
 359     [ focus>> ] follow ;